add custom consistency level

Author: evan-gray

src/interfaces/ICustomConsistencyLevel.sol

@@ -0,0 +1,21 @@
+// SPDX-License-Identifier: Apache 2
+pragma solidity ^0.8.0;
+
+// from https://github.com/wormhole-foundation/wormhole/blob/39081fa2936badf178f8b7e5eb63074d3308bf7d/ethereum/contracts/custom_consistency_level/interfaces/ICustomConsistencyLevel.sol
+interface ICustomConsistencyLevel {
+    /// @notice The configuration for an emitter has been set.
+    /// @dev Topic0
+    ///      0xa37f0112e03d41de27266c1680238ff1548c0441ad1e73c82917c000eefdd5ea.
+    /// @param emitterAddress The emitter address for which the config has been set.
+    /// @param config The config data that was set.
+    event ConfigSet(address emitterAddress, bytes32 config);
+
+    /// @notice Sets / updates the configuration for a given emitter address (msg.sender).
+    /// @param config The config used to determine the custom consistency level handling for an emitter.
+    function configure(bytes32 config) external;
+
+    /// @notice Returns the configuration for a given emitter address.
+    /// @param emitterAddress The emitter address for which the config has been set.
+    /// @return The configuration.
+    function getConfiguration(address emitterAddress) external returns (bytes32);
+}

src/libraries/ConsistencyConfigMakers.sol

@@ -0,0 +1,28 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.0;
+
+// from https://github.com/wormhole-foundation/wormhole/blob/39081fa2936badf178f8b7e5eb63074d3308bf7d/ethereum/contracts/custom_consistency_level/libraries/ConfigMakers.sol
+library ConsistencyConfigMakers {
+    uint8 public constant TYPE_ADDITIONAL_BLOCKS = 1;
+
+    // from https://github.com/wormhole-foundation/wormhole/blob/39081fa2936badf178f8b7e5eb63074d3308bf7d/ethereum/contracts/libraries/external/BytesLib.sol#L385-L394
+    function toBytes32(bytes memory _bytes, uint256 _start) internal pure returns (bytes32) {
+        require(_bytes.length >= _start + 32, "toBytes32_outOfBounds");
+        bytes32 tempBytes32;
+
+        assembly {
+            tempBytes32 := mload(add(add(_bytes, 0x20), _start))
+        }
+
+        return tempBytes32;
+    }
+
+    /// @notice Encodes an additional blocks custom consistency level configuration.
+    /// @param consistencyLevel The consistency level to wait for.
+    /// @param blocksToWait The number of additional blocks to wait after the consistency level is reached.
+    /// @return bytes The encoded config.
+    function makeAdditionalBlocksConfig(uint8 consistencyLevel, uint16 blocksToWait) internal pure returns (bytes32) {
+        bytes28 padding;
+        return toBytes32(abi.encodePacked(TYPE_ADDITIONAL_BLOCKS, consistencyLevel, blocksToWait, padding), 0);
+    }
+}

test/CustomConsistencyLevel.t.sol

@@ -0,0 +1,14 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.0;
+
+import {Test, console} from "forge-std/Test.sol";
+import {ConsistencyConfigMakers} from "../src/libraries/ConsistencyConfigMakers.sol";
+
+// from https://github.com/wormhole-foundation/wormhole/blob/39081fa2936badf178f8b7e5eb63074d3308bf7d/ethereum/forge-test/CustomConsistencyLevel.t.sol
+contract CustomConsistencyLevelTest is Test {
+    function test_makeAdditionalBlocksConfig() public {
+        bytes32 expected = 0x01c9002a00000000000000000000000000000000000000000000000000000000;
+        bytes32 result = ConsistencyConfigMakers.makeAdditionalBlocksConfig(201, 42);
+        assertEq(expected, result);
+    }
+}