Blossoming Pots

gm4_blossoming_pots/README.md

@@ -0,0 +1,28 @@
+# Blossoming Pots<!--$headerTitle--><!--$pmc:delete-->
+
+Decorated Pots and Flower Pots extended to allow all kinds of things to be placed in them! Decorate in Style! <!--$pmc:headerSize-->
+
+### Features
+- Some plants have multiple different heights or options depending on how many items you put in the pot. 
+- Directional plants are placed oriented towards you.
+- Allows you to plant the following
+  - All Flowers (including 2 tall)
+  - All Saplings (including azaleas and propagules)
+  - All Leaves
+  - Cactus
+  - All Fungi
+  - All Dead / Alive Coral, Coral Fans & Coral Blocks!
+  - Nether Roots & Vines
+  - Tall & Short Grass
+  - Tall & Short Ferns
+  - Dead Bush
+  - All Lush Cave Plants
+  - Sweet Berry Bush
+  - Kelp, Seagrass, Sea Pickle
+  - All Seeds
+  - Netherwart
+  - Cocoa Beans
+  - Chorus Flowers
+  - Wheat
+  - All Amethyst Buds & Clusters
+  - Dripstone

gm4_blossoming_pots/beet.yaml

@@ -0,0 +1,41 @@
+id: gm4_blossoming_pots
+name: Blossoming Pots
+version: 3.0.X
+  # should I start the version number over for gm4 release?
+data_pack:
+  load: .
+  overlays:
+    - formats:
+        min_inclusive: 0
+        max_inclusive: 48
+      directory: overlay_48
+
+resource_pack:
+  load: .
+
+pipeline:
+  - gm4.plugins.extend.module
+
+meta:
+  gm4:
+    versioning:
+      schedule_loops: [main]
+    website:
+      description: Decorated Pots and Flower Pots extended to allow all kinds of things to be placed in them! Decorate in Style!
+      #recommended:
+        #- 
+      notes:
+        - <add notes on version or incompatibilities?>
+    #modrinth: 
+      #project_id: null
+    #smithed:
+      #pack_id: null
+    planetminecraft: 
+      uid: null
+    video: null
+    wiki: null
+    credits:
+      Creator:
+        - runcows
+      Icon Design:
+        - <no idea>

gm4_blossoming_pots/data/gm4_blossoming_pots/advancement/interact_flower_pot.json

@@ -0,0 +1,29 @@
+{
+  "criteria": {
+    "use_pot": {
+      "conditions": {
+        "location": [
+          {
+            "condition": "minecraft:location_check",
+            "predicate": {
+              "block": {
+                "blocks": [
+                  "minecraft:flower_pot"
+                ]
+              }
+            }
+          }
+        ]
+      },
+      "trigger": "minecraft:any_block_use"
+    }
+  },
+  "requirements": [
+    [
+      "use_pot"
+    ]
+  ],
+  "rewards": {
+    "function": "gm4_blossoming_pots:flower/as_player"
+  }
+}

gm4_blossoming_pots/data/gm4_blossoming_pots/advancement/interact_vanilla_flower_pot.json

@@ -0,0 +1,27 @@
+{
+  "criteria": {
+    "use_pot": {
+      "conditions": {
+        "location": [
+          {
+            "condition": "minecraft:location_check",
+            "predicate": {
+              "block": {
+                "blocks": "#gm4_blossoming_pots:potted_plants"
+              }
+            }
+          }
+        ]
+      },
+      "trigger": "minecraft:any_block_use"
+    }
+  },
+  "requirements": [
+    [
+      "use_pot"
+    ]
+  ],
+  "rewards": {
+    "function": "gm4_blossoming_pots:flower/vanilla_pots/as_player"
+  }
+}

gm4_blossoming_pots/data/gm4_blossoming_pots/advancement/item_in_pot.json

@@ -0,0 +1,29 @@
+{
+  "criteria": {
+    "use_pot": {
+      "conditions": {
+        "location": [
+          {
+            "condition": "minecraft:location_check",
+            "predicate": {
+              "block": {
+                "blocks": [
+                  "minecraft:decorated_pot"
+                ]
+              }
+            }
+          }
+        ]
+      },
+      "trigger": "minecraft:any_block_use"
+    }
+  },
+  "requirements": [
+    [
+      "use_pot"
+    ]
+  ],
+  "rewards": {
+    "function": "gm4_blossoming_pots:decorated/as_player"
+  }
+}

gm4_blossoming_pots/data/gm4_blossoming_pots/function/decorated/as_marker.mcfunction

@@ -0,0 +1,23 @@
+# Sets up loop for plant stage changes
+# @s = temp marker inside decorated pot
+# at @s align xyz positioned ~.5 ~.5 ~.5
+# with block ~ ~ ~ item
+# run from decorated/as_player
+
+# early returns
+$execute unless data storage gm4_blossoming_pots:decorated_pots $(id).$(count) run return run kill @s
+$execute if data entity @n[type=minecraft:block_display,distance=..0.1,tag=gm4_blossoming_pots.display.decorated_pot] {FallDistance:$(count).0f} run return run kill @s
+
+$execute store result score $array_len gm4_blossoming_pots.loop run data get storage gm4_blossoming_pots:decorated_pots $(id).$(count)
+
+data modify storage gm4_blossoming_pots:decorated_pots temp.rotation set from entity @s data.rotation
+execute store result storage gm4_blossoming_pots:decorated_pots temp.score int 1 run scoreboard players set @s gm4_blossoming_pots.loop 0
+$data merge storage gm4_blossoming_pots:decorated_pots {temp:{id:"$(id)",count:$(count)}}
+$data modify storage gm4_blossoming_pots:decorated_pots temp.data set from storage gm4_blossoming_pots:decorated_pots $(id).$(count)[0]
+
+function gm4_blossoming_pots:decorated/loop with storage gm4_blossoming_pots:decorated_pots temp
+
+$execute if score @s gm4_blossoming_pots.sound matches 1 as @a[distance=..16] \
+    run function gm4_blossoming_pots:decorated/play_sound with storage gm4_blossoming_pots:decorated_pots $(id)
+
+kill @s

gm4_blossoming_pots/data/gm4_blossoming_pots/function/decorated/as_player.mcfunction

@@ -0,0 +1,15 @@
+# Sets up raycast, then redirects to as_marker, then revokes advancement
+# @s = player who interacted with a decorated pot
+# at @s
+# run from advancement gm4_blossoming_pots:item_in_pot
+
+# Raycast for the pot (set up range and search)
+execute store result score @s gm4_blossoming_pots.range run attribute @s minecraft:block_interaction_range get 1
+scoreboard players operation @s gm4_blossoming_pots.range *= $raycast_multiplier gm4_blossoming_pots.range
+execute anchored eyes run function gm4_blossoming_pots:decorated/raycast/loop
+
+execute as @e[type=minecraft:marker,sort=nearest,tag=gm4_blossoming_pots.temp.decorated_pot] at @s \
+    align xyz positioned ~.5 ~.5 ~.5 run function gm4_blossoming_pots:decorated/as_marker with block ~ ~ ~ item
+
+# Reset advancement
+advancement revoke @s only gm4_blossoming_pots:item_in_pot

gm4_blossoming_pots/data/gm4_blossoming_pots/function/decorated/loop.mcfunction

@@ -0,0 +1,27 @@
+# Main Loop 
+# @s = temp marker inside decorated pot
+# at @s align xyz positioned ~.5 ~.5 ~.5
+# with storage gm4_blossoming_pots:decorated_pots temp
+    # which should contain {rotation, score, id, count, data}
+# run from decorated/as_marker
+# run from this function...
+
+# summon if needed
+$execute unless entity @n[type=minecraft:block_display,distance=..0.1,tag=gm4_blossoming_pots.display.decorated_pot.$(score)] \
+    run summon minecraft:block_display ~ ~ ~ {view_range:0.7935f,Tags:["gm4_blossoming_pots.display.decorated_pot","gm4_blossoming_pots.display.decorated_pot.$(score)","smithed.entity"],Rotation:[$(rotation)f,0f]}
+# merge data and store the success
+$execute store success score @s gm4_blossoming_pots.merge_success \
+    run data merge entity @n[type=minecraft:block_display,distance=..0.1,tag=gm4_blossoming_pots.display.decorated_pot.$(score)] $(data)
+# if a single merge success set sound to play
+execute if score @s gm4_blossoming_pots.merge_success matches 1 run scoreboard players set @s gm4_blossoming_pots.sound 1
+
+# set FallDistance to the current stage of the display, this is used to prevent running the loop when the displays already have the desired data
+$data merge entity @n[type=minecraft:block_display,distance=..0.1,tag=gm4_blossoming_pots.display.decorated_pot.$(score)] {FallDistance:$(count).0f}
+
+# increment score
+execute store result storage gm4_blossoming_pots:decorated_pots temp.score int 1 run scoreboard players add @s gm4_blossoming_pots.loop 1
+
+# sets temp.data to next score's data
+function gm4_blossoming_pots:decorated/set_temp_data with storage gm4_blossoming_pots:decorated_pots temp
+# again if needed
+execute unless score @s gm4_blossoming_pots.loop >= $array_len gm4_blossoming_pots.loop run function gm4_blossoming_pots:decorated/loop with storage gm4_blossoming_pots:decorated_pots temp

gm4_blossoming_pots/data/gm4_blossoming_pots/function/decorated/play_sound.mcfunction

@@ -0,0 +1,7 @@
+# literally just plays sound
+# @s = a single player within 16 blocks of the decorated pot
+# with storage gm4_blossoming_pots:decorated_pots <id of item in decorated pot>
+# at the center of the decorated pot
+# run from decorated/as_marker
+
+$playsound $(place_sound) block @s ~ ~ ~

gm4_blossoming_pots/data/gm4_blossoming_pots/function/decorated/raycast/in_pot.mcfunction

@@ -0,0 +1,20 @@
+# checks if execution context is inside the decorated pots hit box
+# @s = player who interacted with a decorated pot
+# at @s anchored eyes, then marched forward 0.005 over and over. Complicated.
+# run from decorated/raycast/loop
+
+# early return if not dec pot
+execute unless block ~ ~ ~ minecraft:decorated_pot run return fail
+
+# summon marker for checking
+summon minecraft:marker ~ ~ ~ {Tags:["gm4_blossoming_pots.temp.decorated_pot","smithed.strict","smithed.entity"],CustomName:'{"text":"gm4_blossoming_pots.temp_marker"}'}
+
+# if temp marker in physical hit box, return 1
+# dxdydz all 0 bc of MC-123441.
+execute as @n[type=minecraft:marker,tag=gm4_blossoming_pots.temp.decorated_pot,distance=..0.1] \
+    align xyz positioned ~0.062499 ~ ~0.062499 if entity @s[dx=0,dy=0,dz=0] at @s align xyz positioned ~-0.062499 ~ ~-0.062499 if entity @s[dx=0,dy=0,dz=0] \
+    run return 1
+
+# else, kill marker, return fail
+kill @e[type=minecraft:marker,tag=gm4_blossoming_pots.temp.decorated_pot,distance=..0.1,sort=nearest]
+return fail

gm4_blossoming_pots/data/gm4_blossoming_pots/function/decorated/raycast/loop.mcfunction

@@ -0,0 +1,14 @@
+# main loop for raycasting for the decorated pot the player interacted with
+# @s = player who interacted with a decorated pot
+# at @s anchored eyes, then marched forward 0.005 over and over
+# run from decorated/as_player
+# run from this function...
+
+
+# if current location is within the decorated pots hit box, summon a temp marker, set its data with the player rotation, and exit raycast
+execute if function gm4_blossoming_pots:decorated/raycast/in_pot run return run function gm4_blossoming_pots:decorated/raycast/player_rotation
+
+scoreboard players remove @s gm4_blossoming_pots.range 1
+
+# repeat until find decorated pot or out of range
+execute if score @s gm4_blossoming_pots.range matches 1.. positioned ^ ^ ^0.005 run function gm4_blossoming_pots:decorated/raycast/loop

gm4_blossoming_pots/data/gm4_blossoming_pots/function/decorated/raycast/player_rotation.mcfunction

@@ -0,0 +1,13 @@
+# sets rotation data of the new temp marker from players
+# @s = player who interacted with a decorated pot
+# at @s anchored eyes, then marched forward 0.005 over and over. This should be in the same spot as the new temp marker
+# run from decorated/raycast/loop
+
+# player facing west
+execute if entity @s[y_rotation=45..135] run return run data merge entity @n[type=minecraft:marker,tag=gm4_blossoming_pots.temp.decorated_pot,distance=..0.01] {data:{rotation:0}}
+# player facing north
+execute if entity @s[y_rotation=135..225] run return run data merge entity @n[type=minecraft:marker,tag=gm4_blossoming_pots.temp.decorated_pot,distance=..0.01] {data:{rotation:90}}
+# player facing east
+execute if entity @s[y_rotation=225..315] run return run data merge entity @n[type=minecraft:marker,tag=gm4_blossoming_pots.temp.decorated_pot,distance=..0.01] {data:{rotation:180}}
+# player facing south
+execute if entity @s[y_rotation=315..405] run return run data merge entity @n[type=minecraft:marker,tag=gm4_blossoming_pots.temp.decorated_pot,distance=..0.01] {data:{rotation:-90}}