[Test] Verified some non-deinit-barrier applies.

Checked that applies of empty functions, or their callees, or their
callees' callees, are not deinit barriers.  Checked that applies of
unknown functions, or their callees, or their callees' calles, are
deinit barriers.

Author: nate-chandler

lib/SILOptimizer/UtilityPasses/UnitTestRunner.cpp

@@ -72,9 +72,11 @@
 #include "swift/SIL/SILBridging.h"
 #include "swift/SIL/SILFunction.h"
 #include "swift/SIL/SILInstruction.h"
+#include "swift/SILOptimizer/Analysis/BasicCalleeAnalysis.h"
 #include "swift/SILOptimizer/PassManager/Passes.h"
 #include "swift/SILOptimizer/PassManager/Transforms.h"
 #include "swift/SILOptimizer/Utils/CanonicalizeOSSALifetime.h"
+#include "swift/SILOptimizer/Utils/InstOptUtils.h"
 #include "swift/SILOptimizer/Utils/InstructionDeleter.h"
 #include "swift/SILOptimizer/Utils/ParseTestSpecification.h"
 #include "llvm/ADT/StringRef.h"
@@ -255,6 +257,23 @@ struct FunctionGetSelfArgumentIndex : UnitTest {
   }
 };
 
+// Arguments:
+// - instruction
+// Dumps:
+// - instruction
+// - whether it's a deinit barrier
+struct IsDeinitBarrierTest : UnitTest {
+  IsDeinitBarrierTest(UnitTestRunner *pass) : UnitTest(pass) {}
+  void invoke(Arguments &arguments) override {
+    auto *instruction = arguments.takeInstruction();
+    auto *analysis = getAnalysis<BasicCalleeAnalysis>();
+    auto isBarrier = isDeinitBarrier(instruction, analysis);
+    instruction->dump();
+    auto *boolString = isBarrier ? "true" : "false";
+    llvm::errs() << boolString << "\n";
+  }
+};
+
 /// [new_tests] Add the new UnitTest subclass above this line.
 
 class UnitTestRunner : public SILFunctionTransform {
@@ -295,6 +314,7 @@ class UnitTestRunner : public SILFunctionTransform {
     ADD_UNIT_TEST_SUBCLASS(
         "pruned-liveness-boundary-with-list-of-last-users-insertion-points",
         PrunedLivenessBoundaryWithListOfLastUsersInsertionPointsTest)
+    ADD_UNIT_TEST_SUBCLASS("is-deinit-barrier", IsDeinitBarrierTest)
     /// [new_tests] Add the new mapping from string to subclass above this line.
 
 #undef ADD_UNIT_TEST_SUBCLASS

test/SILOptimizer/deinit_barrier.sil

@@ -0,0 +1,87 @@
+// RUN: %target-sil-opt -compute-side-effects -unit-test-runner %s 2>&1 | %FileCheck %s
+
+// REQUIRES: swift_in_compiler
+
+sil [ossa] @unknown : $@convention(thin) () -> ()
+
+sil [ossa] @unknown_caller : $@convention(thin) () -> () {
+  %unknown = function_ref @unknown : $@convention(thin) () -> ()
+  apply %unknown() : $@convention(thin) () -> ()
+  %retval = tuple ()
+  return %retval : $()
+}
+
+sil [ossa] @empty_fn : $@convention(thin) () -> () {
+  %retval = tuple ()
+  return %retval : $()
+}
+
+sil [ossa] @empty_fn_caller : $@convention(thin) () -> () {
+  %empty_fn = function_ref @empty_fn : $@convention(thin) () -> ()
+  apply %empty_fn() : $@convention(thin) () -> ()
+  %retval = tuple ()
+  return %retval : $()
+}
+
+sil [ossa] @empty_fn_caller_caller : $@convention(thin) () -> () {
+  %empty_fn_caller = function_ref @empty_fn_caller : $@convention(thin) () -> ()
+  apply %empty_fn_caller() : $@convention(thin) () -> ()
+  %retval = tuple ()
+  return %retval : $()
+}
+
+
+// CHECK-LABEL: begin running test 1 of {{[0-9]+}} on call_functions: dump-function
+// CHECK:       [[EMPTY_FN:%[^,]+]] = function_ref @empty_fn
+// CHECK:       [[EMPTY_FN_CALLER:%[^,]+]] = function_ref @empty_fn_caller
+// CHECK:       [[EMPTY_FN_CALLER_CALLER:%[^,]+]] = function_ref @empty_fn_caller_caller
+// CHECK:       [[UNKNOWN:%[^,]+]] = function_ref @unknown
+// CHECK:       [[UNKNOWN_CALLER:%[^,]+]] = function_ref @unknown_caller
+// CHECK-LABEL: end running test 1 of {{[0-9]+}} on call_functions: dump-function
+// CHECK-LABEL: begin running test 2 of {{[0-9]+}} on call_functions: is-deinit-barrier
+// CHECK:   apply [[EMPTY_FN]]
+// CHECK:   false
+// CHECK-LABEL: end running test 2 of {{[0-9]+}} on call_functions: is-deinit-barrier
+// CHECK-LABEL: begin running test 3 of {{[0-9]+}} on call_functions: is-deinit-barrier
+// CHECK:   apply [[EMPTY_FN_CALLER]]
+// CHECK:   false
+// CHECK-LABEL: end running test 3 of {{[0-9]+}} on call_functions: is-deinit-barrier
+// CHECK-LABEL: begin running test 4 of {{[0-9]+}} on call_functions: is-deinit-barrier
+// CHECK:   apply [[EMPTY_FN_CALLER_CALLER]]
+// CHECK:   false
+// CHECK-LABEL: end running test 4 of {{[0-9]+}} on call_functions: is-deinit-barrier
+// CHECK-LABEL: begin running test 5 of {{[0-9]+}} on call_functions: is-deinit-barrier
+// CHECK:   apply [[UNKNOWN]]
+// CHECK:   true
+// CHECK-LABEL: end running test 5 of {{[0-9]+}} on call_functions: is-deinit-barrier
+// CHECK-LABEL: begin running test 6 of {{[0-9]+}} on call_functions: is-deinit-barrier
+// CHECK:   apply [[UNKNOWN_CALLER]]
+// CHECK:   true
+// CHECK-LABEL: end running test 6 of {{[0-9]+}} on call_functions: is-deinit-barrier
+sil [ossa] @call_functions : $@convention(thin) () -> () {
+entry:
+  test_specification "dump-function"
+  test_specification "is-deinit-barrier @instruction[1]"
+  %empty_fn = function_ref @empty_fn : $@convention(thin) () -> ()
+  apply %empty_fn() : $@convention(thin) () -> ()
+
+  test_specification "is-deinit-barrier @instruction[3]"
+  %empty_fn_caller = function_ref @empty_fn_caller : $@convention(thin) () -> ()
+  apply %empty_fn_caller() : $@convention(thin) () -> ()
+
+  test_specification "is-deinit-barrier @instruction[5]"
+  %empty_fn_caller_caller = function_ref @empty_fn_caller_caller : $@convention(thin) () -> ()
+  apply %empty_fn_caller_caller() : $@convention(thin) () -> ()
+
+  test_specification "is-deinit-barrier @instruction[7]"
+  %unknown = function_ref @unknown : $@convention(thin) () -> ()
+  apply %unknown() : $@convention(thin) () -> ()
+
+  test_specification "is-deinit-barrier @instruction[9]"
+  %unknown_caller = function_ref @unknown_caller : $@convention(thin) () -> ()
+  apply %unknown_caller() : $@convention(thin) () -> ()
+
+  %retval = tuple ()
+  return %retval : $()
+}
+