Don't remove behaviour_info/1 from behaviour modules

[escobera]

After #104 was merged I started getting the following errors on my tests

** (UndefinedFunctionError) function MyModule.behaviour_info/1 is undefined or private

The reason is that that, behaviour_info it is only added when there is a @callback in the module and it doesn't show up in module.__info__(:functions).

This PR adds a step create_mock function to somewhat recreate the callbacks present in the original module. I had to use any() for types in the callbacks because the only way to get the original types involved using Code.Typespec which is a private api.

[edgurgel]

Thanks! I'm still unsure how the previous change cause this issue.

[escobera]

So this is how I understand it:

When a module has a @callback, the elixir compiler will generate the behavior_info/1 function.

This function doesn't appear on Module.__info__(:functions), but it appears on Module.module_info(:exports). You can try this out in Iex with the following code:

defmodule Example do
  @callback test() :: :ok
end

Example.__info__(:functions)
# []
Example.module_info(:exports)
# [__info__: 1, behaviour_info: 1, module_info: 0, module_info: 1]

Before #104 the generate_mimic_functions/1 used module.module_info(:exports) to get the original module functions, this caused the side effect of adding back the behaviour_info/1 function to the list of functions in case of behaviour modules.

This change in #104

-    for {fn_name, arity} <- module.module_info(:exports),
+    for {fn_name, arity} <- if function_exported?(module, :__info__, 1) do
+      module.__info__(:functions)
+    else
+      module.module_info(:exports)
+    end,

filtered the behaviour_info/1.

I went a different route (as not to revert part of #104). And added back any @callbacks to the mock module, so the elixir compiler will auto-generate the behaviour_info/1 function and not depend on the generate_mimic_functions/1.

[edgurgel]

Hmmm I'm more tempted in returning to using exports but excluding macro functions from being copied. Something like this:

  defp generate_mimic_functions(module) do
    internal_functions = [__info__: 1, module_info: 0, module_info: 1]
    macro_functions = macro_functions(module)
    functions = module.module_info(:exports)

    for {fn_name, arity} <- functions,
        {fn_name, arity} not in (internal_functions ++ macro_functions) do # Exclude macro as functions
    ...
  end

  defp macro_functions(module) do
    if function_exported?(module, :__info__, 1) do
      :macros
      |> module.__info__()
      |> Enum.map(fn {name, arity} -> {String.to_atom("MACRO-#{name}"), arity + 1} end)
    else
      []
    end
  end

WDYT?

Could you check if this would work with your tests?

[escobera]

I checked and it works! I've also changed the test I've added to act as a regression test for this behavior.

[edgurgel]

Great! Thanks once again 🎉

[escobera]

Changed the PR name to better match the solution.