Extract more build logic into Convention Plugin

Author: beatbrot

build-logic/base/src/main/groovy/org/spockframework/gradle/SpockBasePlugin.groovy

@@ -19,23 +19,42 @@ package org.spockframework.gradle
 import groovy.transform.CompileStatic
 import org.gradle.api.Plugin
 import org.gradle.api.Project
+import org.gradle.api.artifacts.VersionCatalogsExtension
+import org.gradle.api.plugins.ExtraPropertiesExtension
 import org.gradle.api.plugins.JavaPlugin
+import org.gradle.api.tasks.SourceSetContainer
+import org.gradle.api.tasks.bundling.Jar
 import org.gradle.api.tasks.compile.GroovyCompile
 import org.gradle.api.tasks.compile.JavaCompile
+import org.gradle.api.tasks.diagnostics.DependencyInsightReportTask
 import org.gradle.api.tasks.testing.Test
 import org.gradle.jvm.toolchain.JavaLanguageVersion
 import org.gradle.jvm.toolchain.JavaToolchainService
+import org.gradle.testing.jacoco.plugins.JacocoPluginExtension
 import org.jetbrains.annotations.VisibleForTesting
 
+import java.time.Duration
+
 @CompileStatic
 class SpockBasePlugin implements Plugin<Project> {
 
   @VisibleForTesting
   public static final JavaLanguageVersion COMPILER_VERSION = JavaLanguageVersion.of(8)
 
   void apply(Project project) {
+    applyPlugins(project)
     compileTasks(project)
+    jarTasks(project)
     testTasks(project)
+    jacoco(project)
+    dependencyInsight(project)
+  }
+
+  static void applyPlugins(Project project) {
+    def plugins = project.plugins
+    plugins.apply("java-library")
+    plugins.apply("groovy")
+    plugins.apply("jacoco")
   }
 
   private static void compileTasks(Project project) {
@@ -55,13 +74,63 @@ class SpockBasePlugin implements Plugin<Project> {
     }
   }
 
+  private static void jarTasks(Project project) {
+    project.tasks.withType(Jar).configureEach { jar ->
+      /*
+       * Ensure the jar can be built in a reproducible manner, This shall prevent build cache misses, when different variants are tested.
+       */
+      jar.preserveFileTimestamps = false
+      jar.reproducibleFileOrder = true
+    }
+
+    def sourceSets = project.extensions.getByType(SourceSetContainer)
+    project.tasks.register("sourcesJar", Jar) {
+      it.archiveClassifier.set("sources")
+      it.from(sourceSets.named("main").map { it.allSource })
+    }
+
+    project.tasks.register("javadocJar", Jar) {
+      it.archiveClassifier.set("javadoc")
+      it.from(project.tasks.named("javadoc"))
+    }
+  }
+
   private static void testTasks(Project project) {
     project.tasks.withType(Test).configureEach { task ->
+      task.useJUnitPlatform()
       def taskName = task.name.capitalize()
+      def variant = project.rootProject.extensions.getByType(ExtraPropertiesExtension)
+        .get("variant")
+
+      def junitXml = task.reports.junitXml
+      junitXml.outputLocation.set(project.file("${junitXml.outputLocation.get()}/$taskName-$variant"))
+      def html = task.reports.html
+      html.outputLocation.set(project.file("${html.outputLocation.get()}/$taskName-$variant"))
+
+      // As a generous general timeout, instead of the 6h of GHA.
+      // But only on CI or longer needing debug sessions get killed by the timeout.
+      boolean isCiServer = System.getenv("CI") || System.getenv("GITHUB_ACTIONS")
+      if (isCiServer) {
+        task.timeout.set(Duration.ofMinutes(15))
+      }
+
       File configFile = project.file("Spock${taskName}Config.groovy")
       if (configFile.exists()) {
         task.jvmArgumentProviders.add(new SpockConfigArgumentProvider(configFile))
       }
     }
   }
+
+  private static void jacoco(Project project) {
+    // For tests, we have to handle the case where version catalogs are not present
+    project.rootProject.extensions.findByType(VersionCatalogsExtension)?.find("libs")
+      ?.flatMap { it.findVersion("jacoco") }
+      ?.ifPresent { version ->
+        project.extensions.getByType(JacocoPluginExtension).toolVersion = version.toString()
+      }
+  }
+
+  private static void dependencyInsight(Project project) {
+    project.tasks.register("allDependencyInsight", DependencyInsightReportTask)
+  }
 }

build-logic/base/src/test/groovy/org/spockframework/gradle/SpockBasePluginSpec.groovy

@@ -1,8 +1,10 @@
+//file:noinspection ConfigurationAvoidance
 package org.spockframework.gradle
 
 import org.gradle.api.Project
 import org.gradle.api.plugins.JavaPlugin
 import org.gradle.api.tasks.compile.JavaCompile
+import org.gradle.jvm.tasks.Jar
 import org.gradle.testfixtures.ProjectBuilder
 import spock.lang.Specification
 
@@ -21,11 +23,23 @@ class SpockBasePluginSpec extends Specification {
     compileJava.javaCompiler.get().metadata.languageVersion == SpockBasePlugin.COMPILER_VERSION
   }
 
+  def "Jar settings are configured"() {
+    setup:
+    def project = createProject()
+
+    when:
+    def jarTasks = project.tasks.withType(Jar)
+
+    then:
+    jarTasks.every { it.reproducibleFileOrder }
+    jarTasks.every { !it.preserveFileTimestamps }
+    project.tasks.findByName("sourcesJar") != null
+    project.tasks.findByName("javadocJar") != null
+  }
+
   private static Project createProject() {
     def result = ProjectBuilder.builder()
       .build()
-    result.plugins.apply("java-library")
-    result.plugins.apply("groovy")
     result.plugins.apply(SpockBasePlugin)
     return result
   }

build.gradle

@@ -85,8 +85,6 @@ allprojects {
   group = "org.spockframework"
   version = fullVersion
 
-  apply from: script("common")
-
   // ignore mutable data that is irrelevant for compilation output
   normalization {
     runtimeClasspath {
@@ -99,11 +97,7 @@ allprojects {
 
 apply from: script("ide")
 
-boolean isCiServer = System.env["CI"] || System.env["GITHUB_ACTIONS"]
 subprojects {
-  apply plugin: "java-library"
-  apply plugin: "groovy"
-  apply plugin: "jacoco"
   apply plugin: "org.spockframework.base"
 
   java {
@@ -165,48 +159,6 @@ subprojects {
 
   configureJavadoc(tasks.named("javadoc"))
   configureGroovydoc(tasks.named("groovydoc"))
-
-  tasks.register("sourcesJar", Jar) {
-    archiveClassifier = "sources"
-    from sourceSets.main.allSource
-  }
-
-  tasks.register("javadocJar", Jar) {
-    archiveClassifier = "javadoc"
-    from javadoc
-  }
-
-  tasks.withType(Jar).configureEach {
-    /*
-     * Ensure the jar can be built in a reproducible manner, This shall prevent build cache misses, when different variants are tested.
-     */
-    preserveFileTimestamps = false
-    reproducibleFileOrder = true
-  }
-
-  tasks.withType(Test).configureEach {
-    useJUnitPlatform()
-    def taskName = name
-    reports {
-      junitXml {
-        outputLocation = file("${outputLocation.get()}/$taskName-$variant")
-      }
-      html {
-        outputLocation = file("${outputLocation.get()}/$taskName-$variant")
-      }
-    }
-    // As a generous general timeout, instead of the 6h of GHA.
-    // But only on CI or longer needing debug sessions get killed by the timeout.
-    if (isCiServer) {
-      timeout = Duration.ofMinutes(15)
-    }
-  }
-
-  tasks.register("allDependencyInsight", DependencyInsightReportTask) {}
-
-  jacoco {
-    toolVersion = libs.versions.jacoco.get()
-  }
 }
 
 tasks.register("collectTestXml") {