[cast-opt] When simplifying checked_cast_br, be sure to forward the failing value as the argument to the failure block.

Author: gottesmm

lib/SILOptimizer/Utils/CastOptimizer.cpp

@@ -831,8 +831,12 @@ CastOptimizer::simplifyCheckedCastBranchInst(CheckedCastBranchInst *Inst) {
       return NewI;
     }
 
-    // This exact cast will fail.
-    auto *NewI = Builder.createBranch(Loc, FailureBB);
+    // This exact cast will fail. With ownership enabled, we pass a copy of the
+    // original casts value to the failure block.
+    TinyPtrVector<SILValue> Args;
+    if (Builder.hasOwnership())
+      Args.push_back(Inst->getOperand());
+    auto *NewI = Builder.createBranch(Loc, FailureBB, Args);
     EraseInstAction(Inst);
     WillFailAction();
     return NewI;
@@ -859,9 +863,11 @@ CastOptimizer::simplifyCheckedCastBranchInst(CheckedCastBranchInst *Inst) {
                                          TargetType, isSourceTypeExact);
 
   SILBuilderWithScope Builder(Inst, BuilderContext);
-
   if (Feasibility == DynamicCastFeasibility::WillFail) {
-    auto *NewI = Builder.createBranch(Loc, FailureBB);
+    TinyPtrVector<SILValue> Args;
+    if (Builder.hasOwnership())
+      Args.push_back(Inst->getOperand());
+    auto *NewI = Builder.createBranch(Loc, FailureBB, Args);
     EraseInstAction(Inst);
     WillFailAction();
     return NewI;

test/SILOptimizer/constant_propagation_ownership.sil

@@ -852,6 +852,7 @@ bb0:
 struct Value {}
 
 class AnObject {}
+class AnSubObject : AnObject {}
 
 // CHECK-LABEL: sil [ossa] @replace_unconditional_check_cast_failure
 // CHECK:  bb2:
@@ -1084,3 +1085,50 @@ bb0(%0 : $*Error, %1 : $*E1):
   %2 = tuple ()
   return %2 : $()
 }
+
+// CHECK-LABEL: sil [ossa] @always_fail_protocolmeta_to_concretemeta_checkedcastbr : $@convention(thin) (@thin P.Protocol) -> Builtin.Int1 {
+// CHECK: bb0(
+// CHECK-NEXT: metatype
+// CHECK-NEXT: br bb2(
+// CHECK: } // end sil function 'always_fail_protocolmeta_to_concretemeta_checkedcastbr'
+sil [ossa] @always_fail_protocolmeta_to_concretemeta_checkedcastbr : $@convention(thin) (@thin P.Protocol) -> Builtin.Int1 {
+bb0(%0 : $@thin P.Protocol):
+  %2 = metatype $@thick P.Protocol
+  checked_cast_br %2 : $@thick P.Protocol to $@thick X.Type, bb1, bb2
+
+bb1(%4 : $@thick X.Type):
+  %5 = metatype $@thin X.Type
+  %6 = integer_literal $Builtin.Int1, -1
+  br bb3(%6 : $Builtin.Int1)
+
+bb2(%8 : $@thick P.Protocol):
+  %9 = integer_literal $Builtin.Int1, 0
+  br bb3(%9 : $Builtin.Int1)
+
+bb3(%11 : $Builtin.Int1):
+  return %11 : $Builtin.Int1
+}
+
+// CHECK-LABEL: sil [ossa] @always_succeed_subtoparent : $@convention(thin) (@owned AnSubObject) -> Builtin.Int1 {
+// CHECK: bb0(
+// CHECK-NEXT: upcast
+// CHECK-NEXT: br bb1(
+// CHECK: } // end sil function 'always_succeed_subtoparent'
+sil [ossa] @always_succeed_subtoparent : $@convention(thin) (@owned AnSubObject) -> Builtin.Int1 {
+bb0(%0 : @owned $AnSubObject):
+  checked_cast_br %0 : $AnSubObject to $AnObject, bb1, bb2
+
+bb1(%4 : @owned $AnObject):
+  %5 = metatype $@thin X.Type
+  %6 = integer_literal $Builtin.Int1, -1
+  destroy_value %4 : $AnObject
+  br bb3(%6 : $Builtin.Int1)
+
+bb2(%8 : @owned $AnSubObject):
+  %9 = integer_literal $Builtin.Int1, 0
+  destroy_value %8 : $AnSubObject
+  br bb3(%9 : $Builtin.Int1)
+
+bb3(%11 : $Builtin.Int1):
+  return %11 : $Builtin.Int1
+}