apply PR feedback

Author: filipecabaco

lib/realtime_web/channels/payloads/broadcast.ex

@@ -0,0 +1,17 @@
+defmodule RealtimeWeb.Channels.Payloads.Broadcast do
+  @moduledoc """
+  Validate broadcast field of the join payload.
+  """
+  use Ecto.Schema
+  import Ecto.Changeset
+  alias RealtimeWeb.Channels.Payloads.Join
+
+  embedded_schema do
+    field :ack, :boolean, default: false
+    field :self, :boolean, default: false
+  end
+
+  def changeset(broadcast, attrs) do
+    cast(broadcast, attrs, [:ack, :self], message: &Join.error_message/2)
+  end
+end

lib/realtime_web/channels/payloads/config.ex

@@ -0,0 +1,26 @@
+defmodule RealtimeWeb.Channels.Payloads.Config do
+  @moduledoc """
+  Validate config field of the join payload.
+  """
+  use Ecto.Schema
+  import Ecto.Changeset
+  alias RealtimeWeb.Channels.Payloads.Join
+  alias RealtimeWeb.Channels.Payloads.Broadcast
+  alias RealtimeWeb.Channels.Payloads.Presence
+  alias RealtimeWeb.Channels.Payloads.PostgresChange
+
+  embedded_schema do
+    embeds_one :broadcast, Broadcast
+    embeds_one :presence, Presence
+    embeds_many :postgres_changes, PostgresChange
+    field :private, :boolean, default: false
+  end
+
+  def changeset(config, attrs) do
+    config
+    |> cast(attrs, [:private], message: &Join.error_message/2)
+    |> cast_embed(:broadcast, invalid_message: "unable to parse, expected a map")
+    |> cast_embed(:presence, invalid_message: "unable to parse, expected a map")
+    |> cast_embed(:postgres_changes, invalid_message: "unable to parse, expected an array of maps")
+  end
+end

lib/realtime_web/channels/payloads/join.ex

@@ -0,0 +1,58 @@
+defmodule RealtimeWeb.Channels.Payloads.Join do
+  @moduledoc """
+  Payload validation for the phx_join event.
+  """
+  use Ecto.Schema
+  import Ecto.Changeset
+  alias RealtimeWeb.Channels.Payloads.Config
+  alias RealtimeWeb.Channels.Payloads.Broadcast
+  alias RealtimeWeb.Channels.Payloads.Presence
+
+  embedded_schema do
+    embeds_one :config, Config
+    field :access_token, :string
+    field :user_token, :string
+  end
+
+  def changeset(join, attrs) do
+    join
+    |> cast(attrs, [:access_token, :user_token], message: &error_message/2)
+    |> cast_embed(:config, invalid_message: "unable to parse, expected a map")
+  end
+
+  @spec validate(map()) :: {:ok, %__MODULE__{}} | {:error, :invalid_join_payload, map()}
+  def validate(params) do
+    case changeset(%__MODULE__{}, params) do
+      %Ecto.Changeset{valid?: true} = changeset ->
+        {:ok, Ecto.Changeset.apply_changes(changeset)}
+
+      %Ecto.Changeset{valid?: false} = changeset ->
+        errors = Ecto.Changeset.traverse_errors(changeset, &elem(&1, 0))
+        {:error, :invalid_join_payload, errors}
+    end
+  end
+
+  def presence_enabled?(%__MODULE__{config: %Config{presence: %Presence{enabled: enabled}}}), do: enabled
+  def presence_enabled?(_), do: true
+
+  def presence_key(%__MODULE__{config: %Config{presence: %Presence{key: ""}}}), do: UUID.uuid1()
+  def presence_key(%__MODULE__{config: %Config{presence: %Presence{key: key}}}), do: key
+  def presence_key(_), do: UUID.uuid1()
+
+  def ack_broadcast?(%__MODULE__{config: %Config{broadcast: %Broadcast{ack: ack}}}), do: ack
+  def ack_broadcast?(_), do: false
+
+  def self_broadcast?(%__MODULE__{config: %Config{broadcast: %Broadcast{self: self}}}), do: self
+  def self_broadcast?(_), do: false
+
+  def private?(%__MODULE__{config: %Config{private: private}}), do: private
+  def private?(_), do: false
+
+  def error_message(_field, meta) do
+    type = Keyword.get(meta, :type)
+
+    if type,
+      do: "unable to parse, expected #{type}",
+      else: "unable to parse"
+  end
+end

lib/realtime_web/channels/payloads/postgres_change.ex

@@ -0,0 +1,19 @@
+defmodule RealtimeWeb.Channels.Payloads.PostgresChange do
+  @moduledoc """
+  Validate postgres_changes field of the join payload.
+  """
+  use Ecto.Schema
+  import Ecto.Changeset
+  alias RealtimeWeb.Channels.Payloads.Join
+
+  embedded_schema do
+    field :event, :string
+    field :schema, :string
+    field :table, :string
+    field :filter, :string
+  end
+
+  def changeset(postgres_change, attrs) do
+    cast(postgres_change, attrs, [:event, :schema, :table, :filter], message: &Join.error_message/2)
+  end
+end

lib/realtime_web/channels/payloads/presence.ex

@@ -0,0 +1,17 @@
+defmodule RealtimeWeb.Channels.Payloads.Presence do
+  @moduledoc """
+  Validate presence field of the join payload.
+  """
+  use Ecto.Schema
+  import Ecto.Changeset
+  alias RealtimeWeb.Channels.Payloads.Join
+
+  embedded_schema do
+    field :enabled, :boolean, default: true
+    field :key, :string, default: UUID.uuid1()
+  end
+
+  def changeset(presence, attrs) do
+    cast(presence, attrs, [:enabled, :key], message: &Join.error_message/2)
+  end
+end

lib/realtime_web/channels/realtime_channel.ex

@@ -21,9 +21,9 @@ defmodule RealtimeWeb.RealtimeChannel do
   alias Realtime.Tenants.Authorization.Policies.PresencePolicies
   alias Realtime.Tenants.Connect
 
-  alias RealtimeWeb.Channels.RealtimeChannel.Payloads.Join
-  alias RealtimeWeb.Channels.RealtimeChannel.Payloads.Join.Config
-  alias RealtimeWeb.Channels.RealtimeChannel.Payloads.Join.Config.PostgresChange
+  alias RealtimeWeb.Channels.Payloads.Join
+  alias RealtimeWeb.Channels.Payloads.Config
+  alias RealtimeWeb.Channels.Payloads.PostgresChange
   alias RealtimeWeb.ChannelsAuthorization
   alias RealtimeWeb.RealtimeChannel.BroadcastHandler
   alias RealtimeWeb.RealtimeChannel.MessageDispatcher
@@ -555,9 +555,9 @@ defmodule RealtimeWeb.RealtimeChannel do
 
     access_token =
       cond do
-        access_token != nil and !String.starts_with?(access_token, "sb_") -> access_token
-        user_token != nil and !String.starts_with?(user_token, "sb_") -> user_token
-        tenant_token != nil and !String.starts_with?(tenant_token, "sb_") -> tenant_token
+        is_binary(access_token) and !String.starts_with?(access_token, "sb_") -> access_token
+        is_binary(user_token) and !String.starts_with?(user_token, "sb_") -> user_token
+        is_binary(tenant_token) and !String.starts_with?(tenant_token, "sb_") -> tenant_token
         true -> header
       end
 

lib/realtime_web/channels/realtime_channel/payloads/join.ex

@@ -1,13 +1,13 @@
-defmodule RealtimeWeb.Channels.RealtimeChannel.Payloads.JoinTest do
+defmodule RealtimeWeb.Channels.Payloads.JoinTest do
   use ExUnit.Case
 
   import Generators
 
-  alias RealtimeWeb.Channels.RealtimeChannel.Payloads.Join
-  alias RealtimeWeb.Channels.RealtimeChannel.Payloads.Join.Config
-  alias RealtimeWeb.Channels.RealtimeChannel.Payloads.Join.Config.Broadcast
-  alias RealtimeWeb.Channels.RealtimeChannel.Payloads.Join.Config.Presence
-  alias RealtimeWeb.Channels.RealtimeChannel.Payloads.Join.Config.PostgresChange
+  alias RealtimeWeb.Channels.Payloads.Join
+  alias RealtimeWeb.Channels.Payloads.Config
+  alias RealtimeWeb.Channels.Payloads.Broadcast
+  alias RealtimeWeb.Channels.Payloads.Presence
+  alias RealtimeWeb.Channels.Payloads.PostgresChange
 
   describe "validate/1" do
     test "valid payload allows join" do
@@ -56,6 +56,12 @@ defmodule RealtimeWeb.Channels.RealtimeChannel.Payloads.JoinTest do
       assert is_binary(key)
     end
 
+    test "missing enabled presence defaults to true" do
+      config = %{"config" => %{"presence" => %{}}}
+
+      assert {:ok, %Join{config: %Config{presence: %Presence{enabled: true}}}} = Join.validate(config)
+    end
+
     test "invalid payload returns errors" do
       config = %{"config" => ["test"]}