feat(guard): create soft delete for organizations (#213)

Author: forestileao

github_hooks/db/migrate/20250409112220_add_deleted_at_for_organizations.rb

@@ -0,0 +1,5 @@
+class AddDeletedAtForOrganizations < ActiveRecord::Migration[5.1]
+  def change
+    add_column :organizations, :deleted_at, :datetime, null: true, default: nil
+  end
+end

guard/lib/guard/events/organization_deleted.ex

@@ -3,8 +3,17 @@ defmodule Guard.Events.OrganizationDeleted do
   Event emitted when an organization is deleted.
   """
 
-  @spec publish(String.t()) :: :ok
-  def publish(organization_id) do
+  @spec publish(String.t(), Keyword.t()) :: :ok | {:error, :missing_event_type}
+  def publish(organization_id, opts) do
+    case opts[:type] do
+      :soft_delete -> do_publish(organization_id, "soft_deleted")
+      :hard_delete -> do_publish(organization_id, "deleted")
+      nil -> {:error, :missing_event_type}
+      _ -> {:error, :invalid_event_type}
+    end
+  end
+
+  defp do_publish(organization_id, routing_key) do
     event =
       InternalApi.Organization.OrganizationDeleted.new(
         org_id: organization_id,
@@ -14,10 +23,7 @@ defmodule Guard.Events.OrganizationDeleted do
 
     message = InternalApi.Organization.OrganizationDeleted.encode(event)
 
-    exchange_name = "organization_exchange"
-    routing_key = "deleted"
-
     {:ok, channel} = AMQP.Application.get_channel(:organization)
-    :ok = AMQP.Basic.publish(channel, exchange_name, routing_key, message)
+    :ok = AMQP.Basic.publish(channel, "organization_exchange", routing_key, message)
   end
 end

guard/lib/guard/front_repo/organization.ex

@@ -17,6 +17,7 @@ defmodule Guard.FrontRepo.Organization do
     field(:deny_member_workflows, :boolean)
     field(:deny_non_member_workflows, :boolean)
     field(:settings, :map)
+    field(:deleted_at, :utc_datetime)
 
     has_many(:contacts, Guard.FrontRepo.OrganizationContact, on_delete: :delete_all)
     has_many(:suspensions, Guard.FrontRepo.OrganizationSuspension, on_delete: :delete_all)
@@ -47,7 +48,8 @@ defmodule Guard.FrontRepo.Organization do
         :deny_member_workflows,
         :deny_non_member_workflows,
         :settings,
-        :created_at
+        :created_at,
+        :deleted_at
       ],
       empty_values: []
     )

guard/lib/guard/grpc_servers/organization_server.ex

@@ -421,10 +421,8 @@ defmodule Guard.GrpcServers.OrganizationServer do
     observe("destroy", fn ->
       case fetch_organization(org_id, "") do
         {:ok, organization} ->
-          case Guard.Store.Organization.destroy(organization) do
+          case Guard.Store.Organization.soft_destroy(organization) do
             {:ok, _} ->
-              Guard.Events.OrganizationDeleted.publish(organization.id)
-
               %Google.Protobuf.Empty{}
 
             {:error, changeset} ->

guard/lib/guard/store/organization.ex

@@ -8,6 +8,7 @@ defmodule Guard.Store.Organization do
   def get_by_id(id) when is_binary(id) and id != "" do
     Guard.FrontRepo.Organization
     |> where([o], o.id == ^id)
+    |> where_undeleted()
     |> Guard.FrontRepo.one()
     |> case do
       nil -> Util.ToTuple.error("Organization '#{id}' not found.", :not_found)
@@ -20,6 +21,7 @@ defmodule Guard.Store.Organization do
   def get_by_username(username) when is_binary(username) and username != "" do
     Guard.FrontRepo.Organization
     |> where([o], o.username == ^username)
+    |> where_undeleted()
     |> Guard.FrontRepo.one()
     |> case do
       nil -> Util.ToTuple.error("Organization '#{username}' not found.", :not_found)
@@ -30,6 +32,7 @@ defmodule Guard.Store.Organization do
   def exists?(org_id) do
     Guard.FrontRepo.Organization
     |> where([o], o.id == ^org_id)
+    |> where_undeleted()
     |> Guard.FrontRepo.exists?()
   end
 
@@ -70,6 +73,7 @@ defmodule Guard.Store.Organization do
   def list(params, keyset_params) do
     query =
       Guard.FrontRepo.Organization
+      |> where_undeleted()
       |> filter_by_created_at_gt(params.created_at_gt)
 
     flop =
@@ -87,6 +91,7 @@ defmodule Guard.Store.Organization do
   def list_by_ids(ids) when is_list(ids) do
     Guard.FrontRepo.Organization
     |> where([o], o.id in ^ids)
+    |> where_undeleted()
     |> Guard.FrontRepo.all()
   end
 
@@ -296,12 +301,47 @@ defmodule Guard.Store.Organization do
   end
 
   @doc """
-  Deletes an organization.
+  Soft deletes an organization.
   Returns {:ok, organization} if successful, or {:error, changeset} if not.
   """
-  @spec destroy(Guard.FrontRepo.Organization.t()) ::
+  @spec soft_destroy(Guard.FrontRepo.Organization.t()) ::
           {:ok, Guard.FrontRepo.Organization.t()} | {:error, Ecto.Changeset.t()}
-  def destroy(%Guard.FrontRepo.Organization{} = organization) do
-    Guard.FrontRepo.delete(organization)
+  def soft_destroy(%Guard.FrontRepo.Organization{} = organization) do
+    result =
+      organization
+      |> Guard.FrontRepo.Organization.changeset(%{deleted_at: DateTime.utc_now()})
+      |> Guard.FrontRepo.update()
+
+    case result do
+      {:ok, _} ->
+        :ok = Guard.Events.OrganizationDeleted.publish(organization.id, type: :soft_delete)
+        result
+
+      _ ->
+        result
+    end
+  end
+
+  @doc """
+  Deletes an organization completely from the database.
+  Returns {:ok, organization} if successful, or {:error, changeset} if not.
+  """
+  @spec hard_destroy(Guard.FrontRepo.Organization.t()) ::
+          {:ok, Guard.FrontRepo.Organization.t()} | {:error, Ecto.Changeset.t()}
+  def hard_destroy(%Guard.FrontRepo.Organization{} = organization) do
+    result = Guard.FrontRepo.delete(organization)
+
+    case result do
+      {:ok, _} ->
+        :ok = Guard.Events.OrganizationDeleted.publish(organization.id, type: :hard_delete)
+        result
+
+      _ ->
+        result
+    end
+  end
+
+  defp where_undeleted(query) do
+    query |> where([o], is_nil(o.deleted_at))
   end
 end

guard/priv/front_repo/migrations/20250409190912_add_deleted_at_for_organizations.exs

@@ -0,0 +1,9 @@
+defmodule Guard.FrontRepo.Migrations.AddDeletedAtForOrganizations do
+  use Ecto.Migration
+
+  def change do
+    alter table(:organizations) do
+      add :deleted_at, :utc_datetime, null: true, default: nil
+    end
+  end
+end

guard/test/guard/grpc_servers/organization_server_test.exs

@@ -1196,26 +1196,35 @@ defmodule Guard.GrpcServers.OrganizationServerTest do
       grpc_channel: channel,
       organization: organization
     } do
-      with_mocks [{Guard.Events.OrganizationDeleted, [], [publish: fn _ -> :ok end]}] do
+      with_mocks [{Guard.Events.OrganizationDeleted, [], [publish: fn _, _ -> :ok end]}] do
         request = Organization.DestroyRequest.new(org_id: organization.id)
 
         {:ok, _} = channel |> Organization.OrganizationService.Stub.destroy(request)
 
-        # Verify organization was deleted
-        assert is_nil(Guard.FrontRepo.get(Guard.FrontRepo.Organization, organization.id))
+        # Verify organization was soft deleted
+        soft_deleted_org = Guard.FrontRepo.get(Guard.FrontRepo.Organization, organization.id)
+        assert soft_deleted_org.deleted_at != nil
 
-        assert_called(Guard.Events.OrganizationDeleted.publish(organization.id))
+        assert {:error, {:not_found, _message}} =
+                 Guard.Store.Organization.get_by_id(soft_deleted_org.id)
+
+        assert {:error, {:not_found, _message}} =
+                 Guard.Store.Organization.get_by_username(soft_deleted_org.username)
+
+        assert_called(
+          Guard.Events.OrganizationDeleted.publish(organization.id, type: :soft_delete)
+        )
       end
     end
 
     test "returns error for non-existent organization", %{grpc_channel: channel} do
-      with_mocks [{Guard.Events.OrganizationDeleted, [], [publish: fn _ -> :ok end]}] do
+      with_mocks [{Guard.Events.OrganizationDeleted, [], [publish: fn _, _ -> :ok end]}] do
         non_existent_id = Ecto.UUID.generate()
         request = Organization.DestroyRequest.new(org_id: non_existent_id)
 
         assert {:error, %GRPC.RPCError{message: message}} = Stub.destroy(channel, request)
         assert message =~ "Organization '#{non_existent_id}' not found."
-        assert_not_called(Guard.Events.OrganizationDeleted.publish(:_))
+        assert_not_called(Guard.Events.OrganizationDeleted.publish(:_, type: :soft_delete))
       end
     end
   end

guard/test/guard/store/organization_test.exs

@@ -538,14 +538,14 @@ defmodule Guard.Store.OrganizationTest do
     end
   end
 
-  describe "destroy/1" do
+  describe "hard_destroy/1" do
     test "deletes organization when it exists", %{org_id: org_id} do
       organization = Guard.FrontRepo.get!(Guard.FrontRepo.Organization, org_id)
 
       contact = Support.Factories.Organization.insert_contact!(organization.id)
       suspension = Support.Factories.Organization.insert_suspension!(organization.id)
 
-      assert {:ok, deleted_org} = Organization.destroy(organization)
+      assert {:ok, deleted_org} = Organization.hard_destroy(organization)
       assert deleted_org.id == org_id
 
       assert is_nil(Guard.FrontRepo.get(Guard.FrontRepo.Organization, org_id))
@@ -554,6 +554,23 @@ defmodule Guard.Store.OrganizationTest do
     end
   end
 
+  describe "soft_destroy/1" do
+    test "marks an organization as deleted", %{org_id: org_id} do
+      organization = Guard.FrontRepo.get!(Guard.FrontRepo.Organization, org_id)
+
+      assert {:ok, deleted_org} = Organization.soft_destroy(organization)
+      assert deleted_org.id == org_id
+
+      soft_deleted_org = Guard.FrontRepo.get(Guard.FrontRepo.Organization, org_id)
+      assert soft_deleted_org.deleted_at != nil
+
+      assert {:error, {:not_found, _message}} = Organization.get_by_id(org_id)
+
+      assert {:error, {:not_found, _message}} =
+               Organization.get_by_username(soft_deleted_org.username)
+    end
+  end
+
   describe "create/1" do
     test "creates organization with valid attributes" do
       owner_id = Ecto.UUID.generate()