feat: add minimalistic Vegetables replacement

This commit adds module/submodule pairs defining an abstract test_t
type and a non-abstract test_result_t type that encapsulate test
methods and results-reporting.

Author: rouson

src/test_m.F90

@@ -0,0 +1,44 @@
+module test_m
+  !! Define an abstract test_t type with deferred bindings ("subject" and "results")
+  !! used by a type-bound procedure ("report") for reporting test results.  The "report"
+  !! procedure thus represents an implementation of the Template Method pattern.
+  use test_result_m, only : test_result_t
+  implicit none
+
+  private
+  public :: test_t
+
+  type, abstract :: test_t
+    !! Facilitate testing and test reporting
+  contains
+    procedure(subject_interface), nopass, deferred :: subject 
+    procedure(results_interface), nopass, deferred :: results
+    procedure :: report
+  end type
+
+  abstract interface
+
+    pure function subject_interface() result(specimen)
+      !! The result is the name of the test specimen (the subject of testing)
+      character(len=:), allocatable :: specimen
+    end function
+
+    function results_interface() result(test_results)
+      !! The result is an array of test outcomes for reporting
+      import test_result_t
+      type(test_result_t), allocatable :: test_results(:)
+    end function
+
+  end interface
+
+  interface
+
+    module subroutine report(test)
+      !! Report test results
+      implicit none
+      class(test_t), intent(in) :: test
+    end subroutine
+
+  end interface
+
+end module test_m

src/test_result_m.f90

@@ -0,0 +1,40 @@
+module test_result_m
+  !! Define an abstraction for describing test intentions and results
+  implicit none
+
+  private
+  public :: test_result_t
+
+  type test_result_t
+    !! Encapsulate test descriptions and outcomes and reporting
+    private
+    character(len=:), allocatable :: description_
+    logical outcome_
+  contains
+    procedure :: characterize
+  end type
+
+  interface test_result_t
+
+    pure module function construct(description, outcome) result(test_result)
+      !! The result is a test_result_t object with the components defined by the dummy arguments
+      implicit none
+      character(len=*), intent(in) :: description
+      logical, intent(in) :: outcome
+      type(test_result_t) test_result 
+    end function
+
+  end interface
+
+  interface
+
+    pure module function characterize(self) result(characterization)
+      !! The result is a character test description and its outcome
+      implicit none
+      class(test_result_t), intent(in) :: self
+      character(len=:), allocatable :: characterization
+    end function
+
+  end interface
+
+end module test_result_m

src/test_result_s.f90

@@ -0,0 +1,15 @@
+submodule(test_result_m) test_result_s
+  implicit none
+
+contains
+
+    module procedure construct
+      test_result%description_ = description
+      test_result%outcome_ = outcome
+    end procedure
+
+    module procedure characterize
+      characterization = merge("Pass: ", "Fail: ", self%outcome_) // self%description_
+    end procedure
+
+end submodule test_result_s

src/test_s.F90

@@ -0,0 +1,29 @@
+submodule(test_m) test_s
+#ifdef XLF
+  use test_result_m, only : test_result_t
+#endif
+  implicit none
+
+contains
+
+  module procedure report
+    integer i
+#ifdef XLF
+    type(test_result_t), allocatable :: test_results(:)
+    test_results = test%results()
+#else
+    associate(test_results => test%results())
+#endif
+
+      print *
+      print *, test%subject()
+
+      do i=1,size(test_results)
+        print *,"  ",test_results(i)%characterize()
+      end do
+#ifndef XLF
+    end associate
+#endif
+  end procedure
+
+end submodule test_s