scripts: template_setup_win: Add web-based toolchain installation

This commit adds the feature to download and install individual
toolchains from the web release assets if not all toolchains are
locally installed (e.g. minimal web install distribution archive).

Signed-off-by: Stephanos Ioannidis <[email protected]>

Author: stephanosio

scripts/template_setup_win

@@ -7,9 +7,53 @@ pushd %~dp0
 setlocal ENABLEDELAYEDEXPANSION
 set EXITCODE=0
 
+goto entry
+
+REM # Check if command is available
+:check_command
+where %1 > nul 2>&1
+if [%ERRORLEVEL%] neq [0] (
+  echo Zephyr SDK setup requires '%1' to be installed and available in the PATH.
+  echo Please install '%1' and run this script again.
+
+  set EXITCODE=%2
+  exit /b 1
+)
+exit /b 0
+
+:entry
+
+REM # Initialise toolchain list
+set TOOLCHAINS=
+set TOOLCHAINS=%TOOLCHAINS% aarch64-zephyr-elf
+set TOOLCHAINS=%TOOLCHAINS% arc64-zephyr-elf
+set TOOLCHAINS=%TOOLCHAINS% arc-zephyr-elf
+set TOOLCHAINS=%TOOLCHAINS% arm-zephyr-eabi
+set TOOLCHAINS=%TOOLCHAINS% mips-zephyr-elf
+set TOOLCHAINS=%TOOLCHAINS% nios2-zephyr-elf
+set TOOLCHAINS=%TOOLCHAINS% riscv64-zephyr-elf
+set TOOLCHAINS=%TOOLCHAINS% sparc-zephyr-elf
+set TOOLCHAINS=%TOOLCHAINS% x86_64-zephyr-elf
+set TOOLCHAINS=%TOOLCHAINS% xtensa-espressif_esp32_zephyr-elf
+set TOOLCHAINS=%TOOLCHAINS% xtensa-espressif_esp32s2_zephyr-elf
+set TOOLCHAINS=%TOOLCHAINS% xtensa-intel_apl_adsp_zephyr-elf
+set TOOLCHAINS=%TOOLCHAINS% xtensa-intel_bdw_adsp_zephyr-elf
+set TOOLCHAINS=%TOOLCHAINS% xtensa-intel_byt_adsp_zephyr-elf
+set TOOLCHAINS=%TOOLCHAINS% xtensa-intel_s1000_zephyr-elf
+set TOOLCHAINS=%TOOLCHAINS% xtensa-nxp_imx_adsp_zephyr-elf
+set TOOLCHAINS=%TOOLCHAINS% xtensa-nxp_imx8m_adsp_zephyr-elf
+set TOOLCHAINS=%TOOLCHAINS% xtensa-sample_controller_zephyr-elf
+
+REM Initialise list of toolchains to install
+set INST_TOOLCHAINS=
+
 REM # Read bundle version from file
 set /p VERSION=<sdk_version
 
+REM # Resolve release download base URI
+set DL_REL_BASE=https://github.com/zephyrproject-rtos/sdk-ng/releases/download/v%VERSION%
+set DL_TOOLCHAIN_FILENAME=toolchain_windows-x86_64_%%t.zip
+
 REM # Print banner
 echo Zephyr SDK %VERSION% Setup
 echo.
@@ -20,14 +64,13 @@ if [%1] equ [] (
 )
 
 REM # Check dependencies
-where cmake > nul 2>&1
-if [%ERRORLEVEL%] neq [0] (
-  echo Zephyr SDK setup requires CMake to be installed and available in the PATH.
-  echo Please install CMake and run this script again.
 
-  set EXITCODE=90
-  goto end
-)
+call :check_command cmake 90
+if [%ERRORLEVEL%] neq [0] goto end
+call :check_command wget 91
+if [%ERRORLEVEL%] neq [0] goto end
+call :check_command unzip 92
+if [%ERRORLEVEL%] neq [0] goto end
 
 REM # Enter interactive mode if enabled
 if [%INTERACTIVE%] neq [] (
@@ -36,10 +79,25 @@ if [%INTERACTIVE%] neq [] (
 
 REM # Parse arguments if specified
 :parsearg
-if /i [%1] equ [/c] (
-  set DO_CMAKE_PKG=y
-) else if /i [%1] equ [/t] (
+if /i [%1] equ [/t] (
+  if [%2] equ [all] (
+    set INST_TOOLCHAINS=%TOOLCHAINS%
+  ) else (
+    set IS_VALID=
+    for %%t in (%TOOLCHAINS%) do if [%%t] equ [%2] set IS_VALID=y
+    if [!IS_VALID!] equ [y] (
+      set INST_TOOLCHAINS=!INST_TOOLCHAINS! %2
+    ) else (
+      echo ERROR: Unknown toolchain '%2'
+      set EXITCODE=2
+      goto end
+    )
+  )
+  shift
+) else if /i [%1] equ [/h] (
   set DO_HOSTTOOLS=y
+) else if /i [%1] equ [/c] (
+  set DO_CMAKE_PKG=y
 ) else (
   goto usage
 )
@@ -58,21 +116,67 @@ echo You only need to run this script once after extracting the Zephyr SDK
 echo distribution bundle archive.
 echo.
 
+REM # Check installation type
+for %%t in (%TOOLCHAINS%) do (
+  if not exist %%t\ (
+    set IS_PARTIAL_SDK=y
+  )
+)
+
 REM # Ask user for set-up choices
-choice /c:yn /m:"Register Zephyr SDK CMake package"
-if [%ERRORLEVEL%] equ [1] set DO_CMAKE_PKG=y
+if [%IS_PARTIAL_SDK%] neq [] (
+  choice /c:yn /m:"Install toolchains for all targets"
+  if [!ERRORLEVEL!] equ [1] (
+    set INST_TOOLCHAINS=%TOOLCHAINS%
+  ) else (
+    for %%t in (%TOOLCHAINS%) do (
+      if not exist %%t\ (
+        choice /c:yn /m:"Install '%%t' toolchain"
+        if [!ERRORLEVEL!] equ [1] (
+          set INST_TOOLCHAINS=!INST_TOOLCHAINS! %%t
+        )
+      )
+    )
+  )
+)
 
 choice /c:yn /m:"Install host tools"
 if [%ERRORLEVEL%] equ [1] set DO_HOSTTOOLS=y
 
+choice /c:yn /m:"Register Zephyr SDK CMake package"
+if [%ERRORLEVEL%] equ [1] set DO_CMAKE_PKG=y
+
 echo.
 
 :process
-REM # Register Zephyr SDK CMake package
-if [%DO_CMAKE_PKG%] neq [] (
-  echo Registering Zephyr SDK CMake package ...
-  cmake -P cmake\zephyr_sdk_export.cmake
-  echo.
+REM # Install toolchains
+for %%t in (%INST_TOOLCHAINS%) do (
+  set TOOLCHAIN_FILENAME=%DL_TOOLCHAIN_FILENAME%
+  set TOOLCHAIN_URI=%DL_REL_BASE%/!TOOLCHAIN_FILENAME!
+
+  if not exist %%t\ (
+    echo Installing '%%t' toolchain ...
+
+    REM # Download toolchain archive
+    wget -q --show-progress -N -O !TOOLCHAIN_FILENAME! !TOOLCHAIN_URI!
+    if [!ERRORLEVEL!] neq [0] (
+      del /q !TOOLCHAIN_FILENAME!
+      echo ERROR: Toolchain download failed
+      set EXITCODE=20
+      goto end
+    )
+
+    REM # Extract archive
+    unzip -q !TOOLCHAIN_FILENAME!
+    if [!ERRORLEVEL!] neq [0] (
+      echo ERROR: Toolchain archive extraction failed
+      set EXITCODE=21
+      goto end
+    )
+
+    REM # Remove archive
+    del /q !TOOLCHAIN_FILENAME!
+  )
 )
 
 REM # Install host tools
@@ -82,15 +186,34 @@ if [%DO_HOSTTOOLS%] neq [] (
   echo.
 )
 
+REM # Register Zephyr SDK CMake package
+if [%DO_CMAKE_PKG%] neq [] (
+  echo Registering Zephyr SDK CMake package ...
+  cmake -P cmake\zephyr_sdk_export.cmake
+  if [!ERRORLEVEL!] neq [0] (
+    set EXITCODE=40
+    goto end
+  )
+  echo.
+)
+
 echo All done.
 goto end
 
 REM # Print scripting mode usage
 :usage
-echo %~n0 [/c] [/t]
+echo %~n0 [/t ^<toolchain^>] [/h] [/c]
+echo.
+echo   /t ^<toolchain^>   Install specified toolchain
+echo      all           Install all toolchains
+echo   /h               Install host tools
+echo   /c               Register Zephyr SDK CMake package
 echo.
-echo   /c     Register Zephyr SDK CMake package
-echo   /t     Install host tools
+echo Supported Toolchains:
+echo.
+for %%t in (%TOOLCHAINS%) do (
+  echo %%t
+)
 echo.
 echo When no arguments are specified, the setup script runs in the interactive
 echo mode asking for user inputs.