Added the OLA_IMU_Basics test sketch

Author: PaulZC

Firmware/Test Sketches/OLA_IMU_Basics/OLA_IMU_Basics.ino

@@ -0,0 +1,229 @@
+/****************************************************************
+ * Testing basic functionality of the ICM 20948 on the OpenLog Artemis.
+ * Select "SparkFun Apollo3" \ SparkFun RedBoard Artemis ATP" as the board.
+ * 
+ * Based on:
+ * 
+ * Example1_Basics.ino
+ * ICM 20948 Arduino Library Demo 
+ * Use the default configuration to stream 9-axis IMU data
+ * Owen Lyke @ SparkFun Electronics
+ * Original Creation Date: April 17 2019
+ * 
+ * This code is beerware; if you see me (or any other SparkFun employee) at the
+ * local, and you've found our code helpful, please buy us a round!
+ * 
+ * Distributed as-is; no warranty is given.
+ ***************************************************************/
+
+// OLA Specifics:
+const byte PIN_IMU_POWER = 27; // The Red SparkFun version of the OLA (V10) uses pin 27
+//const byte PIN_IMU_POWER = 22; // The Black SparkX version of the OLA (X04) uses pin 22
+const byte PIN_IMU_INT = 37;
+const byte PIN_IMU_CHIP_SELECT = 44;
+
+
+#include "ICM_20948.h"  // Click here to get the library: http://librarymanager/All#SparkFun_ICM_20948_IMU
+
+#define USE_SPI       // Uncomment this to use SPI
+
+#define SERIAL_PORT Serial
+
+#define SPI_PORT SPI    // Your desired SPI port.       Used only when "USE_SPI" is defined
+#define CS_PIN PIN_IMU_CHIP_SELECT // Which pin you connect CS to. Used only when "USE_SPI" is defined. OLA uses pin 44.
+
+#define WIRE_PORT Wire  // Your desired Wire port.      Used when "USE_SPI" is not defined
+#define AD0_VAL   1     // The value of the last bit of the I2C address. 
+                        // On the SparkFun 9DoF IMU breakout the default is 1, and when 
+                        // the ADR jumper is closed the value becomes 0
+
+#ifdef USE_SPI
+  ICM_20948_SPI myICM;  // If using SPI create an ICM_20948_SPI object
+#else
+  ICM_20948_I2C myICM;  // Otherwise create an ICM_20948_I2C object
+#endif
+
+
+void setup() {
+
+#ifdef USE_SPI
+    SPI_PORT.begin();
+#else
+    WIRE_PORT.begin();
+    WIRE_PORT.setClock(400000);
+#endif
+  
+  enableCIPOpullUp(); // Enable CIPO pull-up on the OLA
+
+  pinMode(PIN_IMU_CHIP_SELECT, OUTPUT);
+  digitalWrite(PIN_IMU_CHIP_SELECT, HIGH); //Be sure IMU is deselected
+
+  //Reset ICM by power cycling it
+  imuPowerOff();
+
+  delay(10);
+
+  imuPowerOn(); // Enable power for the OLA IMU
+
+  delay(100); // Wait for the IMU to power up
+
+  SERIAL_PORT.begin(115200);
+  while(!SERIAL_PORT){};
+
+  bool initialized = false;
+  while( !initialized ){
+
+#ifdef USE_SPI
+    myICM.begin( CS_PIN, SPI_PORT ); 
+#else
+    myICM.begin( WIRE_PORT, AD0_VAL );
+#endif
+
+    SERIAL_PORT.print( F("Initialization of the sensor returned: ") );
+    SERIAL_PORT.println( myICM.statusString() );
+    if( myICM.status != ICM_20948_Stat_Ok ){
+      SERIAL_PORT.println( "Trying again..." );
+      delay(500);
+    }else{
+      initialized = true;
+    }
+  }
+}
+
+void loop() {
+
+  if( myICM.dataReady() ){
+    myICM.getAGMT();                // The values are only updated when you call 'getAGMT'
+//    printRawAGMT( myICM.agmt );     // Uncomment this to see the raw values, taken directly from the agmt structure
+    printScaledAGMT( myICM.agmt);   // This function takes into account the sclae settings from when the measurement was made to calculate the values with units
+    delay(30);
+  }else{
+    Serial.println("Waiting for data");
+    delay(500);
+  }
+  
+}
+
+
+// Below here are some helper functions to print the data nicely!
+
+void printPaddedInt16b( int16_t val ){
+  if(val > 0){
+    SERIAL_PORT.print(" ");
+    if(val < 10000){ SERIAL_PORT.print("0"); }
+    if(val < 1000 ){ SERIAL_PORT.print("0"); }
+    if(val < 100  ){ SERIAL_PORT.print("0"); }
+    if(val < 10   ){ SERIAL_PORT.print("0"); }
+  }else{
+    SERIAL_PORT.print("-");
+    if(abs(val) < 10000){ SERIAL_PORT.print("0"); }
+    if(abs(val) < 1000 ){ SERIAL_PORT.print("0"); }
+    if(abs(val) < 100  ){ SERIAL_PORT.print("0"); }
+    if(abs(val) < 10   ){ SERIAL_PORT.print("0"); }
+  }
+  SERIAL_PORT.print(abs(val));
+}
+
+void printRawAGMT( ICM_20948_AGMT_t agmt){
+  SERIAL_PORT.print("RAW. Acc [ ");
+  printPaddedInt16b( agmt.acc.axes.x );
+  SERIAL_PORT.print(", ");
+  printPaddedInt16b( agmt.acc.axes.y );
+  SERIAL_PORT.print(", ");
+  printPaddedInt16b( agmt.acc.axes.z );
+  SERIAL_PORT.print(" ], Gyr [ ");
+  printPaddedInt16b( agmt.gyr.axes.x );
+  SERIAL_PORT.print(", ");
+  printPaddedInt16b( agmt.gyr.axes.y );
+  SERIAL_PORT.print(", ");
+  printPaddedInt16b( agmt.gyr.axes.z );
+  SERIAL_PORT.print(" ], Mag [ ");
+  printPaddedInt16b( agmt.mag.axes.x );
+  SERIAL_PORT.print(", ");
+  printPaddedInt16b( agmt.mag.axes.y );
+  SERIAL_PORT.print(", ");
+  printPaddedInt16b( agmt.mag.axes.z );
+  SERIAL_PORT.print(" ], Tmp [ ");
+  printPaddedInt16b( agmt.tmp.val );
+  SERIAL_PORT.print(" ]");
+  SERIAL_PORT.println();
+}
+
+
+void printFormattedFloat(float val, uint8_t leading, uint8_t decimals){
+  float aval = abs(val);
+  if(val < 0){
+    SERIAL_PORT.print("-");
+  }else{
+    SERIAL_PORT.print(" ");
+  }
+  for( uint8_t indi = 0; indi < leading; indi++ ){
+    uint32_t tenpow = 0;
+    if( indi < (leading-1) ){
+      tenpow = 1;
+    }
+    for(uint8_t c = 0; c < (leading-1-indi); c++){
+      tenpow *= 10;
+    }
+    if( aval < tenpow){
+      SERIAL_PORT.print("0");
+    }else{
+      break;
+    }
+  }
+  if(val < 0){
+    SERIAL_PORT.print(-val, decimals);
+  }else{
+    SERIAL_PORT.print(val, decimals);
+  }
+}
+
+void printScaledAGMT( ICM_20948_AGMT_t agmt){
+  SERIAL_PORT.print("Scaled. Acc (mg) [ ");
+  printFormattedFloat( myICM.accX(), 5, 2 );
+  SERIAL_PORT.print(", ");
+  printFormattedFloat( myICM.accY(), 5, 2 );
+  SERIAL_PORT.print(", ");
+  printFormattedFloat( myICM.accZ(), 5, 2 );
+  SERIAL_PORT.print(" ], Gyr (DPS) [ ");
+  printFormattedFloat( myICM.gyrX(), 5, 2 );
+  SERIAL_PORT.print(", ");
+  printFormattedFloat( myICM.gyrY(), 5, 2 );
+  SERIAL_PORT.print(", ");
+  printFormattedFloat( myICM.gyrZ(), 5, 2 );
+  SERIAL_PORT.print(" ], Mag (uT) [ ");
+  printFormattedFloat( myICM.magX(), 5, 2 );
+  SERIAL_PORT.print(", ");
+  printFormattedFloat( myICM.magY(), 5, 2 );
+  SERIAL_PORT.print(", ");
+  printFormattedFloat( myICM.magZ(), 5, 2 );
+  SERIAL_PORT.print(" ], Tmp (C) [ ");
+  printFormattedFloat( myICM.temp(), 5, 2 );
+  SERIAL_PORT.print(" ]");
+  SERIAL_PORT.println();
+}
+
+void imuPowerOn()
+{
+  pinMode(PIN_IMU_POWER, OUTPUT);
+  digitalWrite(PIN_IMU_POWER, HIGH);
+}
+void imuPowerOff()
+{
+  pinMode(PIN_IMU_POWER, OUTPUT);
+  digitalWrite(PIN_IMU_POWER, LOW);
+}
+
+bool enableCIPOpullUp()
+{
+  //Add CIPO pull-up
+  ap3_err_t retval = AP3_OK;
+  am_hal_gpio_pincfg_t cipoPinCfg = AP3_GPIO_DEFAULT_PINCFG;
+  cipoPinCfg.uFuncSel = AM_HAL_PIN_6_M0MISO;
+  cipoPinCfg.eDriveStrength = AM_HAL_GPIO_PIN_DRIVESTRENGTH_12MA;
+  cipoPinCfg.eGPOutcfg = AM_HAL_GPIO_PIN_OUTCFG_PUSHPULL;
+  cipoPinCfg.uIOMnum = AP3_SPI_IOM;
+  cipoPinCfg.ePullup = AM_HAL_GPIO_PIN_PULLUP_1_5K;
+  padMode(MISO, cipoPinCfg, &retval);
+  return (retval == AP3_OK);
+}