Not working after updating to 3.1.0

[mahdyfo]

I updated the library to 3.1.0 and it stopped working. it doesn't wake up the mcu from deep sleep in this mode:

volatile bool accelActivity = false;
...
myAcc.setInterrupt(ADXL345_ACTIVITY, INT_PIN_2);
myAcc.setDataRate(ADXL345_DATA_RATE_25);
myAcc.setRange(ADXL345_RANGE_2G);
attachInterrupt(digitalPinToInterrupt(PIN_ACCEL_INT2), accelActivityISR, RISING);
...
void accelActivityISR() {
  accelActivity = true;
}

I didn't check other modes.
atmega328pb

I downgraded to 3.0.6 and it is working correctly again.

[wollewald]

I tried, but I can't reproduce this problem.

I took an ARD-NanoV4-MC from Joy-IT which is based on an ATMEGA328PB. The board package I have used is MiniCore from MCUdude, version 3.1.1. And I took the latest version of my library, 3.1.0

I have applied the following small sketch:

#include <avr/sleep.h>
#include<Wire.h>
#include<ADXL345_WE.h>
#define ADXL345_I2CADDR 0x53
const int int2Pin = 2;
volatile bool accel_activity = false; 

ADXL345_WE myAcc = ADXL345_WE(ADXL345_I2CADDR);

void setup() {
  Wire.begin();
  Serial.begin(115200);
  pinMode(int2Pin, INPUT);
  if (!myAcc.init()) {
    Serial.println("ADXL345 not connected!");
  }
  
  myAcc.setDataRate(ADXL345_DATA_RATE_25);
  myAcc.setRange(ADXL345_RANGE_2G);
 
  attachInterrupt(digitalPinToInterrupt(int2Pin), accelActivityISR, RISING);
  myAcc.setActivityParameters(ADXL345_DC_MODE, ADXL345_XY0, 0.5);
  myAcc.setInterrupt(ADXL345_ACTIVITY, INT_PIN_2);
  myAcc.readAndClearInterrupts();  
}

void loop() {
  static unsigned long lastWakeUp = 0;
  if (millis() - lastWakeUp > 5000) {
    set_sleep_mode(SLEEP_MODE_PWR_DOWN); 
    myAcc.readAndClearInterrupts();
    sleep_mode(); // sleep now!
    lastWakeUp = millis();
    accel_activity = false;
    Serial.println("I woke up!");
  }
  
  /* to indicate that the MCU is awake we let display 
     some values every second */
  if ((millis() % 1000) == 1) {   
    xyzFloat g;
    myAcc.getGValues(&g);
    Serial.print("g-x   = ");
    Serial.print(g.x);
    Serial.print("  |  g-y   = ");
    Serial.print(g.y);
    Serial.print("  |  g-z   = ");
    Serial.println(g.z);
    Serial.flush();
    delay(1);
  }
}

void accelActivityISR() {
  accel_activity = true;
}

As expected, the ATmega328PB goes in deep sleep mode after 5 seconds. If I then turn the ADXL342 board an activity interrupt is triggered and wakes up the ATmega328PB. It displays: "I woke up!" and some acceleration values. Then it goes into deep sleep again. I tried this several times and it works reliably on my side. So, basically, activity interrupts can wake up the ATmega328PB when using my library version 3.1.0.

This leads to the question what's different on your side. Two things would be helpful: 1) You try the sketch above and tell me if it works. 2) You share more details: complete code, board, board package. If your sketch is too big and/or uses lots of other devices. it would help if you boil it down to the relevant part but which still shows the issue.

[mahdyfo]

I used LowPower.h with SLEEP_8S adc_off bod_off. Also watchdogs that are disabled before going to sleep. AC_MODE, XYZ, 0.25 threshold on 3.3v. available ram: 561bytes. MiniCore board, internal 8Mhz, LTO enabled. Raw atmega328pb-mu without any development board.

[wollewald]

I have change the code accordingly:

#include "LowPower.h"
#include<Wire.h>
#include<ADXL345_WE.h>
#define ADXL345_I2CADDR 0x53
const int int2Pin = 2;
volatile bool accel_activity = false; 

ADXL345_WE myAcc = ADXL345_WE(ADXL345_I2CADDR);

void setup() {
  Wire.begin();
  Serial.begin(115200);
  pinMode(int2Pin, INPUT);
  if (!myAcc.init()) {
    Serial.println("ADXL345 not connected!");
  }
  
  myAcc.setDataRate(ADXL345_DATA_RATE_25);
  myAcc.setRange(ADXL345_RANGE_2G);
 
  attachInterrupt(digitalPinToInterrupt(int2Pin), accelActivityISR, RISING);
  myAcc.setActivityParameters(ADXL345_DC_MODE, ADXL345_XY0, 0.5);
  myAcc.setInterrupt(ADXL345_ACTIVITY, INT_PIN_2);
  myAcc.readAndClearInterrupts();  
}

void loop() {
  static unsigned long lastWakeUp = 0;
  if (millis() - lastWakeUp > 5000) {
    myAcc.readAndClearInterrupts();
    LowPower.powerDown(SLEEP_8S, ADC_OFF, BOD_OFF);
    lastWakeUp = millis();
    accel_activity = false;
    Serial.println("I woke up!");
  }
  
  /* to indicate that the MCU is awake we let display 
     some values every second */
  if ((millis() % 1000) == 1) {   
    xyzFloat g;
    myAcc.getGValues(&g);
    Serial.print("g-x   = ");
    Serial.print(g.x);
    Serial.print("  |  g-y   = ");
    Serial.print(g.y);
    Serial.print("  |  g-z   = ");
    Serial.println(g.z);
    Serial.flush();
    delay(1);
  }

}

void accelActivityISR() {
  accel_activity = true;
}

Still it works. Either the ATmega328PB wakes up after 8 seconds or I can wake it up before with the activity interrupt.

LTO is enabled. Difference: I still use the board with a 16 MHz external crystal and 3.3 volts.

This is what I could do short term. It will take time until I can try it at 8 MHz / internal oszillator. But I don't think it this what is relevant for the issue. I assume it's something specific in the code. So, again it would be helpful if you can share more of your code, at least the relevant parts. And it would be helpful if you could try my code. If you don't have access to the Serial monitor you could let an an LED blink to show the MCU woke up.

I need to be able to replicate the issue before I can do anything about it.

[wollewald]

For the sake of completeness (from my side): It also worked at 3.3 V, 8 MHz internal. Only very slight change to the sketch:

#include "LowPower.h"
#include<Wire.h>
#include<ADXL345_WE.h>
#define ADXL345_I2CADDR 0x53
const int int2Pin = 2;
volatile bool accel_activity = false; 

ADXL345_WE myAcc = ADXL345_WE(ADXL345_I2CADDR);

void setup() {
  Wire.begin();
  Serial.begin(115200);
  pinMode(int2Pin, INPUT);
  if (!myAcc.init()) {
    Serial.println("ADXL345 not connected!");
  }
  
  myAcc.setDataRate(ADXL345_DATA_RATE_25);
  myAcc.setRange(ADXL345_RANGE_2G);
 
  attachInterrupt(digitalPinToInterrupt(int2Pin), accelActivityISR, RISING);
  myAcc.setActivityParameters(ADXL345_DC_MODE, ADXL345_XY0, 0.5);
  myAcc.setInterrupt(ADXL345_ACTIVITY, INT_PIN_2);
  myAcc.readAndClearInterrupts();  
}

void loop() {
  static unsigned long lastWakeUp = 0;
  static unsigned long lastValue = 0;
  if (millis() - lastWakeUp > 5000) {
    myAcc.readAndClearInterrupts();
    LowPower.powerDown(SLEEP_8S, ADC_OFF, BOD_OFF);
    lastWakeUp = millis();
    accel_activity = false;
    Serial.println("I woke up!");
  }
  
  /* to indicate that the MCU is awake we let display 
     some values every second */
  if (millis() - lastValue > 1000) {   
    xyzFloat g;
    myAcc.getGValues(&g);
    Serial.print("g-x   = ");
    Serial.print(g.x);
    Serial.print("  |  g-y   = ");
    Serial.print(g.y);
    Serial.print("  |  g-z   = ");
    Serial.println(g.z);
    Serial.flush();
    lastValue = millis();
  }
}

void accelActivityISR() {
  accel_activity = true;
}