Swift Optimizer: simplify builtin "once"

If the callee is side effect-free we can remove the whole builtin "once".

Author: eeckstein

SwiftCompilerSources/Sources/Optimizer/InstructionSimplification/SimplifyBuiltin.swift

@@ -22,6 +22,8 @@ extension BuiltinInst : OnoneSimplifyable {
         optimizeIsConcrete(allowArchetypes: false, context)
       case .IsSameMetatype:
         optimizeIsSameMetatype(context)
+      case .Once:
+        optimizeBuiltinOnce(context)
       default:
         if let literal = constantFold(context) {
           uses.replaceAll(with: literal, context)
@@ -65,6 +67,29 @@ private extension BuiltinInst {
 
     uses.replaceAll(with: result, context)
   }
+
+  func optimizeBuiltinOnce(_ context: SimplifyContext) {
+    guard let callee = calleeOfOnce, callee.isDefinition else {
+      return
+    }
+    // If the callee is side effect-free we can remove the whole builtin "once".
+    // We don't use the callee's memory effects but instead look at all callee instructions
+    // because memory effects are not computed in the Onone pipeline, yet.
+    // This is no problem because the callee (usually a global init function )is mostly very small,
+    // or contains the side-effect instruction `alloc_global` right at the beginning.
+    if callee.instructions.contains(where: { $0.mayReadOrWriteMemory || $0.hasUnspecifiedSideEffects }) {
+      return
+    }
+    context.erase(instruction: self)
+  }
+
+  var calleeOfOnce: Function? {
+    let callee = operands[1].value
+    if let fri = callee as? FunctionRefInst {
+      return fri.referencedFunction
+    }
+    return nil
+  }
 }
 
 private func typesOfValuesAreEqual(_ lhs: Value, _ rhs: Value, in function: Function) -> Bool? {

test/SILOptimizer/simplify_builtin.sil

@@ -264,3 +264,61 @@ bb0:
   %4 = builtin "is_same_metatype"(%2 : $@thick Any.Type, %3 : $@thick Any.Type) : $Builtin.Int1
   return %4 : $Builtin.Int1
 }
+
+sil_global hidden [let] @g : $Int32
+
+sil [global_init_once_fn] @side_effect_free_init : $@convention(c) () -> () {
+bb0:
+  %1 = global_addr @g : $*Int32
+  %2 = integer_literal $Builtin.Int32, 10
+  %3 = struct $Int32 (%2 : $Builtin.Int32)
+  %6 = tuple ()
+  return %6 : $()
+}
+
+sil [global_init_once_fn] @init_with_side_effect : $@convention(c) () -> () {
+bb0:
+  alloc_global @g
+  %1 = global_addr @g : $*Int32
+  %2 = integer_literal $Builtin.Int32, 10
+  %3 = struct $Int32 (%2 : $Builtin.Int32)
+  store %3 to %1 : $*Int32
+  %6 = tuple ()
+  return %6 : $()
+}
+
+sil [global_init_once_fn] @unknown_init : $@convention(c) () -> ()
+
+// CHECK-LABEL: sil @remove_builtin_once :
+// CHECK-NOT:     builtin
+// CHECK:       } // end sil function 'remove_builtin_once'
+sil @remove_builtin_once : $@convention(thin) (Builtin.RawPointer) -> () {
+bb0(%0 : $Builtin.RawPointer):
+  %1 = function_ref @side_effect_free_init : $@convention(c) () -> ()
+  %2 = builtin "once"(%0 : $Builtin.RawPointer, %1 : $@convention(c) () -> ()) : $()
+  %3 = tuple ()
+  return %3 : $()
+}
+
+// CHECK-LABEL: sil @dont_remove_builtin_once_side_effect :
+// CHECK:         builtin
+// CHECK:       } // end sil function 'dont_remove_builtin_once_side_effect'
+sil @dont_remove_builtin_once_side_effect : $@convention(thin) (Builtin.RawPointer) -> () {
+bb0(%0 : $Builtin.RawPointer):
+  %1 = function_ref @init_with_side_effect : $@convention(c) () -> ()
+  %2 = builtin "once"(%0 : $Builtin.RawPointer, %1 : $@convention(c) () -> ()) : $()
+  %3 = tuple ()
+  return %3 : $()
+}
+
+// CHECK-LABEL: sil @dont_remove_builtin_once_unknown :
+// CHECK:         builtin
+// CHECK:       } // end sil function 'dont_remove_builtin_once_unknown'
+sil @dont_remove_builtin_once_unknown : $@convention(thin) (Builtin.RawPointer) -> () {
+bb0(%0 : $Builtin.RawPointer):
+  %1 = function_ref @unknown_init : $@convention(c) () -> ()
+  %2 = builtin "once"(%0 : $Builtin.RawPointer, %1 : $@convention(c) () -> ()) : $()
+  %3 = tuple ()
+  return %3 : $()
+}
+