Test case for SemanticARCOpts fix - remove deadEndBlocks checks

Author: atrick

test/SILOptimizer/semantic-arc-opts.sil

@@ -9,6 +9,7 @@ import Builtin
 //////////////////
 
 typealias AnyObject = Builtin.AnyObject
+protocol Error {}
 
 enum MyNever {}
 enum FakeOptional<T> {
@@ -1525,3 +1526,107 @@ bb3(%7 : @owned $FakeOptional<Builtin.NativeObject>):
   %9999 = tuple()
   return %9999 : $()
 }
+
+// SemanticARCOptVisitor::performGuaranteedCopyValueOptimization should not optimize this case.
+//
+// CHECK-LABEL: sil [ossa] @testDeadInterleavedBorrow : $@convention(c) (@owned FakeOptional<AnyObject>) -> () {
+// CHECK: [[B:%.*]] = begin_borrow [lexical] %0 : $FakeOptional<AnyObject>
+// CHECK: copy_value
+// CHECK: switch_enum
+// CHECK: bb{{.*}}([[COPY:%.*]] : @owned $AnyObject):
+// CHECK: begin_borrow [lexical] [[COPY]] : $AnyObject
+// CHECK: end_borrow [[B]] : $FakeOptional<AnyObject>
+// CHECK: end_borrow
+// CHECK: destroy_value [[COPY]] : $AnyObject
+// CHECK-LABEL: } // end sil function 'testDeadInterleavedBorrow'
+sil [ossa] @testDeadInterleavedBorrow : $@convention(c) (@owned FakeOptional<AnyObject>) -> () {
+bb0(%opt : @owned $FakeOptional<AnyObject>):
+    %opt_borrow = begin_borrow [lexical] %opt : $FakeOptional<AnyObject>
+    %opt_borrow_copy = copy_value %opt_borrow : $FakeOptional<AnyObject>
+    switch_enum %opt_borrow_copy : $FakeOptional<AnyObject>, case #FakeOptional.some!enumelt: some, case #FakeOptional.none!enumelt: none
+
+some(%obj : @owned $AnyObject):
+    %_borrow = begin_borrow [lexical] %obj : $AnyObject
+    end_borrow %opt_borrow : $FakeOptional<AnyObject>
+    end_borrow %_borrow : $AnyObject
+    destroy_value %obj : $AnyObject
+    br die
+
+die:
+    unreachable
+
+none:
+    end_borrow %opt_borrow : $FakeOptional<AnyObject>
+    br exit
+
+exit:
+    destroy_value %opt : $FakeOptional<AnyObject>
+    %res = tuple ()
+    return %res : $()
+}
+
+// SemanticARCOptVisitor::performGuaranteedCopyValueOptimization should not optimize this case.
+//
+// CHECK-LABEL: sil [ossa] @testDeadAndAliveInterleavedBorrow : $@convention(c) (@owned FakeOptional<AnyObject>) -> () {
+// CHECK: [[B:%.*]] = begin_borrow [lexical] %0 : $FakeOptional<AnyObject>
+// CHECK: copy_value
+// CHECK: switch_enum
+//
+// CHECK: bb{{.*}}([[COPY:%.*]] : @owned $AnyObject):
+// CHECK: [[BB:%.*]] = begin_borrow [lexical] [[COPY]] : $AnyObject
+//
+// CHECK: try_apply undef
+//
+// CHECK: [[RESULT:%.*]] = apply undef(%{{.*}}) : $@convention(method) (@guaranteed AnyObject) -> @owned FakeOptional<AnyObject>
+// CHECK: switch_enum [[RESULT]] : $FakeOptional<AnyObject>, case #FakeOptional.some!enumelt: {{.*}}, case #FakeOptional.none!enumelt: [[NONEBB:bb[0-9]?]]
+//
+// CHECK: [[NONEBB]]:
+// CHECK: end_borrow [[B]] : $FakeOptional<AnyObject>
+// CHECK: end_borrow [[BB]] : $AnyObject
+// CHECK: destroy_value [[COPY]] : $AnyObject
+// CHECK: destroy_value %0 : $FakeOptional<AnyObject>
+// CHECK-LABEL: } // end sil function 'testDeadAndAliveInterleavedBorrow'
+sil [ossa] @testDeadAndAliveInterleavedBorrow : $@convention(c) (@owned FakeOptional<AnyObject>) -> () {
+bb0(%opt : @owned $FakeOptional<AnyObject>):
+    %opt_borrow = begin_borrow [lexical] %opt : $FakeOptional<AnyObject>
+    %opt_borrow_copy = copy_value %opt_borrow : $FakeOptional<AnyObject>
+    switch_enum %opt_borrow_copy : $FakeOptional<AnyObject>, case #FakeOptional.some!enumelt: some, case #FakeOptional.none!enumelt: none
+
+some(%obj : @owned $AnyObject):
+    %obj_borrow = begin_borrow [lexical] %obj : $AnyObject
+    %obj_borrow_copy = copy_value %obj_borrow : $AnyObject
+    try_apply undef(%obj_borrow_copy) : $@convention(method) (@owned AnyObject) -> (@owned AnyObject, @error Error), normal good, error bad
+
+good(%obj2 : @owned $AnyObject):
+    %obj3 = apply undef(%obj2) : $@convention(method) (@guaranteed AnyObject) -> @owned FakeOptional<AnyObject>
+    destroy_value %obj2 : $AnyObject
+    switch_enum %obj3 : $FakeOptional<AnyObject>, case #FakeOptional.some!enumelt: good_some, case #FakeOptional.none!enumelt: good_none
+
+good_some(%obj4 : @owned $AnyObject):
+    destroy_value %obj4 : $AnyObject
+    end_borrow %obj_borrow : $AnyObject
+    destroy_value %obj : $AnyObject
+    br exit
+
+good_none:
+    end_borrow %opt_borrow : $FakeOptional<AnyObject>
+    end_borrow %obj_borrow : $AnyObject
+    destroy_value %obj : $AnyObject
+    destroy_value %opt : $FakeOptional<AnyObject>
+    br die
+
+bad(%error1 : @owned $Error):
+    br die
+
+die:
+    unreachable
+
+none:
+    br exit
+
+exit:
+    end_borrow %opt_borrow : $FakeOptional<AnyObject>
+    destroy_value %opt : $FakeOptional<AnyObject>
+    %res = tuple ()
+    return %res : $()
+}