Add initial kotlin native toolchain and kt_library rule

MODULE.bazel

@@ -28,6 +28,14 @@ use_repo(
     "com_github_google_ksp",
     "com_github_jetbrains_kotlin",
     "com_github_jetbrains_kotlin_git",
+    "com_github_jetbrains_kotlin_native_linux_x86_64",
+    "com_github_jetbrains_kotlin_native_linux_x86_64_git",
+    "com_github_jetbrains_kotlin_native_macos_aarch64",
+    "com_github_jetbrains_kotlin_native_macos_aarch64_git",
+    "com_github_jetbrains_kotlin_native_macos_x86_64",
+    "com_github_jetbrains_kotlin_native_macos_x86_64_git",
+    "com_github_jetbrains_kotlin_native_windows_x86_64",
+    "com_github_jetbrains_kotlin_native_windows_x86_64_git",
     "com_github_pinterest_ktlint",
     "kotlin_build_tools_impl",
     "kotlinx_serialization_core_jvm",
@@ -39,6 +47,8 @@ register_toolchains("//src/main/starlark/core/compile/cli")
 
 register_toolchains("//kotlin/internal:default_toolchain")
 
+register_toolchains("//kotlin/internal/native:all")
+
 # Development dependencies
 # TODO(bencodes) A bunch of these dependencies need to be marked as dev_dependencies but before we can do that
 # we need to sort out a few cases around how these rules are consumed in various ways.

docs/kotlin.md

@@ -578,7 +578,9 @@ This macro registers the kotlin toolchain.
 load("@rules_kotlin//kotlin:repositories.doc.bzl", "kotlin_repositories")
 
 kotlin_repositories(<a href="#kotlin_repositories-is_bzlmod">is_bzlmod</a>, <a href="#kotlin_repositories-compiler_repository_name">compiler_repository_name</a>, <a href="#kotlin_repositories-ksp_repository_name">ksp_repository_name</a>, <a href="#kotlin_repositories-compiler_release">compiler_release</a>,
-                    <a href="#kotlin_repositories-ksp_compiler_release">ksp_compiler_release</a>)
+                    <a href="#kotlin_repositories-ksp_compiler_release">ksp_compiler_release</a>, <a href="#kotlin_repositories-kotlin_native_release_linux_x86_64">kotlin_native_release_linux_x86_64</a>,
+                    <a href="#kotlin_repositories-kotlin_native_release_macos_x86_64">kotlin_native_release_macos_x86_64</a>, <a href="#kotlin_repositories-kotlin_native_release_macos_aarch64">kotlin_native_release_macos_aarch64</a>,
+                    <a href="#kotlin_repositories-kotlin_native_release_windows_x86_64">kotlin_native_release_windows_x86_64</a>)
 </pre>
 
 Call this in the WORKSPACE file to setup the Kotlin rules.
@@ -593,6 +595,10 @@ Call this in the WORKSPACE file to setup the Kotlin rules.
 | <a id="kotlin_repositories-ksp_repository_name"></a>ksp_repository_name |  <p align="center"> - </p>   |  `"com_github_google_ksp"` |
 | <a id="kotlin_repositories-compiler_release"></a>compiler_release |  version provider from versions.bzl.   |  `struct(sha256 = "1ba08a8b45da99339a0601134cc037b54cf85e9bc0edbe76dcbd27c2d684a977", url_templates = ["https://github.com/JetBrains/kotlin/releases/download/v{version}/kotlin-compiler-{version}.zip"], version = "2.1.21")` |
 | <a id="kotlin_repositories-ksp_compiler_release"></a>ksp_compiler_release |  (internal) version provider from versions.bzl.   |  `struct(sha256 = "44e965bb067b2bb5cd9184dab2c3dea6e3eab747d341c07645bb4c88f09e49c8", url_templates = ["https://github.com/google/ksp/releases/download/{version}/artifacts.zip"], version = "2.1.21-2.0.1")` |
+| <a id="kotlin_repositories-kotlin_native_release_linux_x86_64"></a>kotlin_native_release_linux_x86_64 |  (internal) version provider from versions.bzl   |  `struct(sha256 = "42fb88529b4039b6ac1961a137ccb1c79fc80315947f3ec31b56834c7ce20d0b", strip_prefix_template = "kotlin-native-prebuilt-linux-x86_64-{version}", url_templates = ["https://github.com/JetBrains/kotlin/releases/download/v{version}/kotlin-native-prebuilt-linux-x86_64-{version}.tar.gz"], version = "2.1.21")` |
+| <a id="kotlin_repositories-kotlin_native_release_macos_x86_64"></a>kotlin_native_release_macos_x86_64 |  (internal) version provider from versions.bzl   |  `struct(sha256 = "fc6b5979ec322be803bfac549661aaf0f8f7342aa3bd09008d471fff2757bbdf", strip_prefix_template = "kotlin-native-prebuilt-macos-x86_64-{version}", url_templates = ["https://github.com/JetBrains/kotlin/releases/download/v{version}/kotlin-native-prebuilt-macos-x86_64-{version}.tar.gz"], version = "2.1.21")` |
+| <a id="kotlin_repositories-kotlin_native_release_macos_aarch64"></a>kotlin_native_release_macos_aarch64 |  <p align="center"> - </p>   |  `struct(sha256 = "8df16175b962bc4264a5c3b32cb042d91458babbd093c0f36194dc4645f5fe2e", strip_prefix_template = "kotlin-native-prebuilt-macos-aarch64-{version}", url_templates = ["https://github.com/JetBrains/kotlin/releases/download/v{version}/kotlin-native-prebuilt-macos-aarch64-{version}.tar.gz"], version = "2.1.21")` |
+| <a id="kotlin_repositories-kotlin_native_release_windows_x86_64"></a>kotlin_native_release_windows_x86_64 |  (internal) version provider from versions.bzl   |  `struct(sha256 = "8df16175b962bc4264a5c3b32cb042d91458babbd093c0f36194dc4645f5fe2", strip_prefix_template = "kotlin-native-prebuilt-windows-x86_64-{version}", url_templates = ["https://github.com/JetBrains/kotlin/releases/download/v{version}/kotlin-native-prebuilt-windows-x86_64-{version}.zip"], version = "2.1.21")` |
 
 
 <a id="versions.use_repository"></a>

kotlin/compiler/compiler.bzl

@@ -12,9 +12,9 @@
 # See the License for the specific language governing permissions and
 # limitations under the License.
 
-load("@com_github_jetbrains_kotlin//:artifacts.bzl", "KOTLINC_ARTIFACTS")
+load("@com_github_jetbrains_kotlin//:artifacts.bzl", "KOTLINC_ARTIFACTS", "KOTLIN_NATIVE_ARTIFACTS_AND_TARGETS")
 load("//kotlin:jvm.bzl", "kt_jvm_import")
-load("//kotlin/internal:defs.bzl", _KT_COMPILER_REPO = "KT_COMPILER_REPO")
+load("//kotlin/internal:defs.bzl", _KT_COMPILER_REPO = "KT_COMPILER_REPO", _KT_NATIVE_COMPILER_REPO_PREFIX = "KT_NATIVE_COMPILER_REPO_PREFIX")
 
 KOTLIN_STDLIBS = [
     "//kotlin/compiler:annotations",
@@ -25,18 +25,18 @@ KOTLIN_STDLIBS = [
     "//kotlin/compiler:trove4j",
 ]
 
-def _import_artifacts(artifacts, rule_kind):
-    _import_labels(artifacts.plugin, rule_kind)
-    _import_labels(artifacts.runtime, rule_kind)
-    _import_labels(artifacts.compile, rule_kind, neverlink = 1)
+def _import_artifacts(artifacts, rule_kind, compiler_repo = _KT_COMPILER_REPO):
+    _import_labels(artifacts.plugin, rule_kind, compiler_repo)
+    _import_labels(artifacts.runtime, rule_kind, compiler_repo)
+    _import_labels(artifacts.compile, rule_kind, compiler_repo, neverlink = 1)
 
-def _import_labels(labels, rule_kind, **rule_args):
+def _import_labels(labels, rule_kind, compiler_repo, **rule_args):
     for (label, file) in labels.items():
         if not file.endswith(".jar"):
             native.filegroup(
                 name = label,
                 srcs = [
-                    "@%s//:%s" % (_KT_COMPILER_REPO, label),
+                    "@%s//:%s" % (compiler_repo, label),
                 ],
             )
             return
@@ -46,10 +46,10 @@ def _import_labels(labels, rule_kind, **rule_args):
         args = dict(rule_args.items())
         args["visibility"] = ["//visibility:public"]
         args["name"] = label
-        args["jars"] = ["@%s//:%s" % (_KT_COMPILER_REPO, label)]
+        args["jars"] = ["@%s//:%s" % (compiler_repo, label)]
         sources = label + "-sources"
         if sources in labels:
-            args["srcjar"] = "@%s//:%s" % (_KT_COMPILER_REPO, sources)
+            args["srcjar"] = "@%s//:%s" % (compiler_repo, sources)
         rule_kind(**args)
 
 def kt_configure_compiler():
@@ -63,3 +63,16 @@ def kt_configure_compiler():
 
     _import_artifacts(KOTLINC_ARTIFACTS.jvm, kt_jvm_import)
     _import_artifacts(KOTLINC_ARTIFACTS.core, kt_jvm_import)
+    for platform in KOTLIN_NATIVE_ARTIFACTS_AND_TARGETS.keys():
+        _import_artifacts(KOTLIN_NATIVE_ARTIFACTS_AND_TARGETS[platform], kt_jvm_import, compiler_repo = _KT_NATIVE_COMPILER_REPO_PREFIX + "_" + platform)
+
+    # a convenience alias for kotlin-native to be referenced in other places
+    native.alias(
+        actual = select({
+            "@bazel_tools//src/conditions:linux_x86_64": "//kotlin/compiler:kotlin-native-linux-x86_64",
+            "@bazel_tools//src/conditions:darwin": "//kotlin/compiler:kotlin-native-macos-x86_64",
+            "@bazel_tools//src/conditions:windows": "//kotlin/compiler:kotlin-native-windows_x86_64",
+            "@bazel_tools//src/conditions:darwin_arm64": "//kotlin/compiler:kotlin-native-macos_aarch64",
+        }),
+        name = "kotlin-native",
+    )

kotlin/internal/defs.bzl

@@ -16,6 +16,7 @@ load(
     _JAVA_RUNTIME_TOOLCHAIN_TYPE = "JAVA_RUNTIME_TOOLCHAIN_TYPE",
     _JAVA_TOOLCHAIN_TYPE = "JAVA_TOOLCHAIN_TYPE",
     _KtJvmInfo = "KtJvmInfo",
+    _KtKlibInfo = "KtKlibInfo",
 )
 load(
     "//src/main/starlark/core/plugin:providers.bzl",
@@ -27,6 +28,7 @@ load(
 
 # The Kotlin Toolchain type.
 TOOLCHAIN_TYPE = "%s" % Label("//kotlin/internal:kt_toolchain_type")
+NATIVE_TOOLCHAIN_TYPE = "%s" % Label("//kotlin/internal/native:kt_native_toolchain_type")
 
 # Java toolchains
 JAVA_TOOLCHAIN_TYPE = _JAVA_TOOLCHAIN_TYPE
@@ -35,6 +37,9 @@ JAVA_RUNTIME_TOOLCHAIN_TYPE = _JAVA_RUNTIME_TOOLCHAIN_TYPE
 # The name of the Kotlin compiler workspace.
 KT_COMPILER_REPO = "com_github_jetbrains_kotlin"
 
+# The preifx of the Kotlin native compiler workspace name (will be suffixed with the platform)
+KT_NATIVE_COMPILER_REPO_PREFIX = "com_github_jetbrains_kotlin_native"
+
 # The name of the KSP compiler plugin workspace
 KSP_COMPILER_PLUGIN_REPO = "com_github_google_ksp"
 
@@ -47,3 +52,5 @@ KspPluginInfo = _KspPluginInfo
 KtCompilerPluginOption = _KtCompilerPluginOption
 
 KtPluginConfiguration = _KtPluginConfiguration
+
+KtKlibInfo = _KtKlibInfo

kotlin/internal/native/BUILD.bazel

@@ -0,0 +1,3 @@
+load("//kotlin/internal/native:toolchains.bzl", "kt_configure_native_toolchains")
+
+kt_configure_native_toolchains()

kotlin/internal/native/library.bzl

@@ -0,0 +1,78 @@
+load("//kotlin/internal:defs.bzl", _KtKlibInfo = "KtKlibInfo", _NATIVE_TOOLCHAIN_TYPE = "NATIVE_TOOLCHAIN_TYPE", _TOOLCHAIN_TYPE = "TOOLCHAIN_TYPE")
+load("//kotlin/internal/utils:utils.bzl", "utils")
+
+def _kt_library_impl(ctx):
+    module_name = utils.derive_module_name(ctx)
+    builder_args = utils.init_args(ctx, "kt_library", module_name)
+
+    klib = ctx.actions.declare_file("{}.klib".format(ctx.label.name))
+    outputs = [klib]
+
+    toolchains = ctx.toolchains[_TOOLCHAIN_TYPE]
+
+    # Retrieve konan.home from the chosen toolchain's distribution
+    native_toolchain_info = ctx.toolchains[_NATIVE_TOOLCHAIN_TYPE].kotlin_native_info
+    konan_home = native_toolchain_info.konan_home
+
+    deps_klibs = []
+    transitive_klibs = []
+    for dep in ctx.attr.deps:
+        deps_klibs.append(dep[_KtKlibInfo].klibs)
+        transitive_klibs.append(dep[_KtKlibInfo].transitive_klibs)
+
+    libraries = depset(transitive = deps_klibs)
+    builder_args.add_all("--sources", ctx.files.srcs)
+    builder_inputs, _, input_manifests = ctx.resolve_command(tools = [toolchains.kotlinbuilder])
+
+    builder_args.add("--strict_kotlin_deps", "off")
+    builder_args.add("--reduced_classpath_mode", "off")
+    builder_args.add("--output_klib", klib.path)
+
+    libraries = depset(transitive = deps_klibs)
+    builder_args.add_all("--klibs", libraries)
+    builder_args.add("--konan_home", konan_home.path)
+
+    ctx.actions.run(
+        mnemonic = "KotlinKlibCompile",
+        inputs = depset(builder_inputs + ctx.files.srcs, transitive = [libraries, native_toolchain_info.konan_home_files]),
+        outputs = outputs,
+        executable = toolchains.kotlinbuilder.files_to_run.executable,
+        tools = [
+            toolchains.kotlinbuilder.files_to_run,
+        ],
+        execution_requirements = {"supports-workers": "1"},
+        arguments = [ctx.actions.args().add_all(toolchains.builder_args), builder_args],
+        progress_message = "Compiling Kotlin to Klib %%{label} { kt: %d }" % len(ctx.files.srcs),
+        input_manifests = input_manifests,
+        env = {
+            "REPOSITORY_NAME": utils.builder_workspace_name(ctx),
+        },
+    )
+
+    return [
+        DefaultInfo(files = depset(outputs)),
+        _KtKlibInfo(
+            klibs = depset(outputs),
+            transitive_klibs = depset(transitive = transitive_klibs),
+        ),
+    ]
+
+kt_library = rule(
+    implementation = _kt_library_impl,
+    doc = """
+This rule is intended to leverage the new Kotlin IR backend to allow for compiling platform-independent Kotlin code
+to be shared between Kotlin code for different platforms (JS/JVM/WASM etc.). It produces a klib file as the output.
+    """,
+    attrs = {
+        "srcs": attr.label_list(
+            doc = "A list of source files to be compiled to klib",
+            allow_files = [".kt"],
+        ),
+        "deps": attr.label_list(
+            doc = "A list of other kt_klib_library targets that this library depends on for compilation",
+            providers = [_KtKlibInfo],
+        ),
+    },
+    toolchains = [_TOOLCHAIN_TYPE, _NATIVE_TOOLCHAIN_TYPE],
+    provides = [_KtKlibInfo],
+)

kotlin/internal/native/toolchains.bzl

@@ -0,0 +1,81 @@
+load("@bazel_skylib//rules/directory:providers.bzl", "DirectoryInfo")
+load("//src/main/starlark/core/repositories/kotlin:artifacts.bzl", "KOTLIN_NATIVE_ARTIFACTS_AND_TARGETS")
+
+KotlinNativeToolchainInfo = provider(fields = {
+    "konan_home": "The path to konan.home directory",
+    "konan_properties": "The kokna.properties file corresponding to this distribution",
+    "konan_home_files": "A depset containing all the files in konan.home",
+    "targets": "A list of Kotlin native targets this toolchain supports",
+})
+
+def _kt_native_toolchain_impl(ctx):
+    konan_home_info = ctx.attr.konan_home[DirectoryInfo]
+    konan_properties = konan_home_info.get_file("konan/konan.properties")
+    konan_home = konan_home_info
+
+    return [
+        platform_common.ToolchainInfo(
+            kotlin_native_info = KotlinNativeToolchainInfo(
+                konan_home = konan_home,
+                konan_home_files = depset(transitive = [konan_home_info.transitive_files]),
+                konan_properties = konan_properties,
+                targets = ctx.attr.targets,
+            ),
+        ),
+    ]
+
+kt_native_toolchain = rule(
+    implementation = _kt_native_toolchain_impl,
+    attrs = {
+        "konan_home": attr.label(
+            providers = [DirectoryInfo],
+            doc = "The directory containing konan.home",
+        ),
+        "targets": attr.string_list(
+            doc = "The list of targets supported by this toolchain. Each target can be passed to kotlinc-native with -target option",
+            default = [],
+        ),
+    },
+    provides = [platform_common.ToolchainInfo],
+)
+
+def kt_configure_native_toolchains():
+    """Defines and registers the default toolchains for the kotlin-native compiler for all the platforms and targets supported."""
+    native.toolchain_type(
+        name = "kt_native_toolchain_type",
+        visibility = ["//visibility:public"],
+    )
+
+    # Create toolchains for each exec platform and their supported targets
+    for exec_platform, artifacts_and_targets in KOTLIN_NATIVE_ARTIFACTS_AND_TARGETS.items():
+        for target_constraint_tuple, kotlin_native_targets in artifacts_and_targets.targets.items():
+            target_os, target_cpu = target_constraint_tuple
+
+            # Create a unique name for this toolchain
+            toolchain_name = "default_kt_native_toolchain_{}_to_{}_{}".format(
+                exec_platform,
+                target_os.split("//")[1].replace(":", "_").replace("/", "_"),
+                target_cpu.split("//")[1].replace(":", "_").replace("/", "_"),
+            )
+
+            toolchain_impl = "default_kt_native_{}_to_{}_{}".format(
+                exec_platform,
+                target_os.split("//")[1].replace(":", "_").replace("/", "_"),
+                target_cpu.split("//")[1].replace(":", "_").replace("/", "_"),
+            )
+
+            # Create the toolchain implementation
+            kt_native_toolchain(
+                name = toolchain_impl,
+                konan_home = "@com_github_jetbrains_kotlin_native_{}//:konan_home".format(exec_platform),
+                targets = kotlin_native_targets,
+            )
+
+            # Register the toolchain
+            native.toolchain(
+                name = toolchain_name,
+                exec_compatible_with = artifacts_and_targets.exec_compatible_with,
+                target_compatible_with = [target_os, target_cpu],
+                toolchain = ":" + toolchain_impl,
+                toolchain_type = ":kt_native_toolchain_type",
+            )

kotlin/internal/toolchains.bzl

@@ -79,6 +79,7 @@ def _kotlin_toolchain_impl(ctx):
         ],
         jdeps_merger = ctx.attr.jdeps_merger,
         kotlin_home = ctx.attr.kotlin_home,
+        konan_home = ctx.attr.konan_home,
         jvm_stdlibs = java_common.merge(compile_time_providers + runtime_providers),
         jvm_emit_jdeps = ctx.attr._jvm_emit_jdeps[BuildSettingInfo].value,
         execution_requirements = {
@@ -115,6 +116,10 @@ _kt_toolchain = rule(
             default = Label("@" + _KT_COMPILER_REPO + "//:home"),
             allow_files = True,
         ),
+        "konan_home": attr.label(
+            doc = "the filegroup defining the konan/kotlin-native home",
+            allow_files = True,
+        ),
         "kotlinbuilder": attr.label(
             doc = "the kotlin builder executable",
             default = Label("//src/main/kotlin:build"),

src/main/kotlin/io/bazel/kotlin/builder/KotlinBuilderComponent.java

@@ -22,6 +22,7 @@
 import io.bazel.kotlin.builder.tasks.CompileKotlin;
 import io.bazel.kotlin.builder.tasks.jvm.InternalCompilerPlugins;
 import io.bazel.kotlin.builder.tasks.jvm.KotlinJvmTaskExecutor;
+import io.bazel.kotlin.builder.tasks.knative.KotlinNativeTaskExecutor;
 import io.bazel.kotlin.builder.toolchain.KotlinToolchain;
 
 import javax.inject.Singleton;
@@ -33,6 +34,8 @@ public interface KotlinBuilderComponent {
 
     KotlinJvmTaskExecutor jvmTaskExecutor();
 
+    KotlinNativeTaskExecutor nativeTaskExecutor();
+
     CompileKotlin work();
 
     @Component.Builder

src/main/kotlin/io/bazel/kotlin/builder/cmd/BUILD.bazel

@@ -19,6 +19,7 @@ kt_bootstrap_binary(
         "//kotlin/compiler:jvm-abi-gen",
         "//kotlin/compiler:kotlin-annotation-processing",
         "//kotlin/compiler:kotlin-compiler",
+        "//kotlin/compiler:kotlin-native",
         "//kotlin/compiler:kotlin-reflect",
         "//kotlin/compiler:symbol-processing-api",
         "//kotlin/compiler:symbol-processing-cmdline",
@@ -38,6 +39,7 @@ kt_bootstrap_binary(
         "-D@com_github_jetbrains_kotlin...build-tools-impl=$(rlocationpath @kotlin_build_tools_impl//jar)",
         "-D@com_github_jetbrains_kotlin...jvm-abi-gen=$(rlocationpath //kotlin/compiler:jvm-abi-gen)",
         "-D@com_github_jetbrains_kotlin...kotlin-compiler=$(rlocationpath //kotlin/compiler:kotlin-compiler)",
+        "-D@com_github_jetbrains_kotlin_native...kotlin-native=$(rlocationpath //kotlin/compiler:kotlin-native)",
         "-D@com_github_jetbrains_kotlin...kapt=$(rlocationpath //kotlin/compiler:kotlin-annotation-processing)",
         "-D@rules_kotlin...jdeps-gen=$(rlocationpath //src/main/kotlin:jdeps-gen)",
         "-D@rules_kotlin...skip-code-gen=$(rlocationpath //src/main/kotlin:skip-code-gen)",