Using only one of the features

[GhostHawk272]

Is it possible to only use one of the features? I am looking to use the 'change text case' feature, it works really well for me and it's exactly what I need. However, I don't want to use the other features from the project. Is there a way to only have that part of the code active?

[xypha]

It's certainly possible. Download the main script and keep the code for the feature you want ( ; Settings, Hotkeys > Change Text Case , User-defined functions > Change Text Case, CallClipboard, PasteThis) and comment out everything else (using ; or /* comment section */ ).

If you mess up, use the error msg dialogue boxes and the AHK help file to troubleshoot

[GhostHawk272]

Thank you. I will try this out.

[xypha]

I tried to create one quickly. It was complicated.
Here is a fast and dirty version that should work in most situations.

Code -

; Settings
;  = Set Global variables
;    + MenuShortcuts
;    + Path to Menu() icons
; Hotkeys
;  = Change Text Case
; User-defined functions
;  = Change Text Case
;    + ChangeCaseMenuFn
;    + ConvertLower
;    + ConvertSentence
;    + ConvertTitle
;    + ConvertUpper
;    + ConvertInvert
;    + CaseConvert
;  = Clipboard Fn
;    + CallClipboard
;  = ToolTip function
;    + ToolTipFn
;  = Paste instead of Send
;    + PasteThis
;    + Paste_via_clipboard
;    + RestoreClip

;------------------------------------------------------------------------------
; Settings
; Start of script code

#Requires AutoHotkey v2.0
#SingleInstance force
#WinActivateForce
KeyHistory 500 ; Max 500

;--------
;  = Set Global variables

;    + MenuShortcuts

; create array to store shortcuts used in Menu() functions
Global MenuShortcuts := StrSplit("1234567890QwertYuioPasdfG")

/* ; shortcuts for each menu item consist of numbers from number row, and letters from the rows below it in a QUERTY keyboard
; Customise the shortcut characters and their order by altering the characters in `MenuShortcuts` variable as needed
menu item 1 Shortcut 1 ; number row
menu item 2 Shortcut 2
menu item 3 Shortcut 3
menu item 4 Shortcut 4
menu item 5 Shortcut 5
menu item 6 Shortcut 6
menu item 7 Shortcut 7
menu item 8 Shortcut 8
menu item 9 Shortcut 9
menu item 10 Shortcut 0
menu item 11 Shortcut Q ; 1st letter row
menu item 12 Shortcut w
menu item 13 Shortcut e
menu item 14 Shortcut r
menu item 15 Shortcut t
menu item 16 Shortcut Y
menu item 17 Shortcut u
menu item 18 Shortcut i
menu item 19 Shortcut o
menu item 20 Shortcut P
menu item 21 Shortcut a ; 2nd letter row
menu item 22 Shortcut s
menu item 23 Shortcut d
menu item 24 Shortcut f
menu item 25 Shortcut G
; QYPG are capitals because selection underline causes confusion with other letters like o or v
; pressing shift + letter is not necessary because shortcuts are NOT case-sensitive
*/

;--------
;    + Path to Menu() icons

; Icon Source: Calendar by Kalash - CC BY 4.0 - https://icon-icons.com/pack/Calendar/4173
; Icons were cropped using https://bulkimagecrop.com/ ; and converted to jpg and resized using mspaint (classic)
; To download and save the icons in below path, visit
; https://github.com/xypha/AHK-v2-scripts/blob/main/icons/Menu/

Global Menu_icon_path := A_MyDocuments "\icons\Menu\"
; icons are saved in default path of AHK's built-in variable: A_MyDocuments
; A_MyDocuments is the full path and name of the current user's "My Documents" folder. Usually corresponds to "C:\Users\<UserName>\Documents" (the final backslash is not included in the variable)

;------------------------------------------------------------------------------
; Hotkeys

;  = Change Text Case

!c::ChangeCaseMenuFn()      ; Alt + C

;------------------------------------------------------------------------------
; User-defined functions

;  = Change Text Case

; inspired from https://geekdrop.com/content/super-handy-AutoHotkey-ahk-script-to-change-the-case-of-text-in-line-or-wrap-text-in-quotes

;    + ChangeCaseMenuFn

ChangeCaseMenuFn() {
ChangeCaseMenu := Menu()
ChangeCaseMenu.Delete
ChangeCaseMenu.Add("&1 lower case"      ,ConvertLower)
ChangeCaseMenu.Add("&2 Sentence case"   ,ConvertSentence)
ChangeCaseMenu.Add("&3 Title Case"      ,ConvertTitle)
ChangeCaseMenu.Add("&4 UPPER CASE"      ,ConvertUpper)
ChangeCaseMenu.Add("&5 iNVERT cASE"     ,ConvertInvert)
ChangeCaseMenu.Show
}

;--------
;    + ConvertLower

ConvertLower(*) {
CallClipboard(2) ; 2s, Exit
CaseConvert(StrLower(A_Clipboard))
}

;--------
;    + ConvertSentence

ConvertSentence(*) {
CallClipboard(2) ; 2s, Exit
CaseConvert(RegExReplace(StrLower(A_Clipboard), "(((^\s*|([.!?]+\s*))[a-z])|\Wi\W)", "$U1")) ; Code Credit #1
}

; RegEx explanation -
; \s = [\r\n\t\f\v ]
; $U1 = back reference uppercase 1
; \W = [^a-zA-Z0-9_] = any character that is NOT alphabet, number, underscore

;--------
;    + ConvertTitle

ConvertTitle(*) {
CallClipboard(2) ; 2s, Exit
CaseConvert(StrTitle(A_Clipboard))
}

;--------
;    + ConvertUpper

ConvertUpper(*) {
CallClipboard(2) ; 2s, Exit
CaseConvert(StrUpper(A_Clipboard))
}

;--------
;    + ConvertInvert

ConvertInvert(*) {
CallClipboard(2) ; 2s, Exit
inverted := ""
Loop Parse A_Clipboard {                        ; Code Credit #2
    If StrLower(A_LoopField) == A_LoopField     ; * Code Credit #3
        inverted .= StrUpper(A_LoopField)       ; *
    Else inverted .= StrLower(A_LoopField)      ; *
    }
CaseConvert(inverted)
}
; Unicode TestString  :=
; abcdefghijklmnopqrstuvwxyzéâäàåçêëèïîìæôöòûùÿáíóúñABCDEFGHIJKLMNOPQRSTUVWXYZÉÂÄÀÅÇÊËÈÏÎÌÆÔÖÒÛÙŸÁÍÓÚÑ
; Unicode iNVERT cASE :=
; ABCDEFGHIJKLMNOPQRSTUVWXYZÉÂÄÀÅÇÊËÈÏÎÌÆÔÖÒÛÙŸÁÍÓÚÑabcdefghijklmnopqrstuvwxyzéâäàåçêëèïîìæôöòûùÿáíóúñ

;--------
;    + CaseConvert

CaseConvert(caseText) {
string := StrReplace(caseText, "`r") ; remove \r
Len := StrLen(string)
PasteThis(string)   ; Paste
If Len <= 20        ; and select text only if text ≤ 20 characters (change limit as needed)
    Send "+{Left " Len "}"
}

; Code Credit #1 - NeedleRegEx pattern modified from https://www.autohotkey.com/board/topic/24431-convert-text-uppercase-lowercase-capitalized-or-inverted/?p=158295
; Code Credit #2 - idea for loop modified from https://www.autohotkey.com/boards/viewtopic.php?p=58417#p58417
; Code Credit #3 - 3 lines of code with a comment "; *" were adapted from a (inaccurate) answer generated from a query to KudoAI's DuckDuckGPT user script - https://greasyfork.org/en/scripts/459849-duckduckgpt


;------------------------------------------------------------------------------
;  = Clipboard Fn

;    + CallClipboard

CallClipboard(secs := 2, retrn := 0) {
ToolTipFn("Waiting for clipboard", secs * 1000)     ; 2s
Global clipSave := ClipboardAll()                   ; Global = Return clipSave
A_Clipboard := ""
Send "^c"
If not ClipWait(secs) {
    ToolTipFn(A_ThisHotkey ":: Clip Failed", 2000)  ; 2s
    A_Clipboard := clipSave
    If retrn = 0
        Exit
    Else Return "err0r"                             ; If retrn = 1
    }
ToolTipFn(A_Clipboard)
}

;------------------------------------------------------------------------------
;  = ToolTip function

;    + ToolTipFn

ToolTipFn(mytext, myduration := 500, xAxis?, yAxis?) { ; 500ms
If not IsSet(WhichToolTip)
    Static WhichToolTip := 1    ; 1
Else {
    ToolTip(,,, WhichToolTip)   ; turn Off previous ToolTip
    WhichToolTip++              ; add 1 to variable
}

; If WhichToolTip variable exceeds 20
If WhichToolTip > 20            ; inbuilt limit of 20
    WhichToolTip := 1           ; reset to 1

ToolTip mytext, xAxis?, yAxis?, WhichToolTip
SetTimer () => ToolTip(,,, WhichToolTip), Abs(myduration) * -1 ; 500ms ; new thread ; always negative number
}

;------------------------------------------------------------------------------
;  = Paste instead of Send
; Modified from https://www.autohotkey.com/boards/viewtopic.php?p=483549#p483549 and https://www.autohotkey.com/boards/viewtopic.php?p=483588#p483588
; alternative to inbuilt command - EditPaste String, Control [, WinTitle, WinText, ExcludeTitle, ExcludeText]

;    + PasteThis

PasteThis(pasteText) {
If StrLen(pasteText) <= 15  ; 15; If short text, Send keystrokes instead of paste
    SendText pasteText      ; text mode to prevent unintended key press when text contains '^+!#{}'
Else Paste_via_clipboard(pasteText)
}

;--------
;    + Paste_via_clipboard

Paste_via_clipboard(pasteText) {
If A_Clipboard !== pasteText {
    tmp_clip := ClipboardAll()          ; preserve Clipboard
    A_Clipboard := pasteText            ; copy pasteText to clipboard
    tmp_clip2 := A_Clipboard
    While tmp_clip2 !== pasteText {     ; validate clipboard
        Sleep 50                        ; 50ms
        If A_Index > 5 {                ; max 250ms
            ToolTipFn(A_ThisHotkey ":: PasteThis tmp_clip copying Failed?")     ; 500ms
            Exit
            }
        }
    }
Else tmp_clip := A_Clipboard
Send "^v"                                                   ; paste
If tmp_clip !== pasteText
    SetTimer () => RestoreClip(tmp_clip, tmp_clip2), -100   ; 100ms  ; new thread - don't wait for restoration
}

;--------
;    + RestoreClip

RestoreClip(tmp_clip, tmp_clip2) {
A_Clipboard := ClipboardAll(tmp_clip)   ; restore clipboard
While tmp_clip2 == A_Clipboard {        ; validate clipboard
    Sleep 50                            ; 50ms
    If A_Index > 5 {                    ; max 250ms
        ToolTipFn(A_ThisHotkey ":: RestoreClip restoration failed!", 5000) ; 5s
        Exit
        }
    }
tmp_clip := ""
tmp_clip2 := ""
}

Save the above code as a script and run it.
To make the menu icons work, download the icons from the folder and save them on your pc and edit the variable Menu_icon_path in the script