Trying to get the CourseCompletedNFT (contains spoils for the challenge)

[dindonero]

So I got all the course NFTs but I'm getting an execution error in the last one. I'm sure I'm missing something in my logic, but I can't figure out what.

Error:
Gas estimation errored with the following message: execution reverted

This is my contract:

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.8;

interface CourseCompletedNFT {
    function mintNft(address yourAddress, bytes4 selector) external returns (uint256);
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId
    ) external;
}

contract CourseCompleted {

    uint256 public s_variable = 0;
    uint256 public s_otherVar = 0; // same storage slots


    constructor() {
        address NFT_ADDRESS = 0x9E9a4e58dDc9483d241AfC9a028E89BD9b9fa683;
        CourseCompletedNFT nft = CourseCompletedNFT(NFT_ADDRESS);
        bytes4 functionSelector = bytes4(keccak256(bytes("doSomething()")));
        uint256 tokenId = nft.mintNft(address(this), functionSelector);
        nft.safeTransferFrom(address(this), msg.sender, tokenId);
    }

    function getOwner() external returns (address) {
        return address(this);
    }

    function doSomething() public {
        s_variable = 123;
        s_otherVar = 2;
    }

}

And this is the contract I'm trying to mint:

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.7;

import "@openzeppelin/contracts/token/ERC721/ERC721.sol";
import "base64-sol/base64.sol";
import "hardhat/console.sol";

error CourseCompletedNFT__Nope();
error VulnerableContract__Nope();
error VulnerableContract__NopeCall();
error CourseCompletedNFT__NotOwnerOfOtherContract();

interface OtherContract {
    function getOwner() external returns (address);
}

contract VulnerableContract {
    uint256 public s_variable = 0;
    uint256 public s_otherVar = 0;

    function callContract(address yourAddress) public returns (bool) {
        (bool success, ) = yourAddress.delegatecall(abi.encodeWithSignature("doSomething()"));
        require(success);
        if (s_variable != 123) {
            revert VulnerableContract__NopeCall();
        }
        s_variable = 0;
        return true;
    }

    function callContractAgain(address yourAddress, bytes4 selector) public returns (bool) {
        s_otherVar = s_otherVar + 1;
        (bool success, bytes memory returnData) = yourAddress.call(
            abi.encodeWithSelector(selector)
        );
        require(success);
        console.log(s_otherVar);
        if (s_otherVar == 2) {
            return true;
        }
        s_otherVar = 0;
        return false;
    }
}

contract CourseCompletedNFT is ERC721 {
    string public constant TOKEN_IMAGE_URI =
        "ipfs://QmeHo8yoogtNC1aajU6Bn8HEWTGjfv8m7m8ZdDDUzNBXij";
    uint256 private s_tokenCounter;
    uint256 private s_otherVar;
    VulnerableContract private s_vulnerableContract;

    constructor(address vulnerableContractAddress)
        ERC721("Patrick's Hardhat FreeCodeCamp Javascript Tutorial | Course Completed", "PHFCC")
    {
        s_tokenCounter = 0;
        s_vulnerableContract = VulnerableContract(vulnerableContractAddress);
    }

    function mintNft(address yourAddress, bytes4 selector) public returns (uint256) {
        if (OtherContract(yourAddress).getOwner() != msg.sender) {
            revert CourseCompletedNFT__NotOwnerOfOtherContract();
        }
        bool returnedOne = s_vulnerableContract.callContract(yourAddress);
        bool returnedTwo = s_vulnerableContract.callContractAgain(yourAddress, selector);

        if (!returnedOne && !returnedTwo) {
            revert CourseCompletedNFT__Nope();
        }

        _safeMint(msg.sender, s_tokenCounter);
        s_tokenCounter = s_tokenCounter + 1;
        return s_tokenCounter;
    }
}

[dindonero]

2nd answer:
https://ethereum.stackexchange.com/questions/29469/is-addressthis-a-valid-address-in-a-contracts-constructor

This contract doesn't work because

Note that while the initialisation code is executing, the newly created address exists but with no intrinsic body code.

So as it tries to call back getOwner from my contract, it fails.

[dindonero]

You'll also need to implement the IERC721Receiver on the contract and the token_counter gets incremented after the mint and before the return so watch out about that.