[new] Add support for scittle, etc.

Before: Trove macro code was :clj conditional
 After: Trove macro code is now unconditional (any platform)

Looks like there shouldn't be any downside to this change [1],
but please do report if you've been negatively affected somehow!

[1] https://clojurians.slack.com/archives/C091TEH5G9Z/p1764682809748049?thread_ts=1764556869.604369&cid=C091TEH5G9Z
    Thanks to borkdude and dnolan for input on this 🙏

Author: ptaoussanis

src/taoensso/trove.cljc

@@ -47,64 +47,62 @@
 
   (console/get-log-fn))
 
-#?(:clj
-   (defmacro set-log-fn!
-     "Sets the root value of `*log-fn*` (see its docstring for more info)."
-     [f]
-     (if (:ns &env)
-       `(set!                *log-fn*           ~f)
-       `(alter-var-root (var *log-fn*) (fn [_#] ~f)))))
-
-#?(:clj
-   (defmacro log!
-     "Logs the given info to the currently configured backend (see `*log-fn*`)
-     and returns nil.
-
-     Common options:
-       `:level` -- ∈ #{:trace :debug :info :warn :error :fatal :report} (default `:info`)
-       `:id` ----- Optional keyword used to identify event, e.g. `:auth/login`, `::order-complete`, etc.
-       `:msg` ---- Optional message string describing event (use `str`, `format`, etc. as needed)
-       `:data` --- Optional arb map of structured data associated with event, e.g. {:user-id 1234}
-       `:error` -- Optional platform error (`java.lang.Throwable`, `js/Error`)
-
-     Advanced options:
-       `:let` ---- Bindings shared by lazy args: {:keys [msg data error kvs]}
-       `:ns` ----- Custom namespace string to override default
-       `:coords` - Custom [line column]    to override default
-       `:log-fn` - Custom `log-fn`         to override default (`*log-fn*`)
-       <kvs> ----- Any other kvs will also be provided to `log-fn`, handy for
-                   custom `log-fn` opts, etc.
-
-     Traditional logs typically include at least {:keys [level msg ...]}.
-     Structured  logs typically include at least {:keys [level id data ...]}."
-
-     {:arglists '([{:keys [level id msg data error]}])} ; Common only
-     [opts]
-
-     (when-not (map? opts)
-       (throw
-         (ex-info "Trove opts must be a compile-time map"
-           {:opts {:value opts, :type (type opts)}})))
-
-     (let [{:keys [ns coords level id msg data error log-fn] letf :let ; forms
-            :or
-            {ns     (str *ns*)
-             level  :info
-             coords (utils/callsite-coords &form)
-             log-fn `*log-fn*}} opts
-
-           lfn (gensym "lfn__")
-           kvs (not-empty (dissoc opts :ns :coords :level :id :error :let :msg :data :log-fn))
-           lazy-form
-           (when-let [opts (utils/assoc-some nil {:error error, :msg msg, :data data, :kvs kvs})]
-             (if (every? utils/const? [opts letf])
-               (if letf        `(let ~letf ~opts)           opts) ; Don't pay for wrapping
-               (if letf `(delay (let ~letf ~opts)) `(delay ~opts))))]
-
-       `(let   [~lfn ~log-fn]
-          (when ~lfn
-            (~lfn ~ns ~coords ~level ~id ~lazy-form))
-          nil))))
+(defmacro set-log-fn!
+  "Sets the root value of `*log-fn*` (see its docstring for more info)."
+  [f]
+  (if (:ns &env)
+    `(set!                *log-fn*           ~f)
+    `(alter-var-root (var *log-fn*) (fn [_#] ~f))))
+
+(defmacro log!
+  "Logs the given info to the currently configured backend (see `*log-fn*`)
+  and returns nil.
+
+  Common options:
+    `:level` -- ∈ #{:trace :debug :info :warn :error :fatal :report} (default `:info`)
+    `:id` ----- Optional keyword used to identify event, e.g. `:auth/login`, `::order-complete`, etc.
+    `:msg` ---- Optional message string describing event (use `str`, `format`, etc. as needed)
+    `:data` --- Optional arb map of structured data associated with event, e.g. {:user-id 1234}
+    `:error` -- Optional platform error (`java.lang.Throwable`, `js/Error`)
+
+  Advanced options:
+    `:let` ---- Bindings shared by lazy args: {:keys [msg data error kvs]}
+    `:ns` ----- Custom namespace string to override default
+    `:coords` - Custom [line column]    to override default
+    `:log-fn` - Custom `log-fn`         to override default (`*log-fn*`)
+    <kvs> ----- Any other kvs will also be provided to `log-fn`, handy for
+                custom `log-fn` opts, etc.
+
+  Traditional logs typically include at least {:keys [level msg ...]}.
+  Structured  logs typically include at least {:keys [level id data ...]}."
+
+  {:arglists '([{:keys [level id msg data error]}])} ; Common only
+  [opts]
+
+  (when-not (map? opts)
+    (throw
+      (ex-info "Trove opts must be a compile-time map"
+        {:opts {:value opts, :type (type opts)}})))
+
+  (let [{:keys [ns coords level id msg data error log-fn] letf :let ; forms
+         :or
+         {ns     (str *ns*)
+          level  :info
+          coords (utils/callsite-coords &form)
+          log-fn `*log-fn*}} opts
+
+        lfn (gensym "lfn__")
+        kvs (not-empty (dissoc opts :ns :coords :level :id :error :let :msg :data :log-fn))
+        lazy-form
+        (when-let [opts (utils/assoc-some nil {:error error, :msg msg, :data data, :kvs kvs})]
+          (if (every? utils/const-form? [opts letf])
+            (if letf        `(let ~letf ~opts)           opts) ; Don't pay for wrapping
+            (if letf `(delay (let ~letf ~opts)) `(delay ~opts))))]
+
+    `(let   [~lfn ~log-fn]
+       (when ~lfn
+         (~lfn ~ns ~coords ~level ~id ~lazy-form))
+       nil)))
 
 (comment
   (do           (log! {:level :info, :msg "msg" :foo :bar}))

src/taoensso/trove/utils.cljc

@@ -4,24 +4,22 @@
 (def ^:no-doc ^:const nl "System line separator"
   #?(:clj (System/getProperty "line.separator") :cljs "\n"))
 
-#?(:clj
-   (let [cons? (fn [x] (instance? clojure.lang.Cons x))]
-     (defn ^:no-doc const? [x]
-       (cond
-         (list? x) false
-         (cons? x) false
-         (map?  x) (every? const? (vals x))
-         (coll? x) (every? const?       x)
-         :else     true))))
+(let [cons? (fn [x] (instance? #?(:clj clojure.lang.Cons, :cljs cljs.core/Cons) x))]
+  (defn ^:no-doc const-form? [form]
+    (cond
+      (list? form) false
+      (cons? form) false
+      (map?  form) (every? const-form? (vals form))
+      (coll? form) (every? const-form?       form)
+      :else        true)))
 
-(comment (const? {:a :A :b :B :c [:d :e :f #_'(str "foo") 'g]}))
+(comment (const-form? {:a :A :b :B :c [:d :e :f #_'(str "foo") 'g]}))
 
-#?(:clj
-   (defn callsite-coords
-     "Returns [line column] from meta on given macro `&form`."
-     [macro-form]
-     (when-let [{:keys [line column]} (meta macro-form)]
-       (when line (if column [line column] [line])))))
+(defn callsite-coords
+  "Returns [line column] from meta on given macro `&form`."
+  [macro-form]
+  (when-let [{:keys [line column]} (meta macro-form)]
+    (when line (if column [line column] [line]))))
 
 (defn assoc-some
   "Assocs each kv to given ?map iff its value is not nil."