Lesson7,:TypeError: Wrong argument count for function call: 0 arguments given but expected 1.

[Maakai123]

I tried compiling both my FundMe and PriceConverter contracts, then am getting this error message
TypeError: Wrong argument count for function call: 0 arguments given but expected 1.
--> contracts/FundMe.sol:24:17:
|
24 | require(msg.value.getConversionRate() >= MINIMUM_USD, "You need to spend more ETH!");
| ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^

Error HH600: Compilation failed

These are my contracts

FundMe.sol

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.8;

import "@chainlink/contracts/src/v0.8/interfaces/AggregatorV3Interface.sol";
import "./PriceConverter.sol";

error NotOwner();

contract FundMe {
    using PriceConverter for uint256;

    mapping(address => uint256) public addressToAmountFunded;
    address[] public funders;

    // Could we make this constant?  /* hint: no! We should make it immutable! */
    address public /* immutable */ i_owner;
    uint256 public constant MINIMUM_USD = 50 * 10 ** 18;
    
    constructor() {
        i_owner = msg.sender;
    }

    function fund() public payable {
        require(msg.value.getConversionRate() >= MINIMUM_USD, "You need to spend more ETH!");
        //require(PriceConverter.getConversionRate(msg.value) >= MINIMUM_USD, "You need to spend more ETH!");
        addressToAmountFunded[msg.sender] += msg.value;
        funders.push(msg.sender);
    }
    
    function getVersion() public view returns (uint256){
        AggregatorV3Interface priceFeed = AggregatorV3Interface(0x8A753747A1Fa494EC906cE90E9f37563A8AF630e);
        return priceFeed.version();
    }
    
    modifier onlyOwner {
        // require(msg.sender == owner);
        if (msg.sender != i_owner) revert NotOwner();
        _;
    }
    
    function withdraw() payable onlyOwner public {
        for (uint256 funderIndex=0; funderIndex < funders.length; funderIndex++){
            address funder = funders[funderIndex];
            addressToAmountFunded[funder] = 0;
        }
        funders = new address[](0);
        // // transfer
        // payable(msg.sender).transfer(address(this).balance);
        // // send
        // bool sendSuccess = payable(msg.sender).send(address(this).balance);
        // require(sendSuccess, "Send failed");
        // call
        (bool callSuccess, ) = payable(msg.sender).call{value: address(this).balance}("");
        require(callSuccess, "Call failed");
    }
    // Explainer from: https://solidity-by-example.org/fallback/
    // Ether is sent to contract
    //      is msg.data empty?
    //          /   \ 
    //         yes  no
    //         /     \
    //    receive()?  fallback() 
    //     /   \ 
    //   yes   no
    //  /        \
    //receive()  fallback()

    fallback() external payable {
        fund();
    }

    receive() external payable {
        fund();
    }

}

// Concepts we didn't cover yet (will cover in later sections)
// 1. Enum
// 2. Events
// 3. Try / Catch
// 4. Function Selector
// 5. abi.encode / decode
// 6. Hash with keccak256
// 7. Yul / Assembly

PriceConverter.sol

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;

import "@chainlink/contracts/src/v0.8/interfaces/AggregatorV3Interface.sol";

library PriceConverter {
  function getPrice(AggregatorV3Interface priceFeed)
    internal
    view
    returns (uint256)
  {
    (, int256 answer, , , ) = priceFeed.latestRoundData();
    // ETH/USD rate in 18 digit
    return uint256(answer * 10000000000);
  }

  // 1000000000
  // call it get fiatConversionRate, since it assumes something about decimals
  // It wouldn't work for every aggregator
  function getConversionRate(uint256 ethAmount, AggregatorV3Interface priceFeed)
    internal
    view
    returns (uint256)
  {
    uint256 ethPrice = getPrice(priceFeed);
    uint256 ethAmountInUsd = (ethPrice * ethAmount) / 1000000000000000000;
    // the actual ETH/USD conversation rate, after adjusting the extra 0s.
    return ethAmountInUsd;
  }
}

please I need help

[alymurtazamemon]

@Maakai123 getConversionRate methods required two parameters eth amount and price feed address, you are passing eth amount with msg.value but you are not giving price feed address in the parameter.

msg.value.getConversionRate()

And I have formatted your questions so others can easily read it. If you want to convey you problem properly to others so they can help. You should follow the how to ask a question guide?.

[alymurtazamemon]

@Maakai123 For now just pass it like this:

msg.value.getConversionRate(AggregatorV3Interface(0x8A753747A1Fa494EC906cE90E9f37563A8AF630e))

your price converter contract is perfectly set. Just pass it and see if your issue is resolved or not.

This is just a workaround for now, but because you are on lesson 7 and in this lesson you have to pass this address through the constructor so you can deploy it locally also, for that watch lesson 7.

[alymurtazamemon]

@Maakai123 For lesson 7 work is totally different so telling here how to pass address is somehow difficult, it would be better to watch lesson 7.

[Maakai123]

Finally @ali-thegilfoyle you are a life saver, please am new to blockchain, can you just explain msg.value.getConversionRate(AggregatorV3Interface(0x8A753747A1Fa494EC906cE90E9f37563A8AF630e)) to me, and help me with resources or pages i can read and Master solidity
Thank you so much, am following you Github immediatedly,

[alymurtazamemon]

@Maakai123 In the price converter contract, you are using an AggregatorV3Interface for getting the current price of Ethereum that in the getConversionRate method you convert to Wei.

Now this price feed data comes from the Chaillink data feed so in order to tell the Chainlink about the network, we are passing a Rinkeby address for ETH/USD price data.

I know it will not make sense to you right now because I think you did not watch lesson 4.

[Maakai123]

OK, Thank you so much