Blossoming Pots

gm4_blossoming_pots/README.md

@@ -0,0 +1,28 @@
+# Blossoming Pots<!--$headerTitle--><!--$pmc:delete-->
+
+Decorated Pots and Flower Pots extended to allow all kinds of things to be placed in them! Decorate in Style! <!--$pmc:headerSize-->
+
+### Features
+- Some plants have multiple different heights or options depending on how many items you put in the pot. 
+- Directional plants are placed oriented towards you.
+- Allows you to plant the following
+  - All Flowers (including 2 tall)
+  - All Saplings (including azaleas and propagules)
+  - All Leaves
+  - Cactus
+  - All Fungi
+  - All Dead / Alive Coral, Coral Fans & Coral Blocks!
+  - Nether Roots & Vines
+  - Tall & Short Grass
+  - Tall & Short Ferns
+  - Dead Bush
+  - All Lush Cave Plants
+  - Sweet Berry Bush
+  - Kelp, Seagrass, Sea Pickle
+  - All Seeds
+  - Netherwart
+  - Cocoa Beans
+  - Chorus Flowers
+  - Wheat
+  - All Amethyst Buds & Clusters
+  - Dripstone

gm4_blossoming_pots/beet.yaml

@@ -0,0 +1,36 @@
+id: gm4_blossoming_pots
+name: Blossoming Pots
+version: 3.0.X
+  # should I start the version number over for gm4 release?
+data_pack:
+  load: .
+
+resource_pack:
+  load: .
+
+pipeline:
+  - gm4.plugins.extend.module
+
+meta:
+  gm4:
+    versioning:
+      schedule_loops: [main]
+    website:
+      description: Decorated Pots and Flower Pots extended to allow all kinds of things to be placed in them! Decorate in Style!
+      #recommended:
+        #- 
+      notes:
+        - <add notes on version or incompatibilities?>
+    #modrinth: 
+      #project_id: null
+    #smithed:
+      #pack_id: null
+    planetminecraft: 
+      uid: null
+    video: null
+    wiki: null
+    credits:
+      Creator:
+        - runcows
+      Icon Design:
+        - <no idea>

gm4_blossoming_pots/data/gm4_blossoming_pots/advancement/interact_flower_pot.json

@@ -0,0 +1,29 @@
+{
+  "criteria": {
+    "use_pot": {
+      "conditions": {
+        "location": [
+          {
+            "condition": "minecraft:location_check",
+            "predicate": {
+              "block": {
+                "blocks": [
+                  "minecraft:flower_pot"
+                ]
+              }
+            }
+          }
+        ]
+      },
+      "trigger": "minecraft:any_block_use"
+    }
+  },
+  "requirements": [
+    [
+      "use_pot"
+    ]
+  ],
+  "rewards": {
+    "function": "gm4_blossoming_pots:flower/as_player"
+  }
+}

gm4_blossoming_pots/data/gm4_blossoming_pots/advancement/interact_vanilla_flower_pot.json

@@ -0,0 +1,27 @@
+{
+  "criteria": {
+    "use_pot": {
+      "conditions": {
+        "location": [
+          {
+            "condition": "minecraft:location_check",
+            "predicate": {
+              "block": {
+                "blocks": "#gm4_blossoming_pots:potted_plants"
+              }
+            }
+          }
+        ]
+      },
+      "trigger": "minecraft:any_block_use"
+    }
+  },
+  "requirements": [
+    [
+      "use_pot"
+    ]
+  ],
+  "rewards": {
+    "function": "gm4_blossoming_pots:flower/vanilla_pots/as_player"
+  }
+}

gm4_blossoming_pots/data/gm4_blossoming_pots/advancement/item_in_pot.json

@@ -0,0 +1,29 @@
+{
+  "criteria": {
+    "use_pot": {
+      "conditions": {
+        "location": [
+          {
+            "condition": "minecraft:location_check",
+            "predicate": {
+              "block": {
+                "blocks": [
+                  "minecraft:decorated_pot"
+                ]
+              }
+            }
+          }
+        ]
+      },
+      "trigger": "minecraft:any_block_use"
+    }
+  },
+  "requirements": [
+    [
+      "use_pot"
+    ]
+  ],
+  "rewards": {
+    "function": "gm4_blossoming_pots:decorated/as_player"
+  }
+}

gm4_blossoming_pots/data/gm4_blossoming_pots/function/decorated/as_marker.mcfunction

@@ -0,0 +1,28 @@
+# Dispatch for operations concerning the decorated pots plants
+# @s = temp marker inside decorated pot
+# at @s align xyz positioned ~.5 ~.5 ~.5
+# run from decorated/as_player
+
+# summon the required amount of block displays, without data
+execute \
+    unless entity @e[type=minecraft:block_display,tag=gm4_blossoming_pots.display.decorated_pot,distance=..0.2] \
+    run function gm4_blossoming_pots:decorated/summon/initialize with block ~ ~ ~ item
+
+# if new block displays summoned, catch it up to count
+execute if score @s gm4_blossoming_pots.summon_loop matches 0 \
+    run function gm4_blossoming_pots:decorated/catch_up/initialize
+
+# merge the data of the corresponding item amount variant with the block displays there
+execute \
+    if entity @e[type=minecraft:block_display,tag=gm4_blossoming_pots.display.decorated_pot,distance=..0.2] \
+    run function gm4_blossoming_pots:decorated/merge/initialize with block ~ ~ ~ item
+
+# if merge score 0, succesfully merged data, play sound?
+    # merge or summon?
+        # merge score 0 triggers every pot interact, not ideal
+        # summon score 0 triggers only on first summon, not ideal either, but better
+    # ideally, we would only play sound on successful CHANGE, and not on just right click
+execute if score @s gm4_blossoming_pots.summon_loop matches 0 run function gm4_blossoming_pots:decorated/sound/find with block ~ ~ ~ item
+
+# kill marker
+kill @s

gm4_blossoming_pots/data/gm4_blossoming_pots/function/decorated/as_player.mcfunction

@@ -0,0 +1,14 @@
+# Sets up raycast, then redirects to as_marker, then revokes advancement
+# @s = player who interacted with a decorated pot
+# at @s
+# run from advancement gm4_blossoming_pots:item_in_pot
+
+# Raycast for the pot (set up range and search)
+    # range is 6 blocks, don't know how to handle custom block interaction range...
+scoreboard players set @s gm4_blossoming_pots.range 1200
+execute anchored eyes run function gm4_blossoming_pots:decorated/raycast/loop
+
+execute as @e[type=minecraft:marker,sort=nearest,tag=gm4_blossoming_pots.temp.decorated_pot] at @s align xyz positioned ~.5 ~.5 ~.5 run function gm4_blossoming_pots:decorated/as_marker
+
+# Reset advancement
+advancement revoke @s only gm4_blossoming_pots:item_in_pot

gm4_blossoming_pots/data/gm4_blossoming_pots/function/decorated/catch_up/initialize.mcfunction

@@ -0,0 +1,7 @@
+# Intializes the loop for catching block display data up to current pot item count
+# @s = temp marker inside decorated pot
+# at @s align xyz positioned ~.5 ~.5 ~.5
+# run from decorated/as_marker
+
+scoreboard players set @s gm4_blossoming_pots.catch_up_loop 0
+function gm4_blossoming_pots:decorated/catch_up/loop with block ~ ~ ~ item

gm4_blossoming_pots/data/gm4_blossoming_pots/function/decorated/catch_up/loop.mcfunction

@@ -0,0 +1,15 @@
+# main loop for catching block display data up to current pot item count
+# @s = temp marker inside decorated pot
+# at @s align xyz positioned ~.5 ~.5 ~.5
+# with block ~ ~ ~ item
+# run from decorated/catch_up/initialize
+
+scoreboard players add @s gm4_blossoming_pots.catch_up_loop 1
+
+data modify storage gm4_blossoming_pots:decorated_pots temp.id set from block ~ ~ ~ item.id
+execute store result storage gm4_blossoming_pots:decorated_pots temp.count int 1 run scoreboard players get @s gm4_blossoming_pots.catch_up_loop
+$execute store result score @s gm4_blossoming_pots.merge_loop run data get storage gm4_blossoming_pots:decorated_pots $(id).display_count
+function gm4_blossoming_pots:decorated/merge/loop
+
+$execute unless score @s gm4_blossoming_pots.catch_up_loop matches $(count).. run function gm4_blossoming_pots:decorated/catch_up/loop with block ~ ~ ~ item
+data remove storage gm4_blossoming_pots:decorated_pots temp

gm4_blossoming_pots/data/gm4_blossoming_pots/function/decorated/merge/display.mcfunction

@@ -0,0 +1,7 @@
+# merges data of one block display with data from storage
+# @s = a single block display
+# at the center of the decorated pot, origin of the block display
+# with storage gm4_blossoming_pots:decorated_pots temp
+# run from decorated/merge/transfer
+
+$data merge entity @s $(merge)

gm4_blossoming_pots/data/gm4_blossoming_pots/function/decorated/merge/initialize.mcfunction

@@ -0,0 +1,21 @@
+# Intializes the loop for merging block display data
+# @s = temp marker inside decorated pot
+# at @s align xyz positioned ~.5 ~.5 ~.5
+# with block ~ ~ ~ item
+# run from decorated/as_marker
+
+
+# we'll need a loop function to iterate over the index in storage and the cooresponding tags of block displays within range of marker
+    # n -> 0 stop when 0
+$execute unless data storage gm4_blossoming_pots:decorated_pots $(id) run return 1
+# store pot data in temp
+$data modify storage gm4_blossoming_pots:decorated_pots temp set value {id:"$(id)",count:$(count)}
+
+# set score of marker to the display count of the item in the pot, (number of block displays to modify)
+$execute store result score @s gm4_blossoming_pots.merge_loop run data get storage gm4_blossoming_pots:decorated_pots $(id).display_count
+
+# now, the rotation is stored, the pot data is stored, the scoreboard is set up
+function gm4_blossoming_pots:decorated/merge/loop
+
+# clear temp
+data remove storage gm4_blossoming_pots:decorated_pots temp

gm4_blossoming_pots/data/gm4_blossoming_pots/function/decorated/merge/loop.mcfunction

@@ -0,0 +1,17 @@
+# main loop for merging block display data
+# @s = temp marker inside decorated pot
+# at @s align xyz positioned ~.5 ~.5 ~.5
+# run from decorated/merge/initialize
+# run from this function...
+# run from decorated/catch_up/loop
+
+scoreboard players remove @s gm4_blossoming_pots.merge_loop 1
+
+# store the current score into storage
+execute store result storage gm4_blossoming_pots:decorated_pots temp.number int 1 run scoreboard players get @s gm4_blossoming_pots.merge_loop
+
+# merge block display data
+function gm4_blossoming_pots:decorated/merge/transfer with storage gm4_blossoming_pots:decorated_pots temp
+
+# if there are more block displays to merge data, run again
+execute unless score @s gm4_blossoming_pots.merge_loop matches 0 run function gm4_blossoming_pots:decorated/merge/loop

gm4_blossoming_pots/data/gm4_blossoming_pots/function/decorated/merge/transfer.mcfunction

@@ -0,0 +1,21 @@
+# transfer layer of a function using macros :(
+# @s = temp marker inside decorated pot
+# at @s align xyz positioned ~.5 ~.5 ~.5
+# with storage gm4_blossoming_pots:decorated_pots temp
+# run from decorated/merge/loop
+
+
+
+# we need to
+    # target select the right block display
+        # use temp.number for numbered tag
+        # limit=1,sort=nearest,distance=..0.2
+    # data modify entity @s <PATH???> merge from storage gm4_blossoming_pots:decorated_pots $(temp.pot.id).$(temp.pot.count)[$(temp.number)]
+# AAAAAA
+# i have to go another function deeper
+
+# bail out if there isnt anything to merge here
+$execute unless data storage gm4_blossoming_pots:decorated_pots $(id).$(count) run return 1
+
+$data modify storage gm4_blossoming_pots:decorated_pots temp.merge set from storage gm4_blossoming_pots:decorated_pots $(id).$(count)[$(number)]
+$execute as @n[tag=gm4_blossoming_pots.display.decorated_pot.$(number),distance=..0.2] run function gm4_blossoming_pots:decorated/merge/display with storage gm4_blossoming_pots:decorated_pots temp

gm4_blossoming_pots/data/gm4_blossoming_pots/function/decorated/raycast/in_pot.mcfunction

@@ -0,0 +1,20 @@
+# checks if execution context is inside the decorated pots hit box
+# @s = player who interacted with a decorated pot
+# at @s anchored eyes, then marched forward 0.005 over and over. Complicated.
+# run from decorated/raycast/loop
+
+# early return if not dec pot
+execute unless block ~ ~ ~ minecraft:decorated_pot run return fail
+
+# summon marker for checking
+summon minecraft:marker ~ ~ ~ {Tags:["gm4_blossoming_pots.temp.decorated_pot","smithed.strict","smithed.entity"],CustomName:'{"text":"gm4_blossoming_pots.temp_marker"}'}
+
+# if temp marker in physical hit box, return 1
+# dxdydz all 0 bc of MC-123441.
+execute as @n[type=minecraft:marker,tag=gm4_blossoming_pots.temp.decorated_pot,distance=..0.1] \
+    align xyz positioned ~0.062499 ~ ~0.062499 if entity @s[dx=0,dy=0,dz=0] at @s align xyz positioned ~-0.062499 ~ ~-0.062499 if entity @s[dx=0,dy=0,dz=0] \
+    run return 1
+
+# else, kill marker, return fail
+kill @e[type=minecraft:marker,tag=gm4_blossoming_pots.temp.decorated_pot,distance=..0.1,sort=nearest]
+return fail

gm4_blossoming_pots/data/gm4_blossoming_pots/function/decorated/raycast/loop.mcfunction

@@ -0,0 +1,14 @@
+# main loop for raycasting for the decorated pot the player interacted with
+# @s = player who interacted with a decorated pot
+# at @s anchored eyes, then marched forward 0.005 over and over
+# run from decorated/as_player
+# run from this function...
+
+
+# if current location is within the decorated pots hit box, summon a temp marker, set its data with the player rotation, and exit raycast
+execute if function gm4_blossoming_pots:decorated/raycast/in_pot run return run function gm4_blossoming_pots:decorated/raycast/player_rotation
+
+scoreboard players remove @s gm4_blossoming_pots.range 1
+
+# repeat until find decorated pot or out of range
+execute if score @s gm4_blossoming_pots.range matches 1.. positioned ^ ^ ^0.005 run function gm4_blossoming_pots:decorated/raycast/loop

gm4_blossoming_pots/data/gm4_blossoming_pots/function/decorated/raycast/player_rotation.mcfunction

@@ -0,0 +1,13 @@
+# sets rotation data of the new temp marker from players
+# @s = player who interacted with a decorated pot
+# at @s anchored eyes, then marched forward 0.005 over and over. This should be in the same spot as the new temp marker
+# run from decorated/raycast/loop
+
+# player facing west
+execute if entity @s[y_rotation=45..135] run return run data merge entity @n[type=minecraft:marker,tag=gm4_blossoming_pots.temp.decorated_pot,distance=..0.01] {data:{rotation:0}}
+# player facing north
+execute if entity @s[y_rotation=135..225] run return run data merge entity @n[type=minecraft:marker,tag=gm4_blossoming_pots.temp.decorated_pot,distance=..0.01] {data:{rotation:90}}
+# player facing east
+execute if entity @s[y_rotation=225..315] run return run data merge entity @n[type=minecraft:marker,tag=gm4_blossoming_pots.temp.decorated_pot,distance=..0.01] {data:{rotation:180}}
+# player facing south
+execute if entity @s[y_rotation=315..405] run return run data merge entity @n[type=minecraft:marker,tag=gm4_blossoming_pots.temp.decorated_pot,distance=..0.01] {data:{rotation:-90}}