feat(trogon_commanded): add is_object_id/1 guard (#329)

Signed-off-by: Yordis Prieto <yordis.prieto@gmail.com>

Author: yordis

apps/trogon_commanded/lib/trogon/commanded/object_id.ex

@@ -60,6 +60,23 @@ defmodule Trogon.Commanded.ObjectId do
   alias Trogon.Commanded.ProtoExtension
   alias TrogonProto.ObjectId.V1Alpha1.EnumValueOptions, as: ObjectIdEnumValueOptions
 
+  @doc """
+  Returns true if `term` is an ObjectId struct; otherwise returns false.
+
+  Allowed in guard tests.
+
+  ## Examples
+
+      iex> is_object_id(%MyApp.UserId{id: "abc-123"})
+      true
+
+      iex> is_object_id(%{id: "abc-123"})
+      false
+  """
+  defguard is_object_id(term)
+           when is_map(term) and :erlang.is_map_key(:__object_id__, term) and
+                  :erlang.map_get(:__object_id__, term) == true
+
   @proto_extension_tag 870_010
   @proto_extension_name "trogon.object_id.v1alpha1.enum_value"
   @default_separator "_"
@@ -204,9 +221,9 @@ defmodule Trogon.Commanded.ObjectId do
 
   defp __generated_struct_and_metadata__(object_type, prefix) do
     quote location: :keep do
-      @type t :: %__MODULE__{id: binary()}
+      @type t :: %__MODULE__{id: binary(), __object_id__: true}
 
-      defstruct [:id]
+      defstruct id: nil, __object_id__: true
 
       @doc false
       @spec object_type() :: String.t()

apps/trogon_commanded/test/trogon/commanded/object_id_test.exs

@@ -1,6 +1,8 @@
 defmodule Trogon.Commanded.ObjectIdTest do
   use ExUnit.Case
 
+  import Trogon.Commanded.ObjectId
+
   alias TestSupport
 
   @test_uuid "test-value-1"
@@ -626,4 +628,47 @@ defmodule Trogon.Commanded.ObjectIdTest do
       assert parsed.id == "abc-123"
     end
   end
+
+  describe "is_object_id/1" do
+    test "returns true for an ObjectId struct" do
+      user_id = TestSupport.UserId.new!("abc-123")
+      assert is_object_id(user_id)
+    end
+
+    test "returns false for a plain map" do
+      refute is_object_id(%{id: "abc-123"})
+    end
+
+    test "returns false for a non-ObjectId struct" do
+      refute is_object_id(%URI{path: "/"})
+    end
+
+    test "returns false for non-map values" do
+      refute is_object_id("user_abc-123")
+      refute is_object_id(123)
+      refute is_object_id(nil)
+    end
+
+    test "works in guard clauses" do
+      user_id = TestSupport.UserId.new!("abc-123")
+
+      result =
+        case user_id do
+          x when is_object_id(x) -> :object_id
+          _ -> :other
+        end
+
+      assert result == :object_id
+    end
+
+    test "rejects non-ObjectId in guard clauses" do
+      result =
+        case %{id: "abc-123"} do
+          x when is_object_id(x) -> :object_id
+          _ -> :other
+        end
+
+      assert result == :other
+    end
+  end
 end