[lsp][macOS][spacemacs][mise] "The package typescript is not installed. Unable to find tsserver"

[stradicat]

Thank you for the bug report

• I am using the latest version of lsp-mode related packages.
• I checked FAQ and Troubleshooting sections
• You may also try reproduce the issue using clean environment using the following command: M-x lsp-start-plain

Bug description

In Emacs + spacemacs, when opening a .js file in js2-mode with lsp + ts-ls as backend, I get the error message "Error running timer: (error "The package typescript is not installed. Unable to find tsserver")". This used to happen a couple of years ago due to an lsp upstream bug (#4254 ), then got resolved. Now it came up again.

I've installed node via mise globally and installed typescript globally with npm i -g typescript.

Despite Emacs having detected mise's node installation location and having installed typescript and typescript-language-server under ~/.emacs.d/.cache/lsp/npm where they're picked up by Emacs, the problem persists, breaking lsp-mode for javascript and typescript modes.

Javascript / Typescript are the only modes exhibiting this behavior, all other modes I use work correctly, including those that use node-based language servers (json-ls, html-ls, css-ls).

Steps to reproduce

• Start Emacs
• Open a .js or .tsx file
• Check the *Messages* buffer

Expected behavior

lsp-mode is correctly enabled for javascript and typescript, loading ts-ls correctly.

Which Language Server did you use?

ts-ls

OS

MacOS

Error callstack

Anything else?

All of my toolchains are managed with mise, and all tools are correctly detected within Emacs (python, ruby, node).

[alexey0308]

Hi @stradicat, as a temporary workaround you can try to install typescript of version 5 or 6 which have the old location of tsserver.

[stradicat]

Thanks for the tip, @alexey0308! That did the trick!

[KallDrexx]

FYI, the reason this occurs is due to Typescript 7 not using typescript-language-server anymore (and no more tsserver.js). tsc itself is the LSP. So at least in Eglot this is fixed by having it call tsc --lsp --stdio instead of typescript-language-server.

I haven't looked yet into how to properly change lsp-mode yet, but that's the root cause. It's going to suck for anyone who has some TS7 and TS6 projects though.

[KallDrexx]

Fwiw, I was able to get TS7's language server working with the following (AI assisted) configuration:

;; Fix Typescript support for TS7
(with-eval-after-load 'lsp-javascript
  (defcustom lsp-clients-typescript7-path "tsc"
    "Path to the TypeScript 7 native binary (supports `tsc --lsp --stdio`)."
    :group 'lsp-typescript
    :type 'string)

  (defun lsp-clients-typescript7-find-binary ()
    "Prefer the project-local TS7 binary, fall back to PATH."
    (or (when-let* ((root (locate-dominating-file default-directory "node_modules")))
          (let ((local (expand-file-name "node_modules/.bin/tsc" root)))
            (when (file-executable-p local) local)))
        (executable-find lsp-clients-typescript7-path)))

  (lsp-register-client
   (make-lsp-client
    :new-connection (lsp-stdio-connection
                      (lambda ()
                        (list (or (lsp-clients-typescript7-find-binary) "tsc")
                              "--lsp" "--stdio")))
    :activation-fn 'lsp-typescript-javascript-tsx-jsx-activate-p
    :priority -2
    :initialization-options (lambda () (list :supportsHoverVerbosity t))
    :server-id 'ts7-ls)))

;; Fixes bug in lsp-mode that crashes ts7's lsp
(defun my/lsp--strip-null-values (data)
  "Recursively remove plist/hash-table/alist keys whose value is nil."
  (cond
   ((hash-table-p data)
    (let ((new (make-hash-table :test 'equal)))
      (maphash (lambda (k v)
                 (unless (null v)
                   (puthash k (my/lsp--strip-null-values v) new)))
               data)
      new))
   ;; plist: (:key val :key val ...)
   ((and (consp data) (keywordp (car data)))
    (let (result)
      (cl-loop for (k v) on data by #'cddr
               unless (null v)
               do (push k result) (push (my/lsp--strip-null-values v) result))
      (nreverse result)))
   ;; alist: ((key . val) (key . val) ...)
   ((and (consp data) (consp (car data)) (not (listp (caar data))))
    (--keep (unless (null (cdr it)) (cons (car it) (my/lsp--strip-null-values (cdr it)))) data))
   ((vectorp data) (cl-map 'vector #'my/lsp--strip-null-values data))
   (t data)))

(defvar my/lsp--strip-null-server-ids '(ts7-ls)
  "Server IDs whose outgoing LSP messages should have null values stripped.")

(defun my/lsp--should-strip-nulls-p ()
  "Non-nil if the in-flight LSP message is destined for a server
in `my/lsp--strip-null-server-ids'."
  (and (boundp 'lsp--cur-workspace)
       lsp--cur-workspace
       (memq (lsp--client-server-id (lsp--workspace-client lsp--cur-workspace))
             my/lsp--strip-null-server-ids)))

(defun my/lsp--make-message-strip-nulls (args)
  (if (my/lsp--should-strip-nulls-p)
      (list (my/lsp--strip-null-values (car args)))
    args))

(with-eval-after-load 'lsp-mode
  (advice-add 'lsp--make-message :filter-args #'my/lsp--make-message-strip-nulls))

The extra null stripping was needed, because there is some incompatibility with lsp-mode and the TS7 language server. The ts7 server crashes with

InvalidParams: json: cannot unmarshal into Go lsproto.TextDocumentClientCapabilities within
"/capabilities/textDocument/inlineCompletion": null value is not allowed for field "inlineCompletion"