Using the Windows Key to open and close Flow

[onesounds]

Try Autohoteky.

1. install autohotkey
2. Make text file. named "winkey.ahk" or what you want. (*.ahk)

edit file like this.

LWin Up::
SendInput, {Pause}
return

LWin Up is important part. if write LWin down, it'll make problem other win+something hotkey.
only for start menu, using LWin UP.

{pause} part is your flowlauncher hotkey.
if you using alt+space, change like this.

LWin Up::
SendInput, !{Space}
return

Now You can run *.ahk and ahk icon will showing into tray.
when you press Left Win key, it'll open/close Flow Launcher.
if you wanna don't use it, right click tray ahk icon ->Exit
I think it is simple logic, and it can be embed to flow launcher.

[taooceros]

#662

[onesounds]

yeah, It's already been discussed. A simple way is to just provide this guide and ahk file.
I write it for those who will find it.

[taooceros]

yep I just want to link back to the issue so people who find the issue can find this discussion. But I think I fail🤣

[NakerTheFirst]

yep I just want to link back to the issue so people who find the issue can find this discussion. But I think I fail🤣

you did not. Thanks!

[onesounds]

Update. When the flow is turned off, the window key originally operates.

LWin Up::
If ProcessExist("Flow.Launcher.exe")
  SendInput, !{Space}
else
  SendInput, {LWin}  
return

ProcessExist(Name){
Process,Exist,%Name%
return Errorlevel
}

[TheBossMagnus]

no way to fix the win+(r, d, arrow,...) hotkey?

[taooceros]

Since this page is discussing how to use autohotkey as a workaround. I think they will follow similar pattern.

[danielsawan]

no way to fix the win+(r, d, arrow,...) hotkey?

F9 is my flow shortcut

~LWin::
If ProcessExist("Flow.Launcher.exe")
SendInput, {f9}
else
SendInput, {LWin}
return

ProcessExist(Name){
Process,Exist,%Name%
return Errorlevel
}

[AarxnBong]

Doesn't seem to work for me unfortunately, it is literally spamming the button rather than opening it once.

[AarxnBong]

For those that have the same issue as me.

1. The windows key is either pressed down although it has been released.
2. The windows key is getting spammed.

This is the code I created, not the best as it looks very messy but it does the job. Hope it helps 😄

LWin::
If ProcessExist("Flow.Launcher.exe"){
KeyWait, LWin, T0.15
If !ErrorLevel ; if you hold the LWin key for less than 150 milliseconds
Send, !{Space} ; send alt+space
Else ; but if it is held for more than that
Send, {LWin Down} ; hold LWin down
KeyWait, LWin ; and, in both cases, wait for it to be released
}else{ ; if process doesn't exist, windows key will function like normal
Send, {LWin Down}
KeyWait, LWin
}
Send, {LWin Up}
return

[brianpardee]

Hi, @AaronB2019
UPDATE: Nevermind. I got it working. Needed a space between ProcessExist and ("Flow.Launcher.exe"):

LWin::
If ProcessExist ("Flow.Launcher.exe"){
KeyWait, LWin, T0.15
If !ErrorLevel ; if you hold the LWin key for less than 150 milliseconds
Send, !{Space} ; send alt+space
Else ; but if it is held for more than that
Send, {LWin Down} ; hold LWin down
KeyWait, LWin ; and, in both cases, wait for it to be released
}else{ ; if process doesn't exist, windows key will function like normal
Send, {LWin Down}
KeyWait, LWin
}
Send, {LWin Up}
return

Your script looks like it will fit my needs but I am getting a Call to nonexistent function error calling out ProcessExist("Flow.Launcher.exe"). Wondering please if you may have missed something in what you posted vs the working script you use.
Thanks
Brian

[AarxnBong]

ProcessExist(Name){
Process,Exist,%Name%
return Errorlevel
}

My bad, you need this function which I copied from the comment above 😄

[ibrahimduran]

Windows key shortcuts stopped working for me with the original solution. This one seems to do the trick:

#NoEnv  ; Recommended for performance and compatibility with future AutoHotkey releases.
; #Warn  ; Enable warnings to assist with detecting common errors.
SendMode Input  ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir%  ; Ensures a consistent starting directory.

LWin & AppsKey::Return
LWin Up::
SendInput, !{Space}
return

[Crunchbits]

Just for clarification, for others seeing this in the future you should:

• NOT put a space between ProcessExist and ("Flow.Launcher.exe") as that will break it's check to see if Flow Launcher is open
• As mentioned above, you need to put a LWin & AppsKey::Return line for other WIN + key shortcuts to continue work

So the following is just using @onesounds's ProcessExist function and combining it with the code directly above this comment by @ibrahimduran. Very easy to combine but simply putting this here for ease of access for people seeing this later. It should work fine but is only tested on Autohotkey v1 so it might not work on v2:

LWin & AppsKey::Return
LWin Up::
If ProcessExist("Flow.Launcher.exe"){
	SendInput, !{Space}
}else{ ; if process doesn't exist, windows key will function like normal
	SendInput, {LWin}
}
return

ProcessExist(Name){
	Process,Exist,%Name%
	return Errorlevel
}

[JustAnOkapi]

Final version, compiled with ahk2exe and put in startup folder. Works with Win + R flow shortcut for cmd.

#NoTrayIcon
#SingleInstance
#NoEnv ; Recommended for performance and compatibility with future AutoHotkey releases.
; #Warn  ; Enable warnings to assist with detecting common errors.
SendMode Input ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir% ; Ensures a consistent starting directory.

LWin::
    If ProcessExist ("Flow.Launcher.exe"){
        KeyWait, LWin, T0.15
        If !ErrorLevel ; if you hold the LWin key for less than 150 milliseconds
            Send, !{Space} ; send alt+space
        Else ; but if it is held for more than that
            Send, {LWin Down} ; hold LWin down
        KeyWait, LWin ; and, in both cases, wait for it to be released
    }else{ ; if process doesn't exist, windows key will function like normal
        Send, {LWin Down}
        KeyWait, LWin
    }
    Send, {LWin Up}
return

[pkkid]

I'm getting the Error: Hotkey or hotstring is missing its opening brace. In fact, I could never get any scripts posted online to work. I suspect maybe I am using a wrong version of AHK or something?

Edit, spent some time tinkering and I believe this is the equivalent AHKv2 script.

LWin:: {
  If (ProcessExist("Flow.Launcher.exe")) {
    If (KeyWait("LWin", "T0.15")) {
      Send "!{Space}"
    } else {
      Send "{LWin Down}"
    }
    KeyWait "LWin"
  } else {
    Send "{LWin Down}"
    KeyWait "LWin"
  }
  Send "{LWin Up}"
}

[Crunchbits]

I just realized a better and cleaner way to write the version I previously had written. It uses #if and anything between the #if's works only when Flow Launcher is running.
Again it is only tested on Autohotkey v1 so it might not work on v2:

#if ProcessExist("Flow.Launcher.exe")
LWin & AppsKey::Return
LWin::SendInput, !{Space}
#if

ProcessExist(Name){
	Process,Exist,%Name%
	return Errorlevel
}

[ntrkd]

Here is my own version. I don't want Win to ever use use regular Start, so no more wait 150 ms. If you want to use the start menu, press Fn + Win to open it. This should ignore any other modifier keys so Win + R, Win + E, Win + Alt + S (for any todoist users).

Thanks to @AaronB2019 and @brianpardee. Of course it also works with Ahk2exe and you can uninstall Autohotkey after making the exe.

Additionally if you want this to work on elevated windows (task manager for example) run the .exe you made using ahk2exe as admin. To do this at startup use Task Scheduler check the "Run with Highest Privilege" and use Configure for: Windows 10 under general.

#NoTrayIcon
#SingleInstance
#NoEnv ; Recommended for performance and compatibility with future AutoHotkey releases.
; #Warn  ; Enable warnings to assist with detecting common errors.
SendMode Input ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir% ; Ensures a consistent starting directory.
LWin & AppsKey::Return

LWin::
    If ProcessExist ("Flow.Launcher.exe"){
        Send, !{Space} ; send alt+space
        KeyWait, LWin ; and, in both cases, wait for it to be released
    }else{ ; if process doesn't exist, windows key will function like normal
        Send, {LWin Down}
        KeyWait, LWin
    }
    Send, {LWin Up}
return

[ntrkd]

Other shortcuts that use the Win key? Aren't those like the ones I mentioned, Win + V and the sort?

[pkkid]

Maybe, when you say "This should ignore any other modifier keys" do you mean it does or does not work with those shortcuts? For me, the other shortcuts such as Win+V do not work.

[ntrkd]

It does work for me. I can use Win + V, Win + R and so on just fine. I did have to install AHK V1, it did prompt me in addition to AHK v2

[pkkid]

Hmm, thanks. I'll try again tonight. I'm realizing I missed some of the code above the main function that might be helping it work correctly when I converted it to AHKv2. Or maybe its just that I'm on AHKv2.

[ls-wdiff]

I can’t begin to express how thankful I am enough.

It’s been a rabbit hole for me to find out how to override the behavior exactly how this ahk does. Muscle memory for super key was too hard to just quit from. Thank you

[monandszy]

This is what I'm using right now, works fine:

If !A_IsAdmin
    Run('*RunAs "Script\Path"')

~LWin::Send "{Blind}{VKFF}"    ; prevents Start menu from showing if pressed by itself while allowing it as a hotkey modifier
LWin Up::{
    if (A_PriorKey = "LWin") { ; check if Lwin was pressed down, then up without other keys pressed in between.
        Send "+!{Space}" ; Shift Alt Space
    }
}
~RWin::Send "{Blind}{VKFF}"
RWin Up::{
    if (A_PriorKey = "RWin") {
        Send "+!{Space}"
    }
}```

[pkkid]

This is what ended up working for me, thanks so much. In my case, I only needed about half the script. So short and simple compare to everything else too.

~LWin::Send "{Blind}{VKFF}"   ; Prevent Start Menu from showing if pressed by itself
LWin Up::{
  if (A_PriorKey = "LWin") {  ; Check Lwin down then up without other keys in between
    Send "^{Space}"           ; Ctrl+Space
  }
}

[ntrkd]

If you dont want Alt Space, you can change it to Control F23.

#SingleInstance

~LWin::Send "{Blind}{VKFF}"    ; prevents Start menu from showing if pressed by itself while allowing it as a hotkey modifier
LWin Up::{
    if (A_PriorKey = "LWin") { ; check if Lwin was pressed down, then up without other keys pressed in between.
        Send "^{F23}" ; Control + F23
    }
}

Close out of Flow Launcher (fully quit)
Then in your %appdata% -> Roaming -> FlowLauncher -> Settings -> settings.json

Replace the hotkey with
"Hotkey": "Ctrl \u002B F23",
Reopen Flow and now it uses Control F23

[jwlei]

For anyone other AHK noob like that comes here in the future, The letter is case sensitive.

E.g. I wanted to run with CTRL+ALT+L and my script wouldn't launch with:

Send "^!{L}"

Instead I had to input a lowercase L(l) like:

Send "^!{l}"

[jjw24]

There will be a new plugin coming to the store that will enable the ability to use the Win key to open and close flow, very good for those that are looking for this functionality. If the plugin hasn't shown up yet for you, you can download it from here also https://github.com/AminSallah/Flow.Launcher.Plugin.WinHotkey (pm install <url_to_the_release_zip>)

[pkkid]

Great idea! However, for whatever reason this is not working great for me yet. Flow wasn't popping up reliably. Sometimes when I push Win, the currently open windows 'Alt' menu would popup (the one that pops up when you right click the a windows menu bar). The only way I could get Flow to popup is if I quickly and repeatedly press the win key 3 or 4 times.

[NoPlagiarism]

@pkkid does it work now? Works on my Machine

[agilido]

Isn't it better to implement it natively in Flow Launcher?

[NoPlagiarism]

@agilido

1. All implementations (including mentioned plugin) here use AutoHotKey => One more dependency in main repo + it's not feature, more like a hack
2. It's not working perfectly. Also, some Win shortcuts are getting harder to reach. So it's like for a bit more advanced users
3. If you want to use this feature, you still can find it in Plugin Manger by pm install Win Hotkey

[taooceros]

Isn't it better to implement it natively in Flow Launcher?

It is. Just it's not so easy without modifying how the hotkey works fundamentally.

[EnigmaSolved]

Great idea! However, for whatever reason this is not working great for me yet. Flow wasn't popping up reliably. Sometimes when I push Win, the currently open windows 'Alt' menu would popup (the one that pops up when you right click the a windows menu bar). The only way I could get Flow to popup is if I quickly and repeatedly press the win key 3 or 4 times.

Probably would be good to post your experience to the plugin page so the author can further investigate: https://github.com/AminSallah/Flow.Launcher.Plugin.WinHotkey :)

[jwlei]

The plugin is just one of the AHK scripts linked here

[NoPlagiarism]

The plugin is just one of the AHK scripts linked here

Yes, but

• Automatically changes shortcut on restart, if you changed it
• You can manage this solution through Flow Launcher

[gwmma]

To anyone looking for an easy solution-if you have MS Powertoys, it's pretty easy rebind Win to any shortcut you like using the Keyboard Manager module:

[surajmandalcell]

Can agree this is the best way, I use power toys anyhow so this is the best solution for me.

[chrisl8]

Unfortunately this makes it impossible to use the Windows key for other things, like snapping windows to the sides of the screen.

[indigofairyx]

hey yall. Dont ya just love driving yourself crazy with AHK?? Haha, I do too.

Thanks for inspiration here!

After playing most of these examples with bugs and lock ups I found a key combo that works. and it expands the use of the Meta key

It has 2 launch options, and a 2nd\sub-key that blocks windows start menu from show its ugly face again 😄
I have a similar combo setup on my capslock key that 1 tap. Copy, 2 taps. Paste, 3(hold). shows my custom Extended Capslock Context Menu

---

The Windows key now has 3 actions

• A Single Tap, shows Flow Launcher

• A Double Tap, You can put another custom function here and the moment I have it up show my 2nd fast launcher Quick Access Popup

• A HOLD, this allows the Win Key to still be used as a hotkey Modifier eg, Win + I or Win + X, etc

• There is a 2nd hotkey that Blocks the Lwin up from showing the start menu!

sidenote about this 2nd key discovery I also use www.Startisback.com for better taskbar, thou I've not used the windows start menu in over a year since I started using Flow Launcher, startisback has a mean keyhook that would always show the start menu when trying to re-bind it with AHK. So this key combo kills 3 bird with one code. 😁 🥳 its taken handful of months to figure this out.

Im going to put two code snippet below.

---

1. One that blocks the start menu I wrote\use this one 1st. Than thought maybe some of you still use the window start menu?? So made another...
2. One that will still show the windows start menu on the double tap

This Code is written in AutoHotkey V1 !

This one Blocks the Start Menu in favor a different custom launcher tool. If not QAP you can replace Lucky Line # 13 too Run, somthingelse.exe or Putafunctionhere()

#NoEnv ;recommend for performance and compatibility with future AHK releases.
#SingleInstance, Force ; Only allows one instance of this script to run at a time
#Persistent ; Keeps a script permanently running (that is, until the user closes it or ExitApp is encountered)
SendMode Input   ;recommend for new scripts do to its superior speed and reliability


$Lwin::
    KeyWait lwin, T0.15
    if ErrorLevel
		{
		sendinput, {Lwin Down} ; LONG PRESS, use Lwin as a hotkey modifier, e.g. Win + X, Shift + Win + → 
		}
    else
    {
        KeyWait lwin, D T0.15
        if ErrorLevel
            sendinput, !{space} ; ONE TAP, opens Flow launcher by sending, Alt + Space
        else
         try run, "C:\Program Files\Quick Access Popup\QAPmessenger.exe" ShowMenuLaunch  ; return ; DOUBLE TAP //This line can customized, the other 3 should be left alone. 
    }
    KeyWait lwin
	sendinput, {lwin up} ; Releases the Lwin key, prevents the win key from becoming locked down. Also still allows it to be used as a modifier.
return

lwin up::return ; blocks "startisback" and\or the windows start menu from showing\interfering with the new $Lwin functions

---

This Snippet keeps the start menu. One Tap for Flow Launcher. Double tap for the windows start menu

#NoEnv ;recommend for performance and compatibility with future AHK releases.
#SingleInstance, Force ; Only allows one instance of this script to run at a time
#Persistent ; Keeps a script permanently running (that is, until the user closes it or ExitApp is encountered)
SendMode Input   ;recommend for new scripts do to its superior speed and reliability

Lwin::
    KeyWait lwin, T0.15
    if ErrorLevel
		{
		sendinput, {Lwin Down} ; LONG PRESS, use Lwin as a hotkey modifier, e.g. Win + X , Shift + Win + → 
		}
    else
    {
        KeyWait lwin, D T0.15
        if ErrorLevel
            sendinput, !{space} ; ONE TAP, opens Flow launcher by sending, Alt + Space
        else
         sendinput, {lwin} ; DOUBLE TAP, Opens Windows Start menu
    }
    KeyWait lwin
	sendinput, {lwin up} ; Releases the Lwin key, prevents the win key from becoming locked down. Also still allows it to be used as a modifier.
return

[temmyddy]

how do i write a code for autohotkey for task manger to hide app ???

[jjw24]

New PR is made for supporting this feature natively.

Please help test this new change:
#662 (comment)

[isotjs]

Hey everyone! I tried the codes from here, and the plugin called "Win hotkey", but I couldn't make it work. So I coded a AutoHotKey2 script.

ATTENTION: It basically redirects the function of Left Windows Key to Right Windows Key, so If you don't have a windows key on the right of your keyboard do not use this script.

; AutoHotkey v2

#SingleInstance Force ; Only allows one instance of this script to run at a time
Persistent ; Keeps a script permanently running (that is, until the user closes it or ExitApp is encountered)
SendMode("Input") ; Recommend for new scripts do to its superior speed and reliability

LWin::return

; Redirect Left Windows Button to Right Windows Button
LWin & a::Send("RWin & a")
LWin & d::Send("RWin & d")
LWin & e::Send("RWin & e")
LWin & i::Send("RWin & i")
LWin & l::Send("RWin & l")
LWin & r::Send("RWin & r")
LWin & s::Send("RWin & s")
LWin & x::Send("RWin & x")
LWin & Tab::Send("RWin & Tab")
LWin & 1::Send("RWin & 1")
LWin & 2::Send("RWin & 2")
LWin & 3::Send("RWin & 3")
LWin & 4::Send("RWin & 4")
LWin & 5::Send("RWin & 5")
LWin & 6::Send("RWin & 6")
LWin & 7::Send("RWin & 7")
LWin & 8::Send("RWin & 8")
LWin & 9::Send("RWin & 9")
LWin & 0::Send("RWin & 0")

~LWin Up::{
    if (A_PriorKey = "LWin") {
        try {
            Run("flowlauncher.exe")
        } catch {
            try {
                Run("C:\Users\" . A_UserName . "\AppData\Local\FlowLauncher\FlowLauncher.exe")
            } catch {
                ; If code cant find it, paste ur way to here.
                Run("C:\Users\İSMAİL\AppData\Local\FlowLauncher\Flow.Launcher.exe")
            }
        }
    }
}

[jjw24]

From v1.20.0 flow natively supports using the win key to open and close the search window.

[isotjs]

From v1.20.0 flow natively supports using the win key to open and close the search window.

Unfortunately, it was not working on my computer.

[jjw24]

Hi there, please create an issue with additional info, e.g. how to reproduce and your Windows version etc.

[Vlad-Dumitrescu]

Not sure if I am in the right place or if I should open a separate issue, but the Win key sometimes fails to open Flow Launcher until I restart it.

I tracked down the issue and it happens only after I open this one app: MusicBee.

Am I doing something wrong? Any idea what I could do to fix this, please?

[Vlad-Dumitrescu]

Can I run Flow Launcher as admin without a UAC prompt?

[jjw24]

There is a workaround by using the Task Scheduler to start flow and choose to run with the highest privileges, I think this will avoid the prompt. There is a startup setting in flow to use logon task for starting up, once it's created in the scheduler you can then set this option I believe.

Having said that, please understand running flow in admin mode will also run any plugins you have installed as admin, so ensure you understand the risks and have also vetted the external plugins you may install.

[Vlad-Dumitrescu]

So it looks like the task is already set up with the highest privileges:

Maybe there is a different issue?

[jjw24]

I was not aware that option is automatically selected. Does it run flow as admin then?

[Vlad-Dumitrescu]

I don't think it is automatically selected; I might've checked it myself at some point in the past and forgot about it.

Anyway, how do I check if Flow runs as admin?