Add support for Xvfb Plugin

Author: Patrick Cadelina

docs/Job-reference.md

@@ -117,6 +117,7 @@ freeStyleJob(String name) { // since 1.30
         timeout(Closure timeoutClosure = null)
         timestamps()
         toolenv(String... tools)
+        xvfb(String installation)
         xvnc(boolean takeScreenshot) // deprecated
         xvnc(Closure xvncClosure = null) // since 1.26
     }
@@ -1667,6 +1668,29 @@ job('example') {
 
 (Since 1.19)
 
+### Xvfb
+
+```groovy
+job {
+    wrappers {
+        xvfb('xvfb') {
+            screen '1024x768x24' // defaults to 1024x768x24
+            debug(boolean debug = true) // defaults to false
+            timeout(int timeout) // defaults to 0
+            displayNameOffset(int displayNameOffset) // defaults to 1
+            shutdownWithBuild(boolean shutdownWithBuild = true) // defaults to false
+            autoDisplayName(boolean autoDisplayName = true) // defaults to false
+            assignedLabels 'xvfb'
+            parallelBuild(boolean parallelBuild = true) // defaults to false
+        }
+    }
+}
+```
+
+Lets you control Xvfb virtual frame buffer X11 server with each build. It starts Xvfb before the build starts, and stops
+it with the build. This is very useful if your build requires X11 access, for instance runs tests that require GUI.
+Requires the [Xvfb Plugin](https://wiki.jenkins-ci.org/display/JENKINS/Xvfb+Plugin).
+
 ### Xvnc
 
 ```groovy

job-dsl-core/src/main/groovy/javaposse/jobdsl/dsl/helpers/wrapper/WrapperContext.groovy

@@ -1,6 +1,7 @@
 package javaposse.jobdsl.dsl.helpers.wrapper
 
 import com.google.common.base.Preconditions
+
 import hudson.util.VersionNumber
 import javaposse.jobdsl.dsl.Context
 import javaposse.jobdsl.dsl.ContextHelper
@@ -308,6 +309,46 @@ class WrapperContext implements Context {
         }
     }
 
+    /**
+     * <pre>
+     * {@code
+     * <project>
+     *     <buildWrappers>
+     *         <org.jenkinsci.plugins.xvfb.XvfbBuildWrapper>
+     *             <installationName>xvfb</installationName>
+     *             <screen>1024x768x24</screen>
+     *             <debug>false</debug>
+     *             <timeout>0</timeout>
+     *             <displayNameOffset>1</displayNameOffset>
+     *             <shutdownWithBuild>false</shutdownWithBuild>
+     *             <autoDisplayName>false</autoDisplayName>
+     *             <assignedLabels>xvfb</assignedLabels>
+     *             <parallelBuild>false</parallelBuild>
+     *         </org.jenkinsci.plugins.xvfb.XvfbBuildWrapper>
+     *     </buildWrappers>
+     * </project>
+     * }
+     *
+     * Runs build under XVFB.
+     * @param name of the Xvfb tool installation that Jenkins administrator set up
+     */
+    void xvfb(String installation, @DslContext(XvfbContext) Closure closure = null) {
+        XvfbContext context = new XvfbContext(installation)
+        ContextHelper.executeInContext(closure, context)
+
+        wrapperNodes << new NodeBuilder().'org.jenkinsci.plugins.xvfb.XvfbBuildWrapper' {
+            installationName(context.installationName)
+            screen(context.screen)
+            debug(context.debug)
+            timeout(context.timeout)
+            displayNameOffset(context.displayNameOffset)
+            shutdownWithBuild(context.shutdownWithBuild)
+            autoDisplayName(context.autoDisplayName)
+            assignedLabels(context.assignedLabels)
+            parallelBuild(context.parallelBuild)
+        }
+    }
+
     /**
      * <pre>
      * {@code

job-dsl-core/src/main/groovy/javaposse/jobdsl/dsl/helpers/wrapper/XvfbContext.groovy

@@ -0,0 +1,55 @@
+package javaposse.jobdsl.dsl.helpers.wrapper
+
+import javaposse.jobdsl.dsl.Context
+
+class XvfbContext implements Context {
+    String installationName
+    String screen = '1024x768x24'
+    boolean debug = false
+    int timeout = 0
+    int displayNameOffset = 1
+    boolean shutdownWithBuild = false
+    boolean autoDisplayName = false
+    String assignedLabels
+    boolean parallelBuild = false
+
+    XvfbContext(String installationName) {
+        this.installationName = installationName
+    }
+
+    void installationName(String installationName) {
+        this.installationName = installationName
+    }
+
+    void screen(String screen) {
+        this.screen = screen
+    }
+
+    void debug(boolean debug = true) {
+        this.debug = debug
+    }
+
+    void timeout(int timeout) {
+        this.timeout = timeout
+    }
+
+    void displayNameOffset(int displayNameOffset) {
+        this.displayNameOffset = displayNameOffset
+    }
+
+    void shutdownWithBuild(boolean shutdownWithBuild = true) {
+        this.shutdownWithBuild = shutdownWithBuild
+    }
+
+    void autoDisplayName(boolean autoDisplayName = false) {
+        this.autoDisplayName = autoDisplayName
+    }
+
+    void assignedLabels(String assignedLabels) {
+        this.assignedLabels = assignedLabels
+    }
+
+    void parallelBuild(boolean parallelBuild = true) {
+        this.parallelBuild = parallelBuild
+    }
+}

job-dsl-core/src/test/groovy/javaposse/jobdsl/dsl/helpers/wrapper/WrapperContextSpec.groovy

@@ -413,6 +413,27 @@ class WrapperContextSpec extends Specification {
         wrapper.takeScreenshot[0].value() == false
     }
 
+    def 'xvfb' () {
+        when:
+        context.xvfb('default') {
+            assignedLabels 'xvfb'
+        }
+
+        then:
+        context.wrapperNodes[0].name() == 'org.jenkinsci.plugins.xvfb.XvfbBuildWrapper'
+        def wrapper = context.wrapperNodes[0]
+        wrapper.children().size() == 9
+        wrapper.installationName[0].value() == 'default'
+        wrapper.screen[0].value() == '1024x768x24'
+        wrapper.debug[0].value() == false
+        wrapper.timeout[0].value() == 0
+        wrapper.displayNameOffset[0].value() == 1
+        wrapper.shutdownWithBuild[0].value() == false
+        wrapper.autoDisplayName[0].value() == false
+        wrapper.assignedLabels[0].value() == 'xvfb'
+        wrapper.parallelBuild[0].value() == false
+    }
+
     def 'toolenv' () {
         when:
         context.toolenv('Ant 1.8.2', 'Maven 3')