Merge pull request #2962 from SeedCompany/edgedb-budget-and-budget-record-schema

Author: CarsonF

dbschema/budget.esdl

@@ -0,0 +1,40 @@
+module default {
+  type Budget extending Project::Child {
+    required status: Budget::Status {
+      default := Budget::Status.Pending;
+    };
+    
+    universalTemplate: File;
+    
+    records := .<budget[is Budget::Record];
+  }
+}
+  
+module Budget {
+  type Record extending Project::Child {
+    constraint exclusive on ((.budget, .fiscalYear, .organization));
+    
+    required fiscalYear: int16 {
+      readonly := true;
+    };
+    
+    amount: float32;
+    
+    required budget: default::Budget {
+      readonly := true;
+      on target delete delete source;
+    };
+    
+    required organization: default::Organization {
+      readonly := true;
+      on target delete delete source;
+    };
+  }
+  
+  scalar type Status extending enum<
+    Pending,
+    Current,
+    Superceded,
+    Rejected
+  >;
+}

dbschema/engagement.esdl

@@ -75,6 +75,7 @@ module default {
     trigger connectDedicationCeremony after insert for each do (
       insert Engagement::DedicationCeremony {
         createdAt := datetime_of_statement(),
+        modifiedAt := datetime_of_statement(),
         engagement := __new__,
         project := __new__.project,
         projectContext := __new__.projectContext,
@@ -128,6 +129,7 @@ module default {
     trigger connectCertificationCeremony after insert for each do (
       insert Engagement::CertificationCeremony {
         createdAt := datetime_of_statement(),
+        modifiedAt := datetime_of_statement(),
         engagement := __new__,
         project := __new__.project,
         projectContext := __new__.projectContext,

dbschema/migrations/00030.edgeql

@@ -0,0 +1,43 @@
+CREATE MIGRATION m1f6w2tfwomhiwhtzwnpraqfo24x3rnfcpnntt7nxe5f5l7utyjzpa
+    ONTO m1t7atw76jdjhcnrngoj5euzbz7qxve7dokvbhh4x5333yxm5klkwa
+{
+  CREATE MODULE Budget IF NOT EXISTS;
+  CREATE TYPE Budget::Record EXTENDING Project::Child {
+      CREATE REQUIRED LINK organization: default::Organization {
+          ON TARGET DELETE DELETE SOURCE;
+          SET readonly := true;
+      };
+      CREATE REQUIRED PROPERTY fiscalYear: std::int16 {
+          SET readonly := true;
+      };
+      CREATE PROPERTY amount: std::float32;
+  };
+  CREATE SCALAR TYPE Budget::Status EXTENDING enum<Pending, Current, Superceded, Rejected>;
+  CREATE TYPE default::Budget EXTENDING Project::Child {
+      CREATE LINK universalTemplate: default::File;
+      CREATE REQUIRED PROPERTY status: Budget::Status {
+          SET default := (Budget::Status.Pending);
+      };
+  };
+  ALTER TYPE Budget::Record {
+      CREATE REQUIRED LINK budget: default::Budget {
+          ON TARGET DELETE DELETE SOURCE;
+          SET readonly := true;
+      };
+      CREATE CONSTRAINT std::exclusive ON ((.budget, .fiscalYear, .organization));
+  };
+  ALTER TYPE default::Budget {
+      CREATE LINK records := (.<budget[IS Budget::Record]);
+  };
+  ALTER TYPE default::Project {
+      CREATE TRIGGER createBudgetOnInsert
+          AFTER INSERT 
+          FOR EACH DO (INSERT
+              default::Budget
+              {
+                  createdAt := std::datetime_of_statement(),
+                  project := __new__,
+                  projectContext := __new__.projectContext
+              });
+  };
+};

dbschema/migrations/00031.edgeql

@@ -0,0 +1,36 @@
+CREATE MIGRATION m1wzaeho6j66fhwcmgkeezkp52hqwxgc27uy7yqsdgml3qekc2iarq
+    ONTO m1f6w2tfwomhiwhtzwnpraqfo24x3rnfcpnntt7nxe5f5l7utyjzpa
+{
+  ALTER TYPE default::InternshipEngagement {
+      ALTER TRIGGER connectCertificationCeremony USING (INSERT
+          Engagement::CertificationCeremony
+          {
+              createdAt := std::datetime_of_statement(),
+              modifiedAt := std::datetime_of_statement(),
+              engagement := __new__,
+              project := __new__.project,
+              projectContext := __new__.projectContext
+          });
+  };
+  ALTER TYPE default::Project {
+      ALTER TRIGGER createBudgetOnInsert USING (INSERT
+          default::Budget
+          {
+              createdAt := std::datetime_of_statement(),
+              modifiedAt := std::datetime_of_statement(),
+              project := __new__,
+              projectContext := __new__.projectContext
+          });
+  };
+  ALTER TYPE default::LanguageEngagement {
+      ALTER TRIGGER connectDedicationCeremony USING (INSERT
+          Engagement::DedicationCeremony
+          {
+              createdAt := std::datetime_of_statement(),
+              modifiedAt := std::datetime_of_statement(),
+              engagement := __new__,
+              project := __new__.project,
+              projectContext := __new__.projectContext
+          });
+  };
+};

dbschema/project.esdl

@@ -60,6 +60,15 @@ module default {
         message := "A Project's own context should be itself (no more or less)"
       )
     );
+    
+    trigger createBudgetOnInsert after insert for each do (
+      insert default::Budget {
+        createdAt := datetime_of_statement(),
+        modifiedAt := datetime_of_statement(),
+        project := __new__,
+        projectContext := __new__.projectContext,
+      }
+    );
   }
 
   type TranslationProject extending Project {