Merge pull request #406 from CoreMedia/sonar

added support for Sonar Plugin

Author: daspilker

docs/Home.md

@@ -19,6 +19,7 @@ Have a look at the [Jenkins Job DSL Gradle example](https://github.com/sheehan/j
 * 1.31 (unreleased)
  * Added support for [Build Node Column Plugin](https://wiki.jenkins-ci.org/display/JENKINS/Build+Node+Column+Plugin)
  * Added support for [Pre-SCM Build Step Plugin](https://wiki.jenkins-ci.org/display/JENKINS/pre-scm-buildstep)
+ * Added support for [Sonar Plugin](http://docs.sonarqube.org/display/SONAR/Jenkins+Plugin)
  * Added `ignorePostCommitHooks` option for SCM trigger
  * Added support for [PostBuildScript Plugin](https://wiki.jenkins-ci.org/display/JENKINS/PostBuildScript+Plugin)
  * The enum argument of `localRepository` for the Maven job and context has changed, see [[Migration]]

docs/Job-reference.md

@@ -250,6 +250,7 @@ freeStyleJob(String name) { // since 1.30
         publishScp(String site, Closure scpClosure)
         rundeck(String jobId, Closure rundeckClosure = null) // since 1.24
         s3(String profile, Closure s3Closure) // since 1.26
+        sonar(Closure sonarClosure = null) // since 1.31
         stashNotifier(Closure stashNotifierClosure = null) // since 1.23
         tasks(String pattern, excludePattern = '', high = '', normal = '', low = '',
               ignoreCase = false, Closure staticAnalysisClosure = null)
@@ -4419,6 +4420,41 @@ job('example-3') {
 
 (Since 1.23)
 
+### Sonar
+
+```groovy
+job {
+    publishers {
+        sonar {
+            branch(String branch)
+            overrideTriggers {
+                skipIfEnvironmentVariable(String environmentVariable)
+            }
+        }
+    }
+}
+```
+
+Allows to trigger SonarQube analysis. Requires the
+[Sonar Plugin](http://docs.sonarqube.org/display/SONAR/Jenkins+Plugin).
+
+```groovy
+// run Sonar analysis for feature-xy branch,
+// but skip if SKIP_SONAR environment variable is set to true
+job {
+    publishers {
+        sonar {
+            branch('feature-xy')
+            overrideTriggers {
+                skipIfEnvironmentVariable('SKIP_SONAR')
+            }
+        }
+    }
+}
+```
+
+(since 1.31)
+
 ### StashNotifier Publisher
 
 ```groovy

job-dsl-core/src/main/groovy/javaposse/jobdsl/dsl/helpers/publisher/PublisherContext.groovy

@@ -1725,6 +1725,50 @@ class PublisherContext implements Context {
         }
     }
 
+    /**
+     * <hudson.plugins.sonar.SonarPublisher>
+     *     <jdk>(Inherit From Job)</jdk>
+     *     <branch/>
+     *     <language/>
+     *     <mavenOpts/>
+     *     <jobAdditionalProperties/>
+     *     <triggers>
+     *         <skipScmCause>false</skipScmCause>
+     *         <skipUpstreamCause>false</skipUpstreamCause>
+     *         <envVar/>
+     *     </triggers>
+     *     <mavenInstallationName>(Inherit From Job)</mavenInstallationName>
+     *     <rootPom/>
+     *     <settings class="jenkins.mvn.DefaultSettingsProvider"/>
+     *     <globalSettings class="jenkins.mvn.DefaultGlobalSettingsProvider"/>
+     *     <usePrivateRepository>false</usePrivateRepository>
+     * </hudson.plugins.sonar.SonarPublisher>
+     */
+    void sonar(@DslContext(SonarContext) Closure sonarClosure = null) {
+        SonarContext sonarContext = new SonarContext()
+        ContextHelper.executeInContext(sonarClosure, sonarContext)
+
+        publisherNodes << new NodeBuilder().'hudson.plugins.sonar.SonarPublisher' {
+            jdk('(Inherit From Job)')
+            branch(sonarContext.branch ?: '')
+            language()
+            mavenOpts()
+            jobAdditionalProperties()
+            if (sonarContext.overrideTriggers) {
+                triggers {
+                    skipScmCause(false)
+                    skipUpstreamCause(false)
+                    envVar(sonarContext.sonarTriggersContext.skipIfEnvironmentVariable ?: '')
+                }
+            }
+            mavenInstallationName('(Inherit From Job)')
+            rootPom()
+            settings(class: 'jenkins.mvn.DefaultSettingsProvider')
+            globalSettings(class: 'jenkins.mvn.DefaultGlobalSettingsProvider')
+            usePrivateRepository(false)
+        }
+    }
+
     private static createDefaultStaticAnalysisNode(String publisherClassName, Closure staticAnalysisClosure,
                                                    String pattern) {
         StaticAnalysisContext staticAnalysisContext = new StaticAnalysisContext()

job-dsl-core/src/main/groovy/javaposse/jobdsl/dsl/helpers/publisher/SonarContext.groovy

@@ -0,0 +1,20 @@
+package javaposse.jobdsl.dsl.helpers.publisher
+
+import javaposse.jobdsl.dsl.Context
+import javaposse.jobdsl.dsl.ContextHelper
+import javaposse.jobdsl.dsl.DslContext
+
+class SonarContext implements Context {
+    String branch
+    boolean overrideTriggers
+    final SonarTriggersContext sonarTriggersContext = new SonarTriggersContext()
+
+    void branch(String branch) {
+        this.branch = branch
+    }
+
+    void overrideTriggers(@DslContext(SonarTriggersContext) Closure sonarTriggersClosure) {
+        overrideTriggers = true
+        ContextHelper.executeInContext(sonarTriggersClosure, sonarTriggersContext)
+    }
+}

job-dsl-core/src/main/groovy/javaposse/jobdsl/dsl/helpers/publisher/SonarTriggersContext.groovy

@@ -0,0 +1,11 @@
+package javaposse.jobdsl.dsl.helpers.publisher
+
+import javaposse.jobdsl.dsl.Context
+
+class SonarTriggersContext implements Context {
+    String skipIfEnvironmentVariable
+
+    void skipIfEnvironmentVariable(String environmentVariable) {
+        this.skipIfEnvironmentVariable = environmentVariable
+    }
+}

job-dsl-core/src/test/groovy/javaposse/jobdsl/dsl/helpers/publisher/PublisherContextSpec.groovy

@@ -3025,4 +3025,59 @@ class PublisherContextSpec extends Specification {
             scriptOnlyIfSuccess[0].value() == false
         }
     }
+
+    def 'call sonar with no options'() {
+        when:
+        context.sonar()
+
+        then:
+        with(context.publisherNodes[0]) {
+            name() == 'hudson.plugins.sonar.SonarPublisher'
+            children().size() == 10
+            jdk[0].value() == '(Inherit From Job)'
+            branch[0].value() == ''
+            language[0].value().empty
+            mavenOpts[0].value().empty
+            jobAdditionalProperties[0].value().empty
+            mavenInstallationName[0].value() == '(Inherit From Job)'
+            rootPom[0].value().empty
+            settings[0].value().empty
+            settings[0].@class == 'jenkins.mvn.DefaultSettingsProvider'
+            globalSettings[0].value().empty
+            globalSettings[0].@class == 'jenkins.mvn.DefaultGlobalSettingsProvider'
+            usePrivateRepository[0].value() == false
+        }
+    }
+
+    def 'call sonar with all options'() {
+        when:
+        context.sonar {
+            branch('test')
+            overrideTriggers {
+                skipIfEnvironmentVariable('FOO')
+            }
+        }
+
+        then:
+        with(context.publisherNodes[0]) {
+            name() == 'hudson.plugins.sonar.SonarPublisher'
+            children().size() == 11
+            jdk[0].value() == '(Inherit From Job)'
+            branch[0].value() == 'test'
+            language[0].value().empty
+            mavenOpts[0].value().empty
+            jobAdditionalProperties[0].value().empty
+            mavenInstallationName[0].value() == '(Inherit From Job)'
+            rootPom[0].value().empty
+            settings[0].value().empty
+            settings[0].@class == 'jenkins.mvn.DefaultSettingsProvider'
+            globalSettings[0].value().empty
+            globalSettings[0].@class == 'jenkins.mvn.DefaultGlobalSettingsProvider'
+            usePrivateRepository[0].value() == false
+            triggers[0].children().size() == 3
+            triggers[0].skipScmCause[0].value() == false
+            triggers[0].skipUpstreamCause[0].value() == false
+            triggers[0].envVar[0].value() == 'FOO'
+        }
+    }
 }