Added edit action specification tests

Author: dilipkrish

springfox-grails/src/main/java/springfox/documentation/grails/EditActionSpecificationFactory.java

@@ -31,7 +31,7 @@ public ActionSpecification create(GrailsActionContext context) {
         handlerMethod,
         new ArrayList<>(Arrays.asList(
             pathParameter(1, "id", resolver.resolve(idType(context.getDomainClass()))),
-            bodyParameter(1, resolver.resolve(domainClass(context.getDomainClass()))))),
+            bodyParameter(2, resolver.resolve(domainClass(context.getDomainClass()))))),
         resolver.resolve(domainClass(context.getDomainClass())));
 
   }

springfox-grails/src/test/groovy/springfox/documentation/grails/EditActionSpecificationFactorySpec.groovy

@@ -0,0 +1,58 @@
+package springfox.documentation.grails
+
+import com.fasterxml.classmate.TypeResolver
+import grails.core.GrailsControllerClass
+import grails.core.GrailsDomainClass
+import grails.core.GrailsDomainClassProperty
+import org.springframework.http.MediaType
+import org.springframework.web.bind.annotation.RequestMethod
+import spock.lang.Specification
+
+class EditActionSpecificationFactorySpec extends Specification {
+  def controller = Mock(GrailsControllerClass)
+  def domain = Mock(GrailsDomainClass)
+  def identifierProperty = Mock(GrailsDomainClassProperty)
+
+  def setup() {
+    controller.clazz >> AController
+    domain.clazz >> ADomain
+    domain.identifier >> identifierProperty
+    domain.identifier.type >> Integer
+  }
+
+  def "Create action produces action specification" () {
+    given:
+      def resolver = new TypeResolver()
+      def sut = new EditActionSpecificationFactory(resolver)
+    when:
+      def spec = sut.create(new GrailsActionContext(controller, domain, "update"))
+    then:
+      spec.consumes == [MediaType.APPLICATION_JSON] as Set
+      spec.produces == [MediaType.APPLICATION_JSON] as Set
+      spec.supportedMethods == [RequestMethod.PUT, RequestMethod.POST] as Set
+      spec.parameters.size() == 2
+      spec.parameters[0].parameterType == resolver.resolve(Integer)
+      spec.parameters[0].parameterIndex == 1
+      spec.parameters[0].defaultName().isPresent()
+      spec.parameters[0].defaultName().get() == "id"
+
+      spec.parameters[1].parameterType == resolver.resolve(ADomain)
+      spec.parameters[1].parameterIndex == 2
+      spec.parameters[1].defaultName().isPresent()
+      spec.parameters[1].defaultName().get() == "body"
+
+      spec.returnType == resolver.resolve(ADomain)
+      spec.handlerMethod.method == AController.methods.find {it.name == "update" }
+  }
+
+  def "Index action throws exception when action is not found" () {
+    given:
+      def resolver = new TypeResolver()
+      def sut = new EditActionSpecificationFactory(resolver)
+    when:
+      sut.create(new GrailsActionContext(controller, domain, "unknown"))
+    then:
+      def exception = thrown(NullPointerException)
+      exception.message.contains("Handler method is null")
+  }
+}