Fix Process#wait to not close @input (#16620)

Prior to this change, `Process#wait` would close the input stream if it is a pipe. This is an unexpected side effect. It prevents writing to the input while the process is still running.
When using `#wait` explicitly, it's now the user's responsibility to close the input pipe at an appropriate time if necessary.

We keep the closing behaviour in the yielding version of `Process.run` where it makes sense: Everything during the runtime of the process is expected to be inside the block. It even expands to closing all streams (if they're a pipe). This was already stated in the API docs, but effectively only input was closed.

Author: straight-shoota

spec/std/process_spec.cr

@@ -4,6 +4,7 @@ require "spec"
 require "process"
 require "./spec_helper"
 require "../support/env"
+require "../support/wait_for"
 
 private def exit_code_command(code)
   {% if flag?(:win32) %}
@@ -214,11 +215,40 @@ describe Process do
       value.should eq("hello#{newline}")
     end
 
-    it "closes ios after block" do
+    it "closes input after block" do
       Process.run(*stdin_to_stdout_command) { }
       $?.exit_code.should eq(0)
     end
 
+    it "closes output and error after block" do
+      reader, writer = IO.pipe
+      channel = Channel(Process).new
+
+      spawn do
+        Process.run(*stdin_to_stdout_command, input: reader, output: :pipe, error: :pipe) do |process|
+          channel.send process
+          channel.receive
+        end
+        channel.close
+      end
+
+      process = channel.receive
+
+      process.output.closed?.should be_false
+      process.error.closed?.should be_false
+
+      channel.send process
+
+      # Wait a moment for the other fiber to continue and close the IOs
+      wait_for { process.output.closed? }
+
+      process.output.closed?.should be_true
+      process.error.closed?.should be_true
+
+      writer.close
+      channel.receive?.should be_nil
+    end
+
     it "forwards closed io" do
       closed_io = IO::Memory.new
       closed_io.close

spec/support/wait_for.cr

@@ -0,0 +1,16 @@
+def wait_for(timeout = 100.milliseconds, sleeping = 10.microseconds, &)
+  now = Time.instant
+
+  Fiber.yield
+
+  until value = yield
+    sleep sleeping
+
+    if now.elapsed > timeout
+      return nil
+    end
+
+    sleeping *= 2
+  end
+  value
+end

src/process.cr

@@ -202,6 +202,8 @@ class Process
     process = new(command, args, env, clear_env, shell, input, output, error, chdir)
     begin
       value = yield process
+
+      process.close
       $? = process.wait
       value
     rescue ex
@@ -375,8 +377,6 @@ class Process
 
   # Waits for this process to complete and closes any pipes.
   def wait : Process::Status
-    close_io @input # only closed when a pipe was created but not managed by copy_io
-
     @wait_count.times do
       ex = channel.receive
       raise ex if ex