`uniform` params to raygeneration shaders are treated as `ShaderRecordBufferKHR`s not `PushConstant`s

[expenses]

Issue Description

For SPIR-V outputs, I expect all uniform entry point struct params to be treated as PushConstants. At the very least, this is what https://shader-slang.org/slang/user-guide/spirv-target-specific#push-constants states. However, compiling the following with slangc shaders/test.slang -o out.spv shows that this is not consistent between compute and raygeneration shaders:

struct Const {
    uint* val;
}

[shader("compute")]
void compute(uniform Const const) {
    const.val++;
}

[shader("raygeneration")]
void raygeneration(uniform Const const) {
    const.val++;
}

; SPIR-V
; Version: 1.5
; Generator: Khronos Slang Compiler; 0
; Bound: 64
; Schema: 0
               OpCapability PhysicalStorageBufferAddresses
               OpCapability RayTracingKHR
               OpCapability Shader
               OpExtension "SPV_KHR_physical_storage_buffer"
               OpExtension "SPV_KHR_ray_tracing"
               OpMemoryModel PhysicalStorageBuffer64 GLSL450
               OpEntryPoint GLCompute %compute "compute" %entryPointParams
               OpEntryPoint RayGenerationKHR %raygeneration "raygeneration" %entryPointParams_0
               OpExecutionMode %compute LocalSize 1 1 1
               OpSource Slang 1
               OpName %Const_std430_logical "Const_std430_logical"
               OpMemberName %Const_std430_logical 0 "val"
               OpName %Const_std430 "Const_std430"
               OpMemberName %Const_std430 0 "val"
               OpName %EntryPointParams_std430 "EntryPointParams_std430"
               OpMemberName %EntryPointParams_std430 0 "const"
               OpName %entryPointParams "entryPointParams"
               OpName %compute "compute"
               OpName %EntryPointParams_std430_0 "EntryPointParams_std430"
               OpMemberName %EntryPointParams_std430_0 0 "const"
               OpName %entryPointParams_0 "entryPointParams"
               OpName %raygeneration "raygeneration"
               OpDecorate %_ptr_PhysicalStorageBuffer_uint ArrayStride 4
               OpMemberDecorate %Const_std430 0 Offset 0
               OpDecorate %EntryPointParams_std430 Block
               OpMemberDecorate %EntryPointParams_std430 0 Offset 0
               OpDecorate %EntryPointParams_std430_0 Block
               OpMemberDecorate %EntryPointParams_std430_0 0 Offset 0
       %void = OpTypeVoid
          %3 = OpTypeFunction %void
       %uint = OpTypeInt 32 0
%_ptr_PhysicalStorageBuffer_uint = OpTypePointer PhysicalStorageBuffer %uint
%Const_std430_logical = OpTypeStruct %_ptr_PhysicalStorageBuffer_uint
%Const_std430 = OpTypeStruct %_ptr_PhysicalStorageBuffer_uint
%EntryPointParams_std430 = OpTypeStruct %Const_std430
%_ptr_PushConstant_EntryPointParams_std430 = OpTypePointer PushConstant %EntryPointParams_std430
        %int = OpTypeInt 32 1
      %int_0 = OpConstant %int 0
%_ptr_PushConstant_Const_std430 = OpTypePointer PushConstant %Const_std430
      %int_1 = OpConstant %int 1
%EntryPointParams_std430_0 = OpTypeStruct %Const_std430
%_ptr_ShaderRecordBufferKHR_EntryPointParams_std430_0 = OpTypePointer ShaderRecordBufferKHR %EntryPointParams_std430_0
%_ptr_ShaderRecordBufferKHR_Const_std430 = OpTypePointer ShaderRecordBufferKHR %Const_std430
%entryPointParams = OpVariable %_ptr_PushConstant_EntryPointParams_std430 PushConstant
%entryPointParams_0 = OpVariable %_ptr_ShaderRecordBufferKHR_EntryPointParams_std430_0 ShaderRecordBufferKHR
    %compute = OpFunction %void None %3
          %4 = OpLabel
         %20 = OpAccessChain %_ptr_PushConstant_Const_std430 %entryPointParams %int_0
         %21 = OpLoad %Const_std430 %20
         %22 = OpCopyLogical %Const_std430_logical %21
         %59 = OpCompositeExtract %_ptr_PhysicalStorageBuffer_uint %22 0
         %31 = OpPtrAccessChain %_ptr_PhysicalStorageBuffer_uint %59 %int_1
               OpReturn
               OpFunctionEnd
%raygeneration = OpFunction %void None %3
         %36 = OpLabel
         %43 = OpAccessChain %_ptr_ShaderRecordBufferKHR_Const_std430 %entryPointParams_0 %int_0
         %44 = OpLoad %Const_std430 %43
         %45 = OpCopyLogical %Const_std430_logical %44
         %63 = OpCompositeExtract %_ptr_PhysicalStorageBuffer_uint %45 0
         %53 = OpPtrAccessChain %_ptr_PhysicalStorageBuffer_uint %63 %int_1
               OpReturn
               OpFunctionEnd

One becomes OpVariable %_ptr_PushConstant_EntryPointParams_std430 PushConstant while the other becomes OpTypePointer ShaderRecordBufferKHR %EntryPointParams_std430_0. This is a total footgun.

Environment

• Slang Version: v2026.3.1-nixpkgs
• OS: Linux

Additional context

Add any other context about the problem here.

[aidanfnv]

This is by design, but it appears that any mention of it is missing from the SPIR-V specific documentation.

As you noted, the SPIR-V-Specific Functionalities doc does imply that all uniform entry point struct params to be treated as PushConstants:

By default, a uniform parameter defined in the parameter list of an entrypoint function is translated to a push constant in SPIRV, if the type of the parameter is ordinary data type (no resources/textures). All uniform parameters defined in global scope are grouped together and placed in a default constant buffer.

However, the Conventional Language Features doc does mention that ray tracing entry-point uniforms are handled differently:

When entry points match a “ray tracing” type, we bind uniforms which are in the global scope to the global root signature (or ray tracing pipeline layout), while uniforms which are local are bound to shader binding table records, which depend on the underlying runtime record indexing.

So entry-point uniform parameters (which are local to the entry point) are intentionally mapped to shader record buffers for ray tracing shaders, matching the Vulkan SBT model.

We should update the SPIR-V-specific doc to mention this exception.

[expenses]

Okay, fair enough. Is there a way to specify entry point function params as push constants in a way that works everywhere? I'd really rather avoid globals

[aidanfnv]

Unfortunately, no, there is currently no way to get push constants from entry point parameters for ray tracing shaders. There is a [[vk::push_constant]] attribute for forcing a push constant layout, but that only works on global-scope ConstantBuffer<T> declarations, and is ignored on uniforms and on entry point parameters, so it will not work for your case.