Swift Optimizer: add Onone simplification of cond_br instructions

Author: eeckstein

SwiftCompilerSources/Sources/Optimizer/InstructionSimplification/CMakeLists.txt

@@ -11,5 +11,6 @@ swift_compiler_sources(Optimizer
   SimplifyBeginCOWMutation.swift
   SimplifyBranch.swift
   SimplifyBuiltin.swift
+  SimplifyCondBranch.swift
   SimplifyGlobalValue.swift
   SimplifyStrongRetainRelease.swift)

SwiftCompilerSources/Sources/Optimizer/InstructionSimplification/SimplifyCondBranch.swift

@@ -0,0 +1,34 @@
+//===--- SimplifyCondBranch.swift -----------------------------------------===//
+//
+// This source file is part of the Swift.org open source project
+//
+// Copyright (c) 2014 - 2023 Apple Inc. and the Swift project authors
+// Licensed under Apache License v2.0 with Runtime Library Exception
+//
+// See https://swift.org/LICENSE.txt for license information
+// See https://swift.org/CONTRIBUTORS.txt for the list of Swift project authors
+//
+//===----------------------------------------------------------------------===//
+
+import SIL
+
+extension CondBranchInst : OnoneSimplifyable {
+  func simplify(_ context: SimplifyContext) {
+    tryConstantFold(context)
+  }
+}
+
+private extension CondBranchInst {
+  func tryConstantFold(_ context: SimplifyContext) {
+    guard let literal = condition as? IntegerLiteralInst else {
+      return
+    }
+    let builder = Builder(before: self, context)
+    if literal.value.isZero() {
+      builder.createBranch(to: falseBlock, arguments: Array(falseOperands.map { $0.value }))
+    } else {
+      builder.createBranch(to: trueBlock, arguments: Array(trueOperands.map { $0.value }))
+    }
+    context.erase(instruction: self)
+  }
+}

test/SILOptimizer/simplify_cond_br.sil

@@ -0,0 +1,64 @@
+// RUN: %target-sil-opt -enable-sil-verify-all %s -onone-simplification -simplify-instruction=cond_br | %FileCheck %s
+
+
+// REQUIRES: swift_in_compiler
+
+import Swift
+import Builtin
+
+// CHECK-LABEL: sil @constant_cond_br_true
+// CHECK:       bb0(%0 : $Int, %1 : $Int):
+// CHECK-NEXT:    br bb1(%0 : $Int)
+// CHECK:       } // end sil function 'constant_cond_br_true'
+sil @constant_cond_br_true : $@convention(thin) (Int, Int) -> Int {
+bb0(%0 : $Int, %1 : $Int):
+  %2 = integer_literal $Builtin.Int1, 1
+  cond_br %2, bb1(%0 : $Int), bb2(%1 : $Int)
+
+bb1(%4 : $Int):
+  br bb3(%4 : $Int)
+
+bb2(%6 : $Int):
+  br bb3(%6 : $Int)
+
+bb3(%8 : $Int):
+  return %8 : $Int
+}
+
+// CHECK-LABEL: sil @constant_cond_br_false
+// CHECK:       bb0(%0 : $Int, %1 : $Int):
+// CHECK-NEXT:    br bb1(%1 : $Int)
+// CHECK:       } // end sil function 'constant_cond_br_false'
+sil @constant_cond_br_false : $@convention(thin) (Int, Int) -> Int {
+bb0(%0 : $Int, %1 : $Int):
+  %2 = integer_literal $Builtin.Int1, 0
+  cond_br %2, bb1(%0 : $Int), bb2(%1 : $Int)
+
+bb1(%4 : $Int):
+  br bb3(%4 : $Int)
+
+bb2(%6 : $Int):
+  br bb3(%6 : $Int)
+
+bb3(%8 : $Int):
+  return %8 : $Int
+}
+
+// CHECK-LABEL: sil @non_constant_cond_br
+// CHECK:       bb0(%0 : $Int, %1 : $Int, %2 : $Builtin.Int1):
+// CHECK-NEXT:    cond_br %2
+// CHECK:       } // end sil function 'non_constant_cond_br'
+sil @non_constant_cond_br : $@convention(thin) (Int, Int, Builtin.Int1) -> Int {
+bb0(%0 : $Int, %1 : $Int, %2 : $Builtin.Int1):
+  cond_br %2, bb1(%0 : $Int), bb2(%1 : $Int)
+
+bb1(%4 : $Int):
+  br bb3(%4 : $Int)
+
+bb2(%6 : $Int):
+  br bb3(%6 : $Int)
+
+bb3(%8 : $Int):
+  return %8 : $Int
+}
+