[sil] Add basic test support for variable name inference.

Author: gottesmm

lib/SILOptimizer/Utils/VariableNameUtils.cpp

@@ -11,6 +11,7 @@
 //===----------------------------------------------------------------------===//
 
 #include "swift/SILOptimizer/Utils/VariableNameUtils.h"
+#include "swift/SIL/Test.h"
 
 using namespace swift;
 
@@ -191,3 +192,30 @@ void VariableNameInferrer::drainVariableNamePath() {
     resultingString += '.';
   }
 }
+
+//===----------------------------------------------------------------------===//
+//                                MARK: Tests
+//===----------------------------------------------------------------------===//
+
+namespace swift::test {
+
+// Arguments:
+// - SILValue: value to emit a name for.
+// Dumps:
+// - The inferred name
+// - The inferred value.
+static FunctionTest VariableNameInferrerTests(
+    "variable-name-inference", [](auto &function, auto &arguments, auto &test) {
+      auto value = arguments.takeValue();
+      SmallString<64> finalString;
+      VariableNameInferrer inferrer(&function, finalString);
+      SILValue rootValue =
+          inferrer.inferByWalkingUsesToDefsReturningRoot(value);
+      llvm::outs() << "Input Value: " << *value;
+      if (!rootValue) {
+        llvm::outs() << "Name: 'unknown'\nRoot: 'unknown'\n";
+        return;
+      }
+      llvm::outs() << "Name: '" << finalString << "'\nRoot: " << rootValue;
+    });
+} // namespace swift::test

test/SILOptimizer/variable_name_inference.sil

@@ -0,0 +1,52 @@
+// RUN: %target-sil-opt -test-runner %s 2>&1 | %FileCheck %s
+
+import Builtin
+
+class Klass {}
+
+sil @getKlass : $@convention(thin) () -> @owned Klass
+sil @useIndirect : $@convention(thin) <T> (@in_guaranteed T) -> ()
+
+// CHECK-LABEL: begin running test {{[0-9]+}} of {{[0-9]+}} on simple_test_case: variable-name-inference with: @trace[0]
+// CHECK: Input Value:   %1 = apply %0() : $@convention(thin) () -> @owned Klass
+// CHECK: Name: 'MyName'
+// CHECK: Root:   %1 = apply %0() : $@convention(thin) () -> @owned Klass
+// CHECK: end running test {{[0-9]+}} of {{[0-9]+}} on simple_test_case: variable-name-inference with: @trace[0]
+sil [ossa] @simple_test_case : $@convention(thin) () -> () {
+bb0:
+  specify_test "variable-name-inference @trace[0]"
+  %0 = function_ref @getKlass : $@convention(thin) () -> @owned Klass
+  %1 = apply %0() : $@convention(thin) () -> @owned Klass
+  debug_value [trace] %1 : $Klass
+  debug_value %1 : $Klass, let, name "MyName"
+  destroy_value %1 : $Klass
+  %9999 = tuple ()
+  return %9999 : $()
+}
+
+// CHECK-LABEL: begin running test {{[0-9]+}} of {{[0-9]+}} on temporary_init_with_copy_addr: variable-name-inference with: @trace[0]
+// CHECK: Input Value:   %4 = alloc_stack $Klass
+// CHECK: Name: 'MyName'
+// CHECK: Root:   %2 = alloc_stack $Klass, var, name "MyName"
+// CHECK: end running test {{[0-9]+}} of {{[0-9]+}} on temporary_init_with_copy_addr: variable-name-inference with: @trace[0]
+sil [ossa] @temporary_init_with_copy_addr : $@convention(thin) () -> () {
+bb0:
+  specify_test "variable-name-inference @trace[0]"
+  %0 = function_ref @getKlass : $@convention(thin) () -> @owned Klass
+  %1 = apply %0() : $@convention(thin) () -> @owned Klass
+  %2 = alloc_stack $Klass, name "MyName"
+  store %1 to [init] %2 : $*Klass
+
+  %temp = alloc_stack $Klass
+  copy_addr %2 to [init] %temp : $*Klass
+  debug_value [trace] %temp : $*Klass
+  %use = function_ref @useIndirect : $@convention(thin) <T> (@in_guaranteed T) -> ()
+  apply %use<Klass>(%temp) : $@convention(thin) <T> (@in_guaranteed T) -> ()
+
+  destroy_addr %temp : $*Klass
+  dealloc_stack %temp : $*Klass
+  destroy_addr %2 : $*Klass
+  dealloc_stack %2 : $*Klass
+  %9999 = tuple ()
+  return %9999 : $()
+}