test: add get stakers delegation undelegation flow

Author: arad-starkware

workspace/apps/staking/contracts/src/flow_test/flow_ideas.md

@@ -1,6 +1,5 @@
 # Flow Ideas
 ## `get_stakers`
-- Undelegate, get stakers.
 - Enable / disable tokens, get stakers.
 - Stake, get stakers, increase stake, get stakers.
 - Stake with delegation, get stakers, switch pool, get stakers.

workspace/apps/staking/contracts/src/flow_test/test.cairo

@@ -2093,3 +2093,152 @@ fn get_stakers_delegation_flow_test() {
         .span();
     assert!(stakers == expected_stakers);
 }
+
+/// Flow:
+/// Staker 1 stake
+/// Staker 2 stake
+/// Advance K epochs
+/// Delegator delegate to staker 1
+/// Test get_stakers next few epochs
+/// Delegator undelegate intent partial amount
+/// Test get_stakers next few epochs
+/// Delegator undelegate action
+/// Test get_stakers next few epochs
+/// Delegator undelegate intent full amount
+/// Test get_stakers next few epochs
+/// Delegator undelegate action
+/// Test get_stakers next few epochs
+#[test]
+fn get_stakers_delegation_undelegation_flow_test() {
+    let cfg: StakingInitConfig = Default::default();
+    let mut system = SystemConfigTrait::basic_stake_flow_cfg(:cfg).deploy();
+    let stake_amount = system.staking.get_min_stake();
+    let strk_delegation_amount = STRK_CONFIG.min_for_rewards * 3;
+    let staker_1 = system.new_staker(amount: stake_amount);
+    let staker_2 = system.new_staker(amount: stake_amount);
+    let delegator = system.new_delegator(amount: strk_delegation_amount);
+    let staking_consensus = system.staking.consensus_dispatcher();
+
+    // Stake and delegate
+    system.stake(staker: staker_1, amount: stake_amount, pool_enabled: true, commission: 200);
+    system.stake(staker: staker_2, amount: stake_amount, pool_enabled: false, commission: 200);
+    let strk_pool = system.staking.get_pool(staker: staker_1);
+    system.advance_k_epochs();
+    system.delegate(:delegator, pool: strk_pool, amount: strk_delegation_amount);
+
+    // Test current epoch.
+    let stakers = staking_consensus.get_stakers(epoch_id: system.staking.get_current_epoch());
+    let expected_stakers = array![
+        (staker_1.staker.address, STRK_WEIGHT_FACTOR / 2, Option::None),
+        (staker_2.staker.address, STRK_WEIGHT_FACTOR / 2, Option::None),
+    ]
+        .span();
+    assert!(stakers == expected_stakers);
+
+    // Test after K epochs.
+    system.advance_k_epochs();
+    let stakers = staking_consensus.get_stakers(epoch_id: system.staking.get_current_epoch());
+    let expected_stakers = array![
+        (
+            staker_1.staker.address,
+            mul_wide_and_div(
+                lhs: STRK_WEIGHT_FACTOR,
+                rhs: stake_amount + strk_delegation_amount,
+                div: stake_amount * 2 + strk_delegation_amount,
+            )
+                .unwrap(),
+            Option::None,
+        ),
+        (
+            staker_2.staker.address,
+            mul_wide_and_div(
+                lhs: STRK_WEIGHT_FACTOR,
+                rhs: stake_amount,
+                div: stake_amount * 2 + strk_delegation_amount,
+            )
+                .unwrap(),
+            Option::None,
+        ),
+    ]
+        .span();
+    assert!(stakers == expected_stakers);
+
+    // Undelegate partial amount
+    system.delegator_exit_intent(:delegator, pool: strk_pool, amount: strk_delegation_amount / 3);
+
+    // Test current epoch.
+    let stakers = staking_consensus.get_stakers(epoch_id: system.staking.get_current_epoch());
+    assert!(stakers == expected_stakers);
+
+    // Test after K epochs.
+    system.advance_k_epochs();
+    let stakers = staking_consensus.get_stakers(epoch_id: system.staking.get_current_epoch());
+    let expected_stakers = array![
+        (
+            staker_1.staker.address,
+            mul_wide_and_div(
+                lhs: STRK_WEIGHT_FACTOR,
+                rhs: stake_amount + strk_delegation_amount * 2 / 3,
+                div: stake_amount * 2 + strk_delegation_amount * 2 / 3,
+            )
+                .unwrap(),
+            Option::None,
+        ),
+        (
+            staker_2.staker.address,
+            mul_wide_and_div(
+                lhs: STRK_WEIGHT_FACTOR,
+                rhs: stake_amount,
+                div: stake_amount * 2 + strk_delegation_amount * 2 / 3,
+            )
+                .unwrap(),
+            Option::None,
+        ),
+    ]
+        .span();
+    assert!(stakers == expected_stakers);
+
+    // Undelegate action
+    system.advance_exit_wait_window();
+    system.delegator_exit_action(:delegator, pool: strk_pool);
+
+    // Test current epoch.
+    let stakers = staking_consensus.get_stakers(epoch_id: system.staking.get_current_epoch());
+    assert!(stakers == expected_stakers);
+
+    // Test after K epochs.
+    system.advance_k_epochs();
+    let stakers = staking_consensus.get_stakers(epoch_id: system.staking.get_current_epoch());
+    assert!(stakers == expected_stakers);
+
+    // Undelegate full amount
+    system
+        .delegator_exit_intent(:delegator, pool: strk_pool, amount: strk_delegation_amount * 2 / 3);
+
+    // Test current epoch.
+    let stakers = staking_consensus.get_stakers(epoch_id: system.staking.get_current_epoch());
+    assert!(stakers == expected_stakers);
+
+    // Test after K epochs.
+    system.advance_k_epochs();
+    let stakers = staking_consensus.get_stakers(epoch_id: system.staking.get_current_epoch());
+    let expected_stakers = array![
+        (staker_1.staker.address, STRK_WEIGHT_FACTOR / 2, Option::None),
+        (staker_2.staker.address, STRK_WEIGHT_FACTOR / 2, Option::None),
+    ]
+        .span();
+    assert!(stakers == expected_stakers);
+
+    // Undelegate action
+    system.advance_exit_wait_window();
+    system.delegator_exit_action(:delegator, pool: strk_pool);
+
+    // Test current epoch.
+    let stakers = staking_consensus.get_stakers(epoch_id: system.staking.get_current_epoch());
+    assert!(stakers == expected_stakers);
+
+    // Test after K epochs.
+    system.advance_k_epochs();
+    let stakers = staking_consensus.get_stakers(epoch_id: system.staking.get_current_epoch());
+    assert!(stakers == expected_stakers);
+}