[bug]: git diff "$(fzf)" evaluates automatically

[YodaEmbedding]

Describe the bug

git diff "$(fzf)"

1. Automatically evaluates fzf when going backwards in history.
2. The highlighting of the quotes is wrong.

No, I am not insane. (I hope.)

Steps to reproduce

rm ~/.zshrc
echo 'source "$HOME/.local/share/zinit/plugins/zdharma-continuum---fast-syntax-highlighting/fast-syntax-highlighting.plugin.zsh"' > ~/.zshrc
zsh

mkdir tmp
cd tmp
git init
git diff "$(fzf)"
# Type: <C-c><Up><Space><C-c><Up><Space>
# wat
git diff "$(echo why is every keypress doubling)"

Expected behavior

Not 1 and 2.

Screenshots and recordings

No response

Operating System & Version

darwin23.0 | apple | x86_64 | arm64 | arm64 arm

Zsh version

zsh 5.9 (x86_64-apple-darwin23.0)

Terminal emulator

iTerm2 with xterm-256color

If using WSL on Windows, which version of WSL

None

Additional context

No response

[vegerot]

To be honest I didn't believe you, but I can reproduce it 😁

[DarioDarko]

i can confirm this too (also they double keypress issue)

this doesnt happen with my global alias though:

alias -g _f='"$(fd --hidden --type file | fzf)"'
git diff _f

[gothink]

I'm able to reproduce this as well. I was curious so I ended up digging a little deeper and ended up falling down a rabbit hole. Apologies for the long-winded response.

Basically, anytime the plugin highlights lines that contain certain git subcommands, it tries to verify if the string you're typing is a valid commit by running git rev-parse --verify --quiet $USER_INPUT, where $USER_INPUT is the contents of the buffer after the subcommand. So anytime the line needs to be (re-)highlighted, the command in the subshell is run again.

The problem seems to arise in the →chroma/-git-verify-commit function in -git.ch which calls out to .fast-run-git-command. The subset of git subcommands that call →chroma/-git-verify-commit are diff, checkout, merge, reset, revert, log and tag.

What's even worse is that all quotes are stripped from the input before executing (using the Q flag), so even if you wrap the subshell in single quotes, it is still executed! For instance, this (unlikely) command: git diff '$(rm -rf ./)' would delete the current directory (only in a git repo) anytime it passes through the highlighter. Just type it in or pull it up from history. Actually running the command does not execute the subshell.

I'm not sure what the best approach to fixing this would be. I probably won't be running this plugin anymore, so I'll leave that to those who are. In the meantime, you can disable/re-assign specific chromas (see below).

Other things I noticed:

1. It uses $EPOCHSECONDS to set/check when the cache was created for a command. But it never loads the zsh/datetime module, so unless you loaded it yourself (or another plugin did), it will never expire the cache.

   To fix this, just load the module before the plugin: zmodload zsh/datetime.

2. Not exactly an issue, but it also checks if you're in a git repo every time it receives new input (after one of the aforementioned git subcommands), which can end up happening repeatedly as you type a new command. So the plugin is running git rev-parse --is-inside-work-tree constantly as you type.

Disabling -git.ch chroma

You can disable the git chroma functionality altogether by pointing it to the generic -subcommand.ch chroma.

Add this to your config somewhere after loading the fast-syntax-highlighting plugin (make sure the → unicode char copies properly!):

FAST_HIGHLIGHT[chroma-git]="→chroma/-subcommand.ch"

Or, to disable special highlighting entirely:

unset "FAST_HIGHLIGHT[chroma-git]"

Reproducing the issues

My setup:

• OS & Version: linux-gnu | pc | x86_64 | x86_64 | x86_64 unknown
• Zsh version: zsh 5.9 (x86_64-pc-linux-gnu)
• Terminal emulator: konsole 25.04.1 / xterm-256color

Subshell execution

I was able to track down the primary issue by using the →chroma/main-chroma-print function, which prints to a debug file (/tmp/fsh-dbg) if FAST_HIGHLIGHT[DEBUG] is set, then writing to that same file from within the subshell argument in a git subcommand.

In -git.ch:

# Add some extra debug logging
→chroma/-git-verify-commit() {
    →chroma/main-chroma-print "in -git-verify-commit" # debug
    local _wrd="$4"
    __lines_list=()
    →chroma/main-chroma-print "calling .fast-run-git-command" # debug
    .fast-run-git-command --status "git rev-parse --verify --quiet \"$_wrd\"" \
                        "chroma-git-commits-$PWD-$_wrd" "" $(( 1.5 * 60 ))
    →chroma/main-chroma-print "returned from .fast-run-git-command" # debug
    if (( __lines_list[1] == 0 )); then
        __style=${FAST_THEME_NAME}correct-subtle
        return 0
    fi
    __style=${FAST_THEME_NAME}incorrect-subtle
    return 1
}

Then, in your shell:

source fast-syntax-highlighting/fast-syntax-highlighting.plugin.zsh
FAST_HIGHLIGHT[DEBUG]=1
cd fast-syntax-highlighting
git diff $(echo BOOP >> /tmp/fsh-dbg)
# or even:
git diff '$(echo BOOP >> /tmp/fsh-dbg)'

Result in /tmp/fsh-dbg:

...
Running handler(3): →chroma/-git-verify-commit-or-file-or-dir  
in -git-verify-commit  
calling .fast-run-git-command  
BOOP  
returned from .fast-run-git-command
...

Cache timestamps

verify zsh/datetime isn't loaded

# zmodload -e returns 0 if <arg> matches loaded module, 1 if not
zmodload -e zsh/datetime && print "loaded" || print "not loaded"

install the plugin, type some commands, check cache timestamps

source fast-syntax-highlighting/fast-syntax-highlighting.plugin.zsh
git diff # just type this, no need to execute it
print -l ${(kv)FAST_HIGHLIGHT[(I)*-cache-born-at]}

Notice that only the key(s) are returned if zsh/datetime isn't loaded. The conditional that handles this looks like this:

if [[ -z ${FAST_HIGHLIGHT[$2-cache]} || $(( EPOCHSECONDS - FAST_HIGHLIGHT[$2-cache-born-at] )) -gt ${4:-5} ]]; then
# refill cache

Which results in: [[ ... || $(( 0 - 0 )) -gt N ]] and since N is a positive integer, it will always return false if the cache isn't empty.

Luckily, the fix for this is simple. Just load the module before the plugin:

zmodload zsh/datetime
# ...
source fast-syntax-highlighting/fast-syntax-highlighting.plugin.zsh

git command frequency

in .fast-run-git-command:

echo "BOOP" >> /tmp/gitruns.txt # add this line
if [[ "$(command git rev-parse --is-inside-work-tree 2>/dev/null)" = true ]]; then
# ...

then start typing some git commands (you don't need to be in a git repo!):

git diff "they dont need to be valid"
git diff "you dont even need to hit enter" # not executed
wc -l /tmp/gitruns.txt
# 60 /tmp/gitruns.txt

That's 60 calls to git!

[vegerot]

@gothink that's awesome. Thanks! 😁