Proper way to install files per user

[jpschewe]

I want to install an application per user in the AppData folder. I've figured out how to reference that and how to have the shortcut removed by adding a RegistryValue and RemoveFolder elements to the Component elements that define the shortct and top-level folder. However I have a number of other files and directories that need to be installed as well. I'm using heat with an XSLT to add the RegistryValue and RemoveFolder elements, however I'm stuck with a folder that only has other folders in it, no files. I'm looking for ideas on the right way to handle this for per user installs.

My problem directory structure looks like this

top dir
|
- reports (does not contain files)
    - test (contains files)
    - js (contains files)

The problem is that "reports" doesn't contain any files and therefore I don't have a place to put the RemoveFolder element.

Here's a snippet of the output from heat + XSLT that shows the issue

                    <Directory Id="dirCAEE038C7A11E53EBBB857C80B50EFED" Name="reports">
                        <Directory Id="dir12C2C874AE93D43C9C0D3835FDC0CB00" Name="test">
                            <Component Id="cmpAC3F3972226051D9DD00E27455C3685B" Guid="{D84C7C76-76E7-40E1-87D9-A92A42C10A94}">
                                <File Id="fil1585DC54F1A630583FB1E85EDB5CA8E6" Source="$(var.sourceDir)\web\documentation\reports\test\index.html" KeyPath="no" />
                                <RegistryValue Root="HKCU" Key="Software\$(var.Manufacturer)" Name="installed" Type="integer" Value="1" KeyPath="yes" />
                                <RemoveFolder On="uninstall" Id="ID0EP4FM" />
                            </Component>
.....

Here you can see I have a RegistryValue and RemoveFolder element for the directory "test" in each of the File elements under the Component that contains the Directory.

It seems odd to me that I end up with multiple RemoveFolder entries in Components for Files rather than putting the RemoveFolder element under Directory. Although adding the RemoveFolder entry under Directly is not valid according to the XML schema.

Am I going about this all wrong?

[jpschewe]

I found an answer, although this seems like lots of work. Perhaps it's because I'm installing to a user folder instead of the program files folder. The XSLT below appears to work.

<?xml version="1.0" encoding="ISO-8859-1"?>
<xsl:stylesheet version="1.0" 
                xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns:wix="http://schemas.microsoft.com/wix/2006/wi"
                xmlns="http://schemas.microsoft.com/wix/2006/wi"
                exclude-result-prefixes="xsl wix">

  <xsl:output method="xml" indent="yes" omit-xml-declaration="yes" />

  <xsl:strip-space elements="*"/>

  <xsl:template match="@*|node()">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="wix:Wix">
    <xsl:copy>
      <xsl:processing-instruction
          name="include">$(sys.CURRENTDIR)install-config.wxi</xsl:processing-instruction>
      <xsl:apply-templates/>
    </xsl:copy>
  </xsl:template>
  
  <xsl:template match="wix:Component/wix:File[@Id]">
    <xsl:variable name="file_unique" select="generate-id()"></xsl:variable>
    
    <xsl:copy>
      <xsl:apply-templates select="@*"/>
      <xsl:attribute name="KeyPath">
        <xsl:text>no</xsl:text>
      </xsl:attribute>
    </xsl:copy>
    <RegistryValue Root="HKCU" Key="Software\$(var.Manufacturer)" Name="installed" Type="integer" Value="1" KeyPath="yes"/>

    <xsl:for-each select="ancestor::wix:Directory">
      <RemoveFolder On="uninstall">
        <!-- need to have a unique ID for Directory + File -->
        <xsl:attribute name="Id">
          <xsl:value-of select="concat($file_unique, '.', generate-id())"/>
        </xsl:attribute>
        <xsl:attribute name="Directory">
          <xsl:value-of select="@Id"/>
        </xsl:attribute>
      </RemoveFolder>
    </xsl:for-each>

  </xsl:template>

  <xsl:template match="wix:Component/wix:File[not(@Id)]">
    <!-- Placeholder for handling anything that should happen
         different for wix:File without @Id attribute.  -->
    <xsl:copy>
      <xsl:apply-templates select="@*"/>
    </xsl:copy>
  </xsl:template>
  
</xsl:stylesheet>