Add JEI Categories and related improvements (#201)

* extra IWC part of JEI

* move JEI removal to mixin to ensure it happens after mods

* fix builders being commented in documentation

* implement adding JEI Categories

* add class and custom reloading example

* move custom script files to their own folder

* use event to reload

Author: WaitingIdly

examples/classes/GenericRecipeCategory.groovy

@@ -0,0 +1,111 @@
+package classes
+
+import classes.SimpleConversionRecipe
+import mezz.jei.api.gui.IDrawable
+import mezz.jei.api.gui.IGuiIngredient
+import mezz.jei.api.gui.IGuiIngredientGroup
+import mezz.jei.api.gui.IRecipeLayout
+import mezz.jei.api.ingredients.IIngredients
+import mezz.jei.api.ingredients.VanillaTypes
+import mezz.jei.api.recipe.IRecipeCategory
+import mezz.jei.api.recipe.IRecipeWrapper
+import mezz.jei.gui.ingredients.GuiIngredient
+import net.minecraft.client.Minecraft
+import net.minecraft.client.renderer.GlStateManager
+import net.minecraft.client.resources.I18n
+
+import java.util.stream.Collectors
+
+/**
+ * An example of a IRecipeCategory from JEI, used in {@code /postInit/jei.groovy}.
+ * Will only appear if {@code SimpleConversionRecipe.recipes} contains recipes.
+ */
+class GenericRecipeCategory implements IRecipeCategory<RecipeWrapper> {
+
+    static final String UID = "${getPackId()}:generic"
+
+    private final def icon
+
+    private final def uid
+    private final def background
+
+    static def rightArrow
+    static def slot
+
+    GenericRecipeCategory(guiHelper) {
+        this(guiHelper, UID, 176, 67)
+    }
+
+    GenericRecipeCategory(guiHelper, uid, width, height) {
+        this.uid = uid
+        this.background = guiHelper.createBlankDrawable(width, height)
+        if (slot == null) {
+            rightArrow = guiHelper.drawableBuilder(resource('groovyscript:textures/jei/arrow_right.png'), 0, 0, 24, 15)
+                .setTextureSize(24, 15)
+                .build()
+            slot = guiHelper.getSlotDrawable()
+        }
+        this.icon = guiHelper.createDrawableIngredient(item('minecraft:clay'))
+    }
+
+    static def getRecipeWrappers() {
+        SimpleConversionRecipe.recipes.collect RecipeWrapper.&new
+    }
+
+    void setRecipe(IRecipeLayout recipeLayout, IRecipeWrapper recipeWrapper, IIngredients ingredients) {
+        addItemSlot(recipeLayout, 0, true, 53, 25)
+        addItemSlot(recipeLayout, 1, false, 105, 25)
+
+        recipeLayout.getItemStacks().set(ingredients)
+        setBackgrounds(recipeLayout.getItemStacks(), slot)
+    }
+
+    void drawExtras(Minecraft minecraft) {
+        GlStateManager.color(1.0f, 1.0f, 1.0f, 1.0f)
+        rightArrow.draw(minecraft, 76, 26)
+    }
+
+    IDrawable getIcon() {
+        icon
+    }
+
+    String getUid() {
+        this.uid
+    }
+
+    String getTitle() {
+        I18n.format("jei.category.${this.uid}.name")
+    }
+
+    String getModName() {
+        getPackName()
+    }
+
+    IDrawable getBackground() {
+        this.background
+    }
+
+    private static void addItemSlot(IRecipeLayout recipeLayout, int index, boolean input, int x, int y) {
+        recipeLayout.getItemStacks().init(index, input, x, y)
+    }
+
+    private static void setBackgrounds(IGuiIngredientGroup<?> ingredientGroup, IDrawable drawable) {
+        for (IGuiIngredient<?> ingredient : ingredientGroup.getGuiIngredients().values()) {
+            ((GuiIngredient<?>) ingredient).setBackground(drawable)
+        }
+    }
+
+    static class RecipeWrapper implements IRecipeWrapper {
+
+        private final SimpleConversionRecipe recipe
+
+        RecipeWrapper(SimpleConversionRecipe recipe) {
+            this.recipe = recipe
+        }
+
+        void getIngredients(IIngredients ingredients) {
+            ingredients.setInput(VanillaTypes.ITEM, this.recipe.getInput())
+            ingredients.setOutput(VanillaTypes.ITEM, this.recipe.getOutput())
+        }
+    }
+}

examples/classes/GenericRecipeReloading.groovy

@@ -0,0 +1,40 @@
+package classes
+
+/**
+ * A simple example of reloadable compat for a single registry, in this case {@code SimpleConversionRecipe}.<br>
+ *
+ * To use, call {@link GenericRecipeReloading#onReload()} in an event listener listening to {@code GroovyReloadEvent},
+ * and manipulate recipes by calling {@link GenericRecipeReloading#add()} or {@link GenericRecipeReloading#remove()}.<br>
+ *
+ * Note that {@link GenericRecipeReloading#onReload()} should only be called when GroovyScript is reloading,
+ * so you will want to have it called by listening to {@code GroovyReloadEvent} in something like this:<br>
+ * <pre>
+ * eventManager.listen(com.cleanroommc.groovyscript.event.GroovyReloadEvent) {
+ *     GenericRecipeReloading.instance.onReload()
+ * }
+ * </pre>
+ */
+class GenericRecipeReloading {
+
+    static def instance = new GenericRecipeReloading()
+
+    def scripted = []
+    def backup = []
+
+    void onReload() {
+        scripted.each { SimpleConversionRecipe.recipes.remove(it) }
+        scripted.clear()
+        backup.each { SimpleConversionRecipe.recipes.add(it) }
+        backup.clear()
+    }
+
+    void add(recipe) {
+        scripted << recipe
+        SimpleConversionRecipe.recipes.add(recipe)
+    }
+
+    void remove(recipe) {
+        backup << recipe
+        SimpleConversionRecipe.recipes.remove(recipe)
+    }
+}

examples/classes/SimpleConversionRecipe.groovy

@@ -0,0 +1,17 @@
+package classes
+
+/**
+ * A simple recipe and recipe holder to demonstrate both classes in GroovyScript and custom reloading compat.
+ */
+class SimpleConversionRecipe {
+    static final List<SimpleConversionRecipe> recipes = []
+
+    ItemStack input
+    ItemStack output
+
+    SimpleConversionRecipe(input, output) {
+        this.input = input
+        this.output = output
+    }
+
+}

examples/postInit/forestry.groovy examples/postInit/custom/forestry.groovyexamples/postInit/forestry.groovy renamed to examples/postInit/custom/forestry.groovy

@@ -0,0 +1,30 @@
+
+// this file demonstrates custom reloading compat
+// also demonstrating some event manager interactions
+
+import classes.GenericRecipeReloading
+import classes.SimpleConversionRecipe
+import net.minecraft.util.text.TextComponentString
+import net.minecraftforge.event.world.BlockEvent
+import com.cleanroommc.groovyscript.event.GroovyReloadEvent
+
+// add the example recipe
+GenericRecipeReloading.instance.add(new SimpleConversionRecipe(item('minecraft:clay'), item('minecraft:gold_ingot')))
+
+// reload via an event
+eventManager.listen(GroovyReloadEvent) {
+    GenericRecipeReloading.instance.onReload()
+}
+
+// use an event to demonstrate the recipe in-game
+eventManager.listen(BlockEvent.BreakEvent) {
+    // get the block drop if it was silk touched
+    def drop = it.getState().getBlock().getSilkTouchDrop(it.getState())
+    // find if any of the recipes have an input that match the drop
+    def found = SimpleConversionRecipe.recipes.find { it.input in drop }
+    if (found != null) {
+        // send the player a pair of messages to demonstrate the recipe
+        it.player.sendMessage(new TextComponentString("You broke a ${it.getState().getBlock().getLocalizedName()} Block!"))
+        it.player.sendMessage(new TextComponentString("A custom recipe marks a ${found.output.getDisplayName()} as its output."))
+    }
+}