FTObjectLibrary/Examples/Calculator.f90 at main · trixi-framework/FTObjectLibrary · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
!
!////////////////////////////////////////////////////////////////////////
!
!      Calculator.f90
!      Created: July 31, 2014 at 9:23 AM
!      By: David Kopriva
!
!      A simple toy reverse polish calculator.
!
!        ---------------------------------
!        Example: compute 3*(4+2*3)-5 = 25
!        ---------------------------------
!
!         CALL calc % init()
!         CALL calc % enter(2.0d0)
!         CALL calc % enter(3.0d0)
!         CALL calc % enter("*")
!         CALL calc % enter(4.0d0)
!         CALL calc % enter("+")
!         CALL calc % enter(3.0d0)
!         CALL calc % enter("*")
!         CALL calc % enter(5.0d0)
!         CALL calc % enter("-")
!         PRINT *, "3*(4+2*3)-5 = ",calc % readDisplay()
!         CALL calc % destruct()
!
!
!////////////////////////////////////////////////////////////////////////
!
      Module CalculatorClass
         USE FTObjectClass
         USE FTStackClass
         USE FTValueClass

         IMPLICIT NONE
         PRIVATE

         TYPE, EXTENDS(FTObject) :: Calculator
            CLASS(FTStack), POINTER, PRIVATE  :: stack
!
!           ========
            CONTAINS
!           ========
!
            PROCEDURE, PUBLIC  :: init     => initCalculator
            PROCEDURE, PUBLIC  :: destruct => destructCalculator
            PROCEDURE, PUBLIC  :: clear    => clearCalculator
            PROCEDURE, PUBLIC  :: enterOperation
            PROCEDURE, PUBLIC  :: enterValue
            GENERIC            :: enter     => enterOperation, enterValue
            PROCEDURE, PUBLIC  :: readDisplay
         END TYPE Calculator

         PUBLIC :: Calculator
!
!        ========
         CONTAINS
!        ========
!
!
!////////////////////////////////////////////////////////////////////////
!
         SUBROUTINE initCalculator(self)
            IMPLICIT NONE
            CLASS(Calculator) :: self

            CALL self % FTObject % init()
            ALLOCATE(self % stack)
            CALL self % stack % init()

         END SUBROUTINE initCalculator
!
!////////////////////////////////////////////////////////////////////////
!
         SUBROUTINE destructCalculator(self)
            IMPLICIT NONE
            CLASS(Calculator) :: self

            CALL releaseFTStack(self % stack)

         END SUBROUTINE destructCalculator
!
!////////////////////////////////////////////////////////////////////////
!
      SUBROUTINE releaseCalculator(self)
         IMPLICIT NONE
         CLASS(Calculator) , POINTER :: self
         CLASS(FTObject)   , POINTER :: obj
         IF(.NOT. ASSOCIATED(self)) RETURN
         obj => self
         CALL releaseFTObject(self = obj)
         IF ( .NOT. ASSOCIATED(obj) )     THEN
            self => NULL()
         END IF
      END SUBROUTINE releaseCalculator
!
!////////////////////////////////////////////////////////////////////////
!
         SUBROUTINE clearCalculator(self)
            IMPLICIT NONE
            CLASS(Calculator) :: self
            CALL self % stack % removeAllObjects()
         END SUBROUTINE clearCalculator
!
!////////////////////////////////////////////////////////////////////////
!
         SUBROUTINE enterOperation(self,op)
            IMPLICIT NONE
            CLASS(Calculator)                   :: self
            CHARACTER(LEN=*)                    :: op
            CLASS(FTObject) , POINTER           :: obj
            CLASS(FTValue)  , POINTER           :: v
            REAL(KIND=FT_DOUBLE_PRECISION_KIND) :: x, y, r

            SELECT CASE ( op )
               CASE( "+" )
                  x = popValue(self % stack)
                  y = popValue(self % stack)
                  r = x + y
                  CALL self % enterValue(r)
               CASE( "-" )
                  x = popValue(self % stack)
                  y = popValue(self % stack)
                  r = y - x
                  CALL self % enterValue(r)
               CASE( "*" )
                  x = popValue(self % stack)
                  y = popValue(self % stack)
                  r = x*y
                  CALL self % enterValue(r)
               CASE( "/" )
                  x = popValue(self % stack)
                  y = popValue(self % stack)
                  r = x/y
                  CALL self % enterValue(r)
               CASE DEFAULT
            END SELECT

         END SUBROUTINE enterOperation
!
!////////////////////////////////////////////////////////////////////////
!
         FUNCTION popValue(stack) RESULT(r)
            IMPLICIT NONE
            TYPE(FTStack)                       :: stack
            CLASS(FTObject) , POINTER           :: obj
            CLASS(FTValue)  , POINTER           :: v
            REAL(KIND=FT_DOUBLE_PRECISION_KIND) :: r

            CALL stack % pop(obj)

            v   => valueFromObject(obj)
            r   = v % doublePrecisionValue()

            CALL releaseFTValue(v)

         END FUNCTION popValue
!
!////////////////////////////////////////////////////////////////////////
!
         SUBROUTINE enterValue(self,v)
            IMPLICIT NONE
            CLASS(Calculator)                   :: self
            REAL(KIND=FT_DOUBLE_PRECISION_KIND) :: v
            CLASS(FTValue) , POINTER            :: vValue
            CLASS(FTObject), POINTER            :: obj

            ALLOCATE(vValue)
            CALL vValue % initWithValue(v)

            obj => vValue
            CALL self % stack % push(obj)
            CALL releaseFTValue(vValue)

         END SUBROUTINE enterValue
!
!////////////////////////////////////////////////////////////////////////
!
         FUNCTION readDisplay(self)  RESULT(r)
            IMPLICIT NONE
            CLASS(Calculator)                   :: self
            REAL(KIND=FT_DOUBLE_PRECISION_KIND) :: r
            CLASS(FTObject), POINTER            :: obj

            obj => self % stack % peek()
            SELECT TYPE(obj)
               TYPE is (FTValue)
                  r = obj % doublePrecisionValue()
               CLASS DEFAULT
                  PRINT *, "Can't read display"
                  r = 0.0
            END SELECT

         END FUNCTION readDisplay
      END MODULE CalculatorClass