SF: Add operation ivscc_apfrequency

- Add plot property support for axisOffsets and axisPercent

An operation can set these through SF_META_XAXISOFFSET, SF_META_YAXISOFFSET,
SF_META_XAXISPERCENT and SF_META_YAXISPERCENT in the JSON wave note of
the result wave.

The plotter uses the settings from the last result in a "with" block.
e.g.

op_that_sets_axisoffet()
with
1

would ignore the plot properties set by the first operation, whereas

1
with
op_that_sets_axisoffet()

would apply it.

Author: MichaelHuth

Packages/MIES/MIES_Constants.ipf

@@ -2141,6 +2141,11 @@ StrConstant SF_META_TRACETOFRONT       = "/TraceToFront"     // number, boolean,
 StrConstant SF_META_DONOTPLOT          = "/DoNotPlot"        // number, boolean, defaults to false (0)
 StrConstant SF_META_WINDOW_HOOK        = "/WindowHook"       // string
 StrConstant SF_META_FORMULA            = "/Formula"          // string
+StrConstant SF_META_PLOT               = "/Plot"             // number, boolean, defaults to false (0)
+StrConstant SF_META_XAXISOFFSET        = "/XAxisOffset"      // number
+StrConstant SF_META_YAXISOFFSET        = "/YAxisOffset"      // number
+StrConstant SF_META_XAXISPERCENT       = "/XAxisPercent"     // number
+StrConstant SF_META_YAXISPERCENT       = "/YAxisPercent"     // number
 
 /// A color group allows to have matching colors for sweep data with the same channel type/number and sweep.
 /// It is applied before the matching headstage/average colors in #SF_GetTraceColor().
@@ -2542,6 +2547,7 @@ StrConstant SF_OP_TPBASE              = "tpbase"
 StrConstant SF_OP_TPFIT               = "tpfit"
 StrConstant SF_OP_EXTRACT             = "extract"
 StrConstant SF_OP_FLATTEN             = "flatten"
+StrConstant SF_OP_IVSCCAPFREQUENCY    = "ivscc_apfrequency"
 ///@}
 
 StrConstant SF_PROPERTY_TABLE = "Table"

Packages/MIES/MIES_SweepFormula.ipf

@@ -97,7 +97,7 @@ Function/WAVE SF_GetNamedOperations()
 	                  SF_OP_SELECTIVSCCSWEEPQC, SF_OP_SELECTIVSCCSETQC, SF_OP_SELECTRANGE, SF_OP_SELECTEXP, SF_OP_SELECTDEV,            \
 	                  SF_OP_SELECTEXPANDSCI, SF_OP_SELECTEXPANDRAC, SF_OP_SELECTSETCYCLECOUNT, SF_OP_SELECTSETSWEEPCOUNT,               \
 	                  SF_OP_SELECTSCIINDEX, SF_OP_SELECTRACINDEX, SF_OP_ANAFUNCPARAM, SF_OP_CONCAT, SF_OP_TABLE, SF_OP_EXTRACT,         \
-	                  SF_OP_FLATTEN}
+	                  SF_OP_FLATTEN, SF_OP_IVSCCAPFREQUENCY}
 
 	return wt
 End
@@ -172,6 +172,10 @@ static Function/WAVE SF_FillPlotMetaData(WAVE wvYRef, variable useXLabel, string
 	plotMetaData[%ARGSETUPSTACK] = JWN_GetStringFromWaveNote(wvYRef, SF_META_ARGSETUPSTACK)
 	plotMetaData[%XAXISLABEL]    = SelectString(useXLabel, SF_XLABEL_USER, JWN_GetStringFromWaveNote(wvYRef, SF_META_XAXISLABEL))
 	plotMetaData[%YAXISLABEL]    = JWN_GetStringFromWaveNote(wvYRef, SF_META_YAXISLABEL) + dataUnits
+	plotMetaData[%XAXISOFFSET]   = num2str(JWN_GetNumberFromWaveNote(wvYRef, SF_META_XAXISOFFSET), "%f")
+	plotMetaData[%YAXISOFFSET]   = num2str(JWN_GetNumberFromWaveNote(wvYRef, SF_META_YAXISOFFSET), "%f")
+	plotMetaData[%XAXISPERCENT]  = num2str(JWN_GetNumberFromWaveNote(wvYRef, SF_META_XAXISPERCENT), "%f")
+	plotMetaData[%YAXISPERCENT]  = num2str(JWN_GetNumberFromWaveNote(wvYRef, SF_META_YAXISPERCENT), "%f")
 
 	return plotMetaData
 End
@@ -1478,6 +1482,29 @@ static Function SF_FormulaPlotter(string graph, string formula, [variable dmMode
 	SF_KillOldDataDisplayWindows(graph, winDisplayMode, wList, outputWindows)
 End
 
+/// @brief Sets axis properties for plots of the SF formula plotter. The properties are stored in the plotMetaData wave.
+static Function [STRUCT SF_PlotterGraphStruct pg] SF_SetAxisProperties()
+
+	variable xaxisOffset, yaxisOffset, xaxisPercent, yaxisPercent
+
+	xaxisOffset = str2num(pg.plotMetaData[%XAXISOFFSET])
+	if(!IsNaN(xaxisOffset))
+		ModifyGraph/W=$pg.win axOffset(bottom)=xaxisOffset
+	endif
+	yaxisOffset = str2num(pg.plotMetaData[%YAXISOFFSET])
+	if(!IsNaN(yaxisOffset))
+		ModifyGraph/W=$pg.win axOffset(left)=yaxisOffset
+	endif
+	xaxisPercent = str2num(pg.plotMetaData[%XAXISPERCENT])
+	if(!IsNaN(xaxisPercent))
+		ModifyGraph/W=$pg.win axisEnab(bottom)={0, xaxisPercent * PERCENT_TO_ONE}
+	endif
+	yaxisPercent = str2num(pg.plotMetaData[%YAXISPERCENT])
+	if(!IsNaN(yaxisPercent))
+		ModifyGraph/W=$pg.win axisEnab(left)={0, yaxisPercent * PERCENT_TO_ONE}
+	endif
+End
+
 static Function [STRUCT SF_PlotterGraphStruct pg] SF_FinishPlotWindow(WAVE/T winGraphs)
 
 	variable formulasAreDifferent, numTableFormulas
@@ -1490,6 +1517,9 @@ static Function [STRUCT SF_PlotterGraphStruct pg] SF_FinishPlotWindow(WAVE/T win
 	endif
 
 	if(pg.panelsCreated[%GRAPH])
+
+		[pg] = SF_SetAxisProperties()
+
 		pg.win = winGraphs[GetNumberFromWaveNote(winGraphs, NOTE_INDEX) - 1]
 		if(pg.showLegend)
 			[formulasAreDifferent, pg] = SF_AddPlotLegend()
@@ -2804,3 +2834,9 @@ Function SF_TableWindowHook(STRUCT WMWinHookStruct &s)
 
 	return 0
 End
+
+/// @brief Adds an expression to a formula string with the proper termination character
+Function/S SF_AddExpressionToFormula(string formula, string expr)
+
+	return formula + expr + SF_CHAR_CR
+End

Packages/MIES/MIES_SweepFormula_Executor.ipf

@@ -520,6 +520,9 @@ Function/WAVE SFE_FormulaExecutor(STRUCT SF_ExecutionData &exd, [variable srcLoc
 		case SF_OP_FLATTEN:
 			WAVE out = SFO_OperationFlatten(exdop)
 			break
+		case SF_OP_IVSCCAPFREQUENCY:
+			WAVE out = SFO_OperationIVSCCApFrequency(exdop)
+			break
 		default:
 			SFH_FATAL_ERROR("Undefined Operation", jsonId = exdop.jsonId)
 	endswitch

Packages/MIES/MIES_SweepFormula_Helpers.ipf

@@ -2173,3 +2173,40 @@ Function/WAVE SFH_GetDatasetArrayAsResolvedWaverefs(STRUCT SF_ExecutionData &exd
 
 	return dataFromEachGroup
 End
+
+/// @brief Executes a formula from within an operation with low overhead
+///        - the currently active variable storage is used
+///        - the formula string is not preprocessed
+Function/WAVE SFH_ExecuteFormulaInternal(string graph, string formula)
+
+	STRUCT SF_ExecutionData exd
+	variable jsonId, srcLocId
+
+	exd.graph          = graph
+	[jsonId, srcLocId] = SFP_ParseFormulaToJSON(formula)
+	exd.jsonId         = jsonId
+	WAVE dataRef = SFE_FormulaExecutor(exd, srcLocId = srcLocId)
+
+	JSON_Release(exd.jsonId)
+	JSON_Release(srcLocId)
+
+	WAVE resolved = SF_ResolveDataset(dataRef)
+
+	return resolved
+End
+
+/// @brief Adds a variable to the variable storage. If the variable already exists it is overwritten.
+Function SFH_AddVariableToStorage(string graph, string name, WAVE result)
+
+	variable size, idx
+
+	WAVE/WAVE varStorage = GetSFVarStorage(graph)
+	idx = FindDimLabel(varStorage, ROWS, name)
+	if(idx == -2)
+		size = DimSize(varStorage, ROWS)
+		Redimension/N=(size + 1) varStorage
+		idx = size
+	endif
+	varStorage[idx] = result
+	SetDimLabel ROWS, idx, $name, varStorage
+End

Packages/MIES/MIES_SweepFormula_Operations.ipf

@@ -30,6 +30,10 @@ static StrConstant SF_OP_APFREQUENCY_NONORM             = "nonorm"
 static StrConstant SF_OP_APFREQUENCY_X_COUNT            = "count"
 static StrConstant SF_OP_APFREQUENCY_X_TIME             = "time"
 
+static StrConstant SF_OP_IVSCCAPFREQUENCY_MIN  = "min"
+static StrConstant SF_OP_IVSCCAPFREQUENCY_MAX  = "max"
+static StrConstant SF_OP_IVSCCAPFREQUENCY_NONE = "none"
+
 static StrConstant SF_OP_AVG_INSWEEPS   = "in"
 static StrConstant SF_OP_AVG_OVERSWEEPS = "over"
 static StrConstant SF_OP_AVG_GROUPS     = "group"
@@ -2503,3 +2507,136 @@ Function/WAVE SFO_OperationTable(STRUCT SF_ExecutionData &exd)
 
 	return SFH_GetOutputForExecutor(output, exd.graph, SF_OP_TABLE)
 End
+
+/// @brief Sets the plot meta data for the ivscc_apfrequency operation
+static Function SFO_OperationIVSCCApFrequencySetPlotProperties(WAVE wvY, variable xAxisPercentage, variable yAxisPercentage)
+
+	JWN_SetNumberInWaveNote(wvY, SF_META_XAXISPERCENT, xAxisPercentage)
+	JWN_SetNumberInWaveNote(wvY, SF_META_YAXISPERCENT, yAxisPercentage)
+End
+
+// ivscc_apfrequency([xaxisOffset, yaxisOffset, xAxisPercentage, yAxisPercentage])
+Function/WAVE SFO_OperationIVSCCApFrequency(STRUCT SF_ExecutionData &exd)
+
+	string   opShort    = SF_OP_IVSCCAPFREQUENCY
+	variable numArgsMin = 0
+	variable numArgsMax = 4
+	string formula, expr, exprPart
+	variable i, numArgs, col, size, numExp
+	variable xAxisPercentage, yAxisPercentage
+	string xaxisOffset, yaxisOffset
+
+	SFH_ASSERT(BSP_IsSweepBrowser(exd.graph), "ivscc_apfrequency only works with sweepbrowser")
+
+	numArgs = SFH_GetNumberOfArguments(exd)
+	SFH_ASSERT(numArgs <= numArgsMax, "ivscc_apfrequency has " + num2istr(numArgsMax) + " arguments at most.")
+	SFH_ASSERT(numArgs >= numArgsMin, "ivscc_apfrequency needs at least " + num2istr(numArgsMin) + " argument(s).")
+
+	xaxisOffset     = SFH_GetArgumentAsText(exd, opShort, 0, defValue = SF_OP_IVSCCAPFREQUENCY_MIN, allowedValues = {SF_OP_IVSCCAPFREQUENCY_MIN, SF_OP_IVSCCAPFREQUENCY_MAX, SF_OP_IVSCCAPFREQUENCY_NONE})
+	yaxisOffset     = SFH_GetArgumentAsText(exd, opShort, 1, defValue = SF_OP_IVSCCAPFREQUENCY_MIN, allowedValues = {SF_OP_IVSCCAPFREQUENCY_MIN, SF_OP_IVSCCAPFREQUENCY_MAX, SF_OP_IVSCCAPFREQUENCY_NONE})
+	xAxisPercentage = SFH_GetArgumentAsNumeric(exd, opShort, 2, defValue = 100, checkFunc = BetweenZeroAndOneHoundred)
+	yAxisPercentage = SFH_GetArgumentAsNumeric(exd, opShort, 3, defValue = 100, checkFunc = BetweenZeroAndOneHoundred)
+
+	WAVE/T sweepMap = SB_GetSweepMap(exd.graph)
+	col  = FindDimlabel(sweepMap, COLS, "FileName")
+	size = GetNumberFromWaveNote(sweepMap, NOTE_INDEX)
+	Duplicate/FREE/RMD=[0, size - 1][col] sweepMap, fileNames
+	WAVE/T uniqueFiles = GetUniqueEntries(fileNames, dontDuplicate = 1)
+	numExp = DimSize(uniqueFiles, ROWS)
+	SFH_ASSERT(numExp > 0, "ivscc_apfrequency: data from at least one experiment has to be loaded")
+
+	Make/FREE/T/N=(numExp) elems
+
+	formula = "sel = select(selsweeps(), selstimset(\"*rheo*\", \"*supra*\"), selvis(all))\r"
+	for(i = 0; i < numExp; i += 1)
+		sprintf expr, "selexpAD%d = select(selexp(\"%s\"), $sel, selchannels(AD0), selrange(E1))", i, uniqueFiles[i]
+		formula = SF_AddExpressionToFormula(formula, expr)
+		sprintf expr, "selexpDA%d = select(selexp(\"%s\"), $sel, selchannels(DA0), selrange(E1))", i, uniqueFiles[i]
+		formula = SF_AddExpressionToFormula(formula, expr)
+		sprintf expr, "freq%d = apfrequency(data($selexpAD%d))", i, i
+		formula = SF_AddExpressionToFormula(formula, expr)
+		sprintf expr, "current%d = max(data($selexpDA%d))", i, i
+		formula = SF_AddExpressionToFormula(formula, expr)
+		if(!CmpStr(xaxisOffset, SF_OP_IVSCCAPFREQUENCY_MIN))
+			sprintf expr, "currentNorm%d = $current%d - extract($current%d, 0)", i, i, i
+		elseif(!CmpStr(xaxisOffset, SF_OP_IVSCCAPFREQUENCY_MAX))
+			sprintf expr, "currentNorm%d = $current%d - max(flatten($current%d))", i, i, i
+		elseif(!CmpStr(xaxisOffset, SF_OP_IVSCCAPFREQUENCY_NONE))
+			sprintf expr, "currentNorm%d = $current%d", i, i
+		else
+			FATAL_ERROR("Unknown xaxisOffset specification")
+		endif
+		formula = SF_AddExpressionToFormula(formula, expr)
+	endfor
+
+	elems[] = "$freq" + num2istr(p)
+	expr    = "ivsccavg = avg([" + TextWaveToList(elems, ",", trailSep = 0) + "], group)"
+	formula = SF_AddExpressionToFormula(formula, expr)
+
+	elems[] = "$currentNorm" + num2istr(p)
+	expr    = "ivscccurrentavg = avg([" + TextWaveToList(elems, ",", trailSep = 0) + "], group)"
+	formula = SF_AddExpressionToFormula(formula, expr)
+
+	elems[] = "\"" + uniqueFiles[p] + "\""
+	expr    = "ivscc_apfrequency_explist = [" + TextWaveToList(elems, ",", trailSep = 0) + "]"
+	formula = SF_AddExpressionToFormula(formula, expr)
+
+	WAVE/WAVE varStorage = GetSFVarStorage(exd.graph)
+	Duplicate/FREE varStorage, varBackup
+	SFE_ExecuteVariableAssignments(exd.graph, formula)
+
+	WAVE/WAVE varStorageOp = GetSFVarStorage(exd.graph)
+	WAVE      wvResult     = varStorageOp[%ivscc_apfrequency_explist]
+
+	WAVE/WAVE plotAND = SFH_CreateSFRefWave(exd.graph, opShort, 1)
+	Make/FREE/WAVE/N=(numExp + 1, 2) plotWITH
+	SetDimlabel COLS, 0, FORMULAX, plotWITH
+	SetDimlabel COLS, 1, FORMULAY, plotWITH
+	plotAND[0] = plotWITH
+
+	for(i = 0; i < numExp; i += 1)
+		if(!CmpStr(yaxisOffset, SF_OP_IVSCCAPFREQUENCY_MIN))
+			sprintf formula, "$freq%d - extract($freq%d, 0)", i, i
+		elseif(!CmpStr(yaxisOffset, SF_OP_IVSCCAPFREQUENCY_MAX))
+			sprintf formula, "$freq%d - max(flatten($freq%d))", i, i
+		elseif(!CmpStr(yaxisOffset, SF_OP_IVSCCAPFREQUENCY_NONE))
+			sprintf formula, "$freq%d", i
+		else
+			FATAL_ERROR("Unknown xaxisOffset specification")
+		endif
+		plotWITH[i][%FORMULAY] = SFH_ExecuteFormulaInternal(exd.graph, formula)
+		SFO_OperationIVSCCApFrequencySetPlotProperties(plotWITH[i][%FORMULAY], xAxisPercentage, yAxisPercentage)
+		sprintf formula, "$currentNorm%d", i
+		plotWITH[i][%FORMULAX] = SFH_ExecuteFormulaInternal(exd.graph, formula)
+	endfor
+
+	if(!CmpStr(yaxisOffset, SF_OP_IVSCCAPFREQUENCY_MIN))
+		formula = "$ivsccavg - extract($ivsccavg, 0)"
+	elseif(!CmpStr(yaxisOffset, SF_OP_IVSCCAPFREQUENCY_MAX))
+		formula = "$ivsccavg - max(flatten($ivsccavg))"
+	elseif(!CmpStr(yaxisOffset, SF_OP_IVSCCAPFREQUENCY_NONE))
+		formula = "$ivsccavg"
+	else
+		FATAL_ERROR("Unknown yaxisOffset specification")
+	endif
+	plotWITH[i][%FORMULAY] = SFH_ExecuteFormulaInternal(exd.graph, formula)
+	SFO_OperationIVSCCApFrequencySetPlotProperties(plotWITH[i][%FORMULAY], xAxisPercentage, yAxisPercentage)
+
+	if(!CmpStr(xaxisOffset, SF_OP_IVSCCAPFREQUENCY_MIN))
+		formula = "$ivscccurrentavg - extract($ivscccurrentavg, 0)"
+	elseif(!CmpStr(xaxisOffset, SF_OP_IVSCCAPFREQUENCY_MAX))
+		formula = "$ivscccurrentavg - max(flatten($ivscccurrentavg))"
+	elseif(!CmpStr(xaxisOffset, SF_OP_IVSCCAPFREQUENCY_NONE))
+		formula = "$ivscccurrentavg"
+	else
+		FATAL_ERROR("Unknown xaxisOffset specification")
+	endif
+	plotWITH[i][%FORMULAX] = SFH_ExecuteFormulaInternal(exd.graph, formula)
+
+	Duplicate/O varBackup, varStorage
+	SFH_AddVariableToStorage(exd.graph, "ivscc_apfrequency_explist", wvResult)
+
+	JWN_SetNumberInWaveNote(plotAND, SF_META_PLOT, 1)
+
+	return SFH_GetOutputForExecutor(plotAND, exd.graph, opShort)
+End

Packages/MIES/MIES_WaveDataFolderGetters.ipf

@@ -9284,8 +9284,8 @@ End
 /// @brief Wave storing sf plot meta information per formularesult, filled in SF_GatherFormulaResults
 Function/WAVE GetSFPlotMetaData()
 
-	Make/FREE/T/N=(5) wv
-	SetDimensionLabels(wv, "DATATYPE;OPSTACK;ARGSETUPSTACK;XAXISLABEL;YAXISLABEL;", ROWS)
+	Make/FREE/T/N=(9) wv
+	SetDimensionLabels(wv, "DATATYPE;OPSTACK;ARGSETUPSTACK;XAXISLABEL;YAXISLABEL;XAXISOFFSET;YAXISOFFSET;XAXISPERCENT;YAXISPERCENT;", ROWS)
 
 	return wv
 End