pythonqt/src/src.pro at 1a21795afac8683bca0aa6da81c1cb7be7a3226d · trikset/pythonqt · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
# --------- PythonQt profile -------------------
# Last changed by $Author: florian $
# $Id: PythonQt.pro 35381 2006-03-16 13:05:52Z florian $
# $Source$
# --------------------------------------------------

TARGET = trikPythonQt-QtXY-PythonXY
TEMPLATE = lib

CONFIG += qt msvc_mp
CONFIG -= flat

# allow to choose static linking through the environment variable PYTHONQT_STATIC
isEmpty(PYTHONQT_STATIC) {
PYTHONQT_STATIC = $$(PYTHONQT_STATIC)
}

isEmpty(PYTHONQT_STATIC) {
  CONFIG += dll
} else {
  CONFIG += static
}

DEFINES += PYTHONQT_CATCH_ALL_EXCEPTIONS

QT += widgets core-private

INCLUDEPATH += $$PWD

macx {
  contains(QT_MAJOR_VERSION, 6) {
    QMAKE_APPLE_DEVICE_ARCHS = x86_64 arm64
  }
}

include ( ../build/common.prf )
include ( ../build/python.prf )
TARGET = $$replace(TARGET, PythonXY, Python$${PYTHON_VERSION})
TARGET = $$replace(TARGET, QtXY, Qt$${QT_MAJOR_VERSION}$${QT_MINOR_VERSION})

include ( src.pri )

include($${PYTHONQT_GENERATED_PATH}/com_trolltech_qt_core_builtin/com_trolltech_qt_core_builtin.pri)
include($${PYTHONQT_GENERATED_PATH}/com_trolltech_qt_gui_builtin/com_trolltech_qt_gui_builtin.pri)

unix {
  CONFIG += create_pc create_prl no_install_prl
  QMAKE_PKGCONFIG_NAME = $${TARGET}
  QMAKE_PKGCONFIG_DESCRIPTION = Dynamic Python binding for the Qt framework
  QMAKE_PKGCONFIG_PREFIX = $$INSTALLBASE
  QMAKE_PKGCONFIG_LIBDIR = $$target.path
  QMAKE_PKGCONFIG_INCDIR = $$headers.path
  QMAKE_PKGCONFIG_INCDIR += ${prefix}/include/PythonQt5
  QMAKE_PKGCONFIG_VERSION = $$VERSION
}

unix: target.path = $${INSTALL_PREFIX}/lib
win32: target.path = /

headers.files = $${HEADERS} $$PWD/PythonQtPythonInclude.h
headers.path = $${INSTALL_PREFIX}/include

INSTALLS += target headers