Start adding tests for bazel_platforms

Author: cgrindel

haskell/private/bazel_platforms.bzl

@@ -4,8 +4,6 @@
 # implementation for get_cpu_value in lib_cc_configure.bzl.
 # https://github.com/bazelbuild/bazel/blob/e11506feaea7401c3d27f55b47183ef49bd1d5a8/tools/cpp/lib_cc_configure.bzl#L186
 
-# TODO(chuck): Add unit tests.
-
 def _get_os(os_cpu):
     if os_cpu.find("darwin") >= 0:
         return "osx"

rules_haskell_nix/shell.nix

@@ -0,0 +1,3 @@
+load(":bazel_platforms_tests.bzl", "bazel_platforms_test_suite")
+
+bazel_platforms_test_suite()

tests/haskell_tests/BUILD.bazel

@@ -0,0 +1,97 @@
+"""Tests for `bazel_platforms` module."""
+
+load("@bazel_skylib//lib:unittest.bzl", "asserts", "unittest")
+load("//haskell:private/bazel_platforms.bzl", "bazel_platforms")
+
+def _get_os_test(ctx):
+    env = unittest.begin(ctx)
+
+    tests = [
+        struct(
+            msg = "darwin (legacy MacOS on x86_64)",
+            os_cpu = "darwin",
+            exp = "osx",
+        ),
+        struct(
+            os_cpu = "darwin_x86_64",
+            exp = "osx",
+        ),
+        struct(
+            os_cpu = "darwin_arm64",
+            exp = "osx",
+        ),
+        struct(
+            os_cpu = "arm64_windows",
+            exp = "windows",
+        ),
+        struct(
+            os_cpu = "x64_windows",
+            exp = "windows",
+        ),
+        struct(
+            os_cpu = "freebsd",
+            exp = "linux",
+        ),
+        struct(
+            os_cpu = "openbsd",
+            exp = "linux",
+        ),
+    ]
+    for t in tests:
+        actual = bazel_platforms.get_os(t.os_cpu)
+        msg = getattr(t, "msg", t.os_cpu)
+        asserts.equals(env, t.exp, actual, msg)
+
+    return unittest.end(env)
+
+get_os_test = unittest.make(_get_os_test)
+
+def _get_cpu_test(ctx):
+    env = unittest.begin(ctx)
+
+    tests = [
+        struct(
+            msg = "darwin (legacy MacOS on x86_64)",
+            os_cpu = "darwin",
+            exp = "x86_64",
+        ),
+        struct(
+            os_cpu = "darwin_x86_64",
+            exp = "x86_64",
+        ),
+        struct(
+            os_cpu = "darwin_arm64",
+            exp = "arm64",
+        ),
+        struct(
+            os_cpu = "arm64_windows",
+            exp = "arm64",
+        ),
+        struct(
+            os_cpu = "x64_windows",
+            exp = "x86_64",
+        ),
+        struct(
+            os_cpu = "freebsd",
+            exp = "x86_64",
+        ),
+        struct(
+            os_cpu = "openbsd",
+            exp = "x86_64",
+        ),
+    ]
+    for t in tests:
+        actual = bazel_platforms.get_cpu(t.os_cpu)
+        msg = getattr(t, "msg", t.os_cpu)
+        asserts.equals(env, t.exp, actual, msg)
+
+    return unittest.end(env)
+
+get_cpu_test = unittest.make(_get_cpu_test)
+
+def bazel_platforms_test_suite(name = "bazel_platforms_tests"):
+    return unittest.suite(
+        name,
+        get_os_test,
+        get_cpu_test,
+    )