Merge pull request #3023 from SeedCompany/edgedb/department-id

Author: CarsonF

dbschema/funding-account.esdl

@@ -3,7 +3,7 @@ module default {
     overloaded name {
       constraint exclusive;
     }
-
+    
     required accountNumber: int16 {
       constraint min_value(0);
       constraint max_value(9);

dbschema/migrations/00034.edgeql

@@ -0,0 +1,15 @@
+CREATE MIGRATION m1abuwgh5eb3m3ivtyo6lru3w6k7ermhoof3bphd72jtx2cezj7ewa
+    ONTO m1ijgeabkfengfe2lpxjtq7xxqjiulhehay7tuutdoa5g3scsenwvq
+{
+  ALTER TYPE default::Project {
+      CREATE LINK fieldRegion: default::FieldRegion;
+      CREATE LINK marketingLocation: default::Location;
+      CREATE LINK primaryLocation: default::Location;
+      CREATE TRIGGER enforceFundingAccount
+          AFTER UPDATE 
+          FOR EACH DO (std::assert((std::any((__new__.primaryLocation.fundingAccount.accountNumber > 0)) OR NOT (EXISTS (__new__.primaryLocation))), message := 'Project must have a primary location with a specified funding account'));
+      ALTER PROPERTY departmentId {
+          SET TYPE std::int32 USING (<std::int32>.departmentId);
+      };
+  };
+};

dbschema/migrations/00035.edgeql

@@ -0,0 +1,11 @@
+CREATE MIGRATION m13bndkbclxwviy3uj4eskx56bd2chw2xbvfn5pae557oslmbz2ssa
+    ONTO m1abuwgh5eb3m3ivtyo6lru3w6k7ermhoof3bphd72jtx2cezj7ewa
+{
+  ALTER TYPE default::Project {
+      ALTER PROPERTY departmentId {
+          CREATE CONSTRAINT std::exclusive;
+          CREATE CONSTRAINT std::max_value(99999);
+          CREATE CONSTRAINT std::min_value(10000);
+      };
+  };
+};

dbschema/migrations/00036.edgeql

@@ -0,0 +1,26 @@
+CREATE MIGRATION m1ydhle3dwjru34saeiidf5dyepbesugdwttrvnsyxhezpme5bfqga
+    ONTO m13bndkbclxwviy3uj4eskx56bd2chw2xbvfn5pae557oslmbz2ssa
+{
+  ALTER TYPE default::Project {
+      ALTER PROPERTY departmentId {
+          CREATE REWRITE
+              UPDATE 
+              USING ((IF ((NOT (EXISTS (.departmentId)) AND (.status <= Project::Status.Active)) AND (.step >= Project::Step.PendingFinanceConfirmation)) THEN (WITH
+                  fa := 
+                      std::assert_exists(__subject__.primaryLocation.fundingAccount, message := 'Project must have a primary location')
+                  ,
+                  existing := 
+                      (SELECT
+                          (DETACHED default::Project).departmentId
+                      FILTER
+                          (default::Project.primaryLocation.fundingAccount = fa)
+                      )
+                  ,
+                  available := 
+                      (std::range_unpack(std::range(((fa.accountNumber * 10000) + 11), ((fa.accountNumber * 10000) + 9999))) EXCEPT existing)
+              SELECT
+                  std::min(available)
+              ) ELSE .departmentId));
+      };
+  };
+};

dbschema/project.esdl

@@ -10,7 +10,32 @@ module default {
       default := Sensitivity.High;
     };
 
-    departmentId: str;
+    departmentId: int32 {
+      constraint exclusive;
+      constraint min_value(10000);
+      constraint max_value(99999);
+      rewrite update using (
+        if (
+          not exists .departmentId and
+          .status <= Project::Status.Active and
+          .step >= Project::Step.PendingFinanceConfirmation
+        ) then ((
+          with
+            fa := assert_exists(
+              __subject__.primaryLocation.fundingAccount,
+              message := "Project must have a primary location"
+            ),
+            existing := (
+              select detached Project.departmentId filter Project.primaryLocation.fundingAccount = fa
+            ),
+            available := (
+              range_unpack(range(fa.accountNumber * 10000 + 11, fa.accountNumber * 10000 + 9999))
+              except existing
+            )
+          select min(available)
+        )) else .departmentId
+      );
+    };
 
     required step: Project::Step {
       default := Project::Step.EarlyConversations;
@@ -44,9 +69,17 @@ module default {
 #     multi link engagements := .<project[is Engagement];
     property engagementTotal := count(.<project[is Engagement]);
 
-#       link primaryLocation: Location;
-#       link marketingLocation: Location;
-#       link fieldRegion: FieldRegion;
+    primaryLocation: Location;
+    trigger enforceFundingAccount after update for each do (
+      assert(
+        any(__new__.primaryLocation.fundingAccount.accountNumber > 0)
+          or not exists __new__.primaryLocation, # allow clearing
+        message := "Project must have a primary location with a specified funding account"
+      )
+    );
+    marketingLocation: Location;
+    fieldRegion: FieldRegion;
+    
     link rootDirectory: Directory;
 
     overloaded link projectContext: Project::Context {

src/components/project/handlers/set-department-id.handler.ts

@@ -4,17 +4,29 @@ import {
   ServerException,
   UnsecuredDto,
 } from '../../../common';
-import { DatabaseService, EventsHandler, IEventHandler } from '../../../core';
+import {
+  ConfigService,
+  DatabaseService,
+  EventsHandler,
+  IEventHandler,
+} from '../../../core';
 import { Project, ProjectStep } from '../dto';
 import { ProjectUpdatedEvent } from '../events';
 
 type SubscribedEvent = ProjectUpdatedEvent;
 
 @EventsHandler(ProjectUpdatedEvent)
 export class SetDepartmentId implements IEventHandler<SubscribedEvent> {
-  constructor(private readonly db: DatabaseService) {}
+  constructor(
+    private readonly db: DatabaseService,
+    private readonly config: ConfigService,
+  ) {}
 
   async handle(event: SubscribedEvent) {
+    if (this.config.databaseEngine === 'edgedb') {
+      return;
+    }
+
     const shouldSetDepartmentId =
       event.updates.step === ProjectStep.PendingFinanceConfirmation &&
       !event.updated.departmentId;