Clean up deploy script

Don't add a keyper set in the deploy script. Provide a separate script
for this instead.

Also, add a separate script to deploy the sequencer only.

Author: jannikluhn

script/addKeyperSet.s.sol

@@ -0,0 +1,67 @@
+// SPDX-License-Identifier: MIT
+pragma solidity ^0.8.20;
+
+import "forge-std/Test.sol";
+import "forge-std/Script.sol";
+import "../src/KeyperSet.sol";
+import "../src/KeyperSetManager.sol";
+
+contract AddKeyperSet is Script, Test {
+    function run() external {
+        uint256 deployKey = vm.envUint("DEPLOY_KEY");
+        address deployerAddress = vm.addr(deployKey);
+        console.log("Deployer:", deployerAddress);
+
+        address ksmAddress = vm.envAddress("KEYPER_SET_MANAGER");
+        address[] memory keypers = vm.envAddress("KEYPER_ADDRESSES", ",");
+        uint256 threshold = vm.envUint("THRESHOLD");
+        uint256 activationBlockNumber = vm.envUint("ACTIVATION_BLOCK_NUMBER");
+        uint256 activationBlockDelta = vm.envUint("ACTIVATION_BLOCK_DELTA");
+        address key_broadcaster = vm.envAddress("KEY_BROADCASTER");
+
+        uint32 size;
+        assembly {
+            size := extcodesize(ksmAddress)
+        }
+        require(size > 0, "no contract deployed at given keyper set address");
+        require(keypers.length > 0, "given keyper set is empty");
+        require(
+            threshold <= keypers.length,
+            "threshold exceeds keyper set size"
+        );
+        require(
+            activationBlockNumber > 0 || activationBlockDelta > 0,
+            "neither activation block number nor delta is given"
+        );
+        require(
+            activationBlockNumber == 0 || activationBlockDelta == 0,
+            "both activation block number and delta is given"
+        );
+        require(
+            key_broadcaster != address(0),
+            "key broadcaster is zero address"
+        );
+
+        if (activationBlockDelta > 0) {
+            activationBlockNumber = block.number + activationBlockDelta;
+        }
+
+        vm.startBroadcast(deployKey);
+        KeyperSet ks = new KeyperSet();
+        ks.addMembers(keypers);
+        ks.setThreshold(uint64(threshold));
+        ks.setKeyBroadcaster(key_broadcaster);
+        ks.setFinalized();
+
+        KeyperSetManager ksm = KeyperSetManager(ksmAddress);
+        ksm.addKeyperSet(uint64(activationBlockNumber), address(ks));
+        uint256 index = ksm.getNumKeyperSets() - 1;
+        vm.stopBroadcast();
+
+        console.log("Keyper set added at index", index);
+        console.log("Index:", index);
+        console.log("Num members:", keypers.length);
+        console.log("Threshold:", threshold);
+        console.log("Activation block number:", activationBlockNumber);
+    }
+}

script/deploy.s.sol

@@ -8,52 +8,50 @@ import "../src/KeyperSetManager.sol";
 import "../src/Sequencer.sol";
 import "../src/ValidatorRegistry.sol";
 
-contract DeployAll is Script {
-    KeyBroadcastContract public keyBroadcastContract;
-    KeyperSet public keyperSet;
-    KeyperSetManager public keyperSetManager;
-    Sequencer public sequencer;
-    ValidatorRegistry public validatorRegistry;
-
-    function deployKeyperSet() public {
-        address broadcaster = vm.envAddress("BROADCASTER");
-        keyperSet = new KeyperSet();
-        address[] memory members = new address[](3);
-        members[0] = address(1);
-        members[1] = address(2);
-        members[2] = address(3);
-        keyperSet.addMembers(members);
-        keyperSet.setKeyBroadcaster(broadcaster);
-        keyperSet.setFinalized();
-    }
+contract Deploy is Script {
+    function deployKeyperSetManager() public returns (KeyperSetManager) {
+        KeyperSetManager ksm = new KeyperSetManager();
+
+        // add bootstrap keyper set
+        KeyperSet fakeKeyperset = new KeyperSet();
+        fakeKeyperset.setFinalized();
+        ksm.addKeyperSet(0, address(fakeKeyperset));
 
-    function deployKeyperSetManager() public {
-        keyperSetManager = new KeyperSetManager();
-        keyperSetManager.addKeyperSet(0, address(keyperSet));
+        console.log("KeyperSetManager:", address(ksm));
+        return ksm;
     }
 
-    function deployKeyBroadcastContract() public {
-        keyBroadcastContract = new KeyBroadcastContract(
-            address(keyperSetManager)
-        );
+    function deployKeyBroadcastContract(
+        KeyperSetManager ksm
+    ) public returns (KeyBroadcastContract) {
+        KeyBroadcastContract kbc = new KeyBroadcastContract(address(ksm));
+        console.log("KeyBroadcastContract:", address(kbc));
+        return kbc;
     }
 
-    function deploySequencer() public {
-        sequencer = new Sequencer();
+    function deploySequencer() public returns (Sequencer) {
+        Sequencer s = new Sequencer();
+        console.log("Sequencer:", address(s));
+        return s;
     }
 
-    function deployValidatorRegistry() public {
-        validatorRegistry = new ValidatorRegistry();
+    function deployValidatorRegistry() public returns (ValidatorRegistry) {
+        ValidatorRegistry vr = new ValidatorRegistry();
+        console.log("ValidatorRegistry:", address(vr));
+        return vr;
     }
 
     function run() external {
-        uint256 deployerPrivateKey = vm.envUint("PRIVATE_KEY");
-        vm.startBroadcast(deployerPrivateKey);
-        deployKeyperSet();
-        deployKeyperSetManager();
-        deployKeyBroadcastContract();
+        uint256 deployKey = vm.envUint("DEPLOY_KEY");
+        address deployerAddress = vm.addr(deployKey);
+        console.log("Deployer:", deployerAddress);
+        vm.startBroadcast(deployKey);
+
+        KeyperSetManager ksm = deployKeyperSetManager();
+        deployKeyBroadcastContract(ksm);
         deploySequencer();
         deployValidatorRegistry();
+
         vm.stopBroadcast();
     }
 }

script/deploySequencer.s.sol

@@ -0,0 +1,33 @@
+// SPDX-License-Identifier: MIT
+pragma solidity ^0.8.20;
+
+import "forge-std/Script.sol";
+import "../src/KeyBroadcastContract.sol";
+import "../src/KeyperSet.sol";
+import "../src/KeyperSetManager.sol";
+import "../src/Sequencer.sol";
+import "../src/ValidatorRegistry.sol";
+
+contract Deploy is Script {
+    function run() external {
+        uint256 deployKey = vm.envUint("DEPLOY_KEY");
+        address deployerAddress = vm.addr(deployKey);
+        console.log("Deployer:", deployerAddress);
+        vm.startBroadcast(deployKey);
+        deploySequencer();
+        deployValidatorRegistry();
+        vm.stopBroadcast();
+    }
+
+    function deploySequencer() public returns (Sequencer) {
+        Sequencer s = new Sequencer();
+        console.log("Sequencer:", address(s));
+        return s;
+    }
+
+    function deployValidatorRegistry() public returns (ValidatorRegistry) {
+        ValidatorRegistry vr = new ValidatorRegistry();
+        console.log("ValidatorRegistry:", address(vr));
+        return vr;
+    }
+}