Add service for inserting new types

Author: VeljkoMaksimovic

ee/ephemeral_environments/lib/ephemeral_environments/repo/ephemeral_environment_type.ex

@@ -6,25 +6,44 @@ defmodule EphemeralEnvironments.Repo.EphemeralEnvironmentType do
   @foreign_key_type :binary_id
 
   schema "ephemeral_environment_types" do
-    field :org_id, :binary_id
-    field :name, :string
-    field :description, :string
-    field :created_by, :binary_id
-    field :last_modified_by, :binary_id
-    field :state, :string
-    field :max_number_of_instances, :integer
+    field(:org_id, :binary_id)
+    field(:name, :string)
+    field(:description, :string)
+    field(:created_by, :binary_id)
+    field(:last_modified_by, :binary_id)
+    field(:state, Ecto.Enum, values: [:draft, :ready, :cordoned, :deleted])
+    field(:max_number_of_instances, :integer)
 
     timestamps()
   end
 
   @doc false
   def changeset(ephemeral_environment_type, attrs) do
     ephemeral_environment_type
-    |> cast(attrs, [:org_id, :name, :description, :created_by, :last_modified_by, :state, :max_number_of_instances])
+    |> cast(attrs, [
+      :org_id,
+      :name,
+      :description,
+      :created_by,
+      :last_modified_by,
+      :state,
+      :max_number_of_instances
+    ])
     |> validate_required([:org_id, :name, :created_by, :last_modified_by, :state])
+    |> validate_uuid(:org_id)
+    |> validate_uuid(:created_by)
+    |> validate_uuid(:last_modified_by)
     |> validate_length(:name, min: 1, max: 255)
     |> validate_length(:description, max: 1000)
-    |> validate_inclusion(:state, [:draft, :ready, :cordoned, :deleted])
     |> validate_number(:max_number_of_instances, greater_than: 0)
   end
-end
+
+  defp validate_uuid(changeset, field) do
+    validate_change(changeset, field, fn ^field, value ->
+      case Ecto.UUID.cast(value) do
+        {:ok, _} -> []
+        :error -> [{field, "must be a valid UUID"}]
+      end
+    end)
+  end
+end

ee/ephemeral_environments/lib/ephemeral_environments/service/ephemeral_environment_type.ex

@@ -0,0 +1,45 @@
+defmodule EphemeralEnvironments.Service.EphemeralEnvironmentType do
+  alias EphemeralEnvironments.Repo
+  alias EphemeralEnvironments.Repo.EphemeralEnvironmentType, as: Schema
+
+  @doc """
+  Creates a new ephemeral environment type.
+
+  ## Parameters
+    - attrs: Map with keys:
+      - org_id (required)
+      - name (required)
+      - created_by (required)
+      - state (optional, defaults to :draft)
+      - description (optional)
+      - max_number_of_instances (optional)
+
+  ## Returns
+    - {:ok, %Schema{}} on success
+    - {:error, String.t()} on validation failure
+  """
+  def create(attrs) do
+    attrs = Map.put(attrs, :last_modified_by, attrs[:created_by])
+    attrs = Map.put_new(attrs, :state, :draft)
+
+    %Schema{}
+    |> Schema.changeset(attrs)
+    |> Repo.insert()
+    |> case do
+      {:ok, record} -> {:ok, record}
+      {:error, changeset} -> {:error, format_errors(changeset)}
+    end
+  end
+
+  defp format_errors(changeset) do
+    Ecto.Changeset.traverse_errors(changeset, fn {msg, opts} ->
+      Enum.reduce(opts, msg, fn {key, value}, acc ->
+        String.replace(acc, "%{#{key}}", to_string(value))
+      end)
+    end)
+    |> Enum.map(fn {field, errors} ->
+      "#{field}: #{Enum.join(errors, ", ")}"
+    end)
+    |> Enum.join("; ")
+  end
+end