Initial work on config

Author: José Valim

lib/mix/lib/mix/config.ex

@@ -0,0 +1,88 @@
+defmodule Mix.Config do
+  @moduledoc """
+  Module for reading and merging app configurations.
+  """
+
+  @doc """
+  Reads a configuration file.
+
+  It returns the read configuration and a list of
+  dependencies this configuration may have on.
+  """
+  def read(file) do
+    config = Code.eval_file(file) |> elem(0)
+    validate!(config)
+    config
+  end
+
+  @doc """
+  Validates a configuration.
+  """
+  def validate!(config) do
+    if is_list(config) do
+      Enum.all?(config, fn
+        {app, value} when is_atom(app) ->
+          if Keyword.keyword?(value) do
+            true
+          else
+            raise ArgumentError, message:
+              "expected config for app #{inspect app} to return keyword list, got: #{inspect value}"
+          end
+        _ ->
+          false
+      end)
+    else
+      raise ArgumentError, message:
+        "expected config to return keyword list, got: #{inspect config}"
+    end
+  end
+
+  @doc """
+  Merges two configurations.
+
+  The configuration of each application is merged together
+  with the values in the second one having higher preference
+  than the first in case of conflicts.
+
+  ## Examples
+
+      iex> Mix.Config.merge([app: [k: :v1]], [app: [k: :v2]])
+      [app: [k: :v2]]
+
+      iex> Mix.Config.merge([app1: []], [app2: []])
+      [app1: [], app2: []]
+
+  """
+  def merge(config1, config2) do
+    Keyword.merge(config1, config2, fn _, app1, app2 ->
+      Keyword.merge(app1, app2)
+    end)
+  end
+
+  @doc """
+  Merges two configurations.
+
+  The configuration of each application is merged together
+  and a callback is invoked in case of conflicts receiving
+  the app, the conflicting key and both values. It must return
+  a value that will be used as part of the conflict resolution.
+
+  ## Examples
+
+      iex> Mix.Config.merge([app: [k: :v1]], [app: [k: :v2]],
+      ...>   fn app, k, v1, v2 -> {app, k, v1, v2} end)
+      [app: [k: {:app, :k, :v1, :v2}]]
+
+  """
+  def merge(config1, config2, callback) do
+    Keyword.merge(config1, config2, fn app, app1, app2 ->
+      Keyword.merge(app1, app2, fn k, v1, v2 ->
+        if v1 == v2 do
+          v1
+        else
+          callback.(app, k, v1, v2)
+        end
+      end)
+    end)
+  end
+end

lib/mix/lib/mix/tasks/loadconfig.ex

@@ -0,0 +1,78 @@
+defmodule Mix.Tasks.Loadconfig do
+  use Mix.Task
+
+  @moduledoc """
+  Loads the application configuration.
+
+  In case the application is an umbrella application, the
+  configuration for all children app will be merged together
+  and, in case there are any conflicts, they need to be resolved
+  in the umbrella application.
+  """
+
+  def run(_) do
+    set load()
+  end
+
+  def load() do
+    if Mix.Project.get do
+      project = Mix.Project.config
+      project[:config_path]
+      |> eval()
+      |> merge(Mix.Project.umbrella?)
+    else
+      []
+    end
+  end
+
+  def set(config) do
+    _ =
+      for {app, kw} <- config, {k, v} <- kw do
+        :application.set_env(app, k, v, persist: true)
+      end
+  end
+
+  defp eval(nil) do
+    if File.regular?("config/config.exs") do
+      eval("config/config.exs")
+    else
+      []
+    end
+  end
+
+  defp eval(file) do
+    try do
+      Mix.Config.read(file)
+    catch
+      kind, reason ->
+        stacktrace = System.stacktrace
+        Mix.shell.error "Could not load config #{file} from project #{inspect Mix.Project.get}"
+        :erlang.raise(kind, reason, stacktrace)
+    end
+  end
+
+  defp merge(base, false), do: base
+  defp merge(base, true) do
+    Mix.Dep.Umbrella.unloaded
+    |> Enum.reduce([], fn dep, acc ->
+         Mix.Dep.in_dependency dep, fn _ ->
+           config = eval(Mix.Project.config[:config_path])
+           merge dep, acc, config, base
+         end
+       end)
+    |> Mix.Config.merge(base)
+  end
+
+  defp merge(dep, acc, config, base) do
+    Mix.Config.merge(acc, config, fn app, k, v1, v2 ->
+      if Keyword.has_key?(base, app) and Keyword.has_key?(base[app], k) do
+        v1
+      else
+        raise Mix.Error, message: "umbrella child #{inspect dep.app} has set the configuration for " <>
+          "key #{inspect k} in app #{inspect app} to #{inspect v2} but another umbrella child has " <>
+          "already set it to #{inspect v1}. You need to remove the configuration or resolve " <>
+          "the conflict by setting a value in the umbrella config"
+      end
+    end)
+  end
+end

lib/mix/test/fixtures/configs/bad_app.exs

@@ -0,0 +1 @@
+[sample: :oops]

lib/mix/test/fixtures/configs/bad_root.exs

@@ -0,0 +1 @@
+:oops

lib/mix/test/fixtures/configs/good.exs

@@ -0,0 +1 @@
+[my_app: [key: :value]]

lib/mix/test/mix/config_test.exs

@@ -0,0 +1,22 @@
+Code.require_file "../test_helper.exs", __DIR__
+
+defmodule Mix.ConfigTest do
+  use MixTest.Case, async: true
+
+  doctest Mix.Config
+
+  test "read/1" do
+    assert Mix.Config.read(fixture_path("configs/good.exs")) ==
+           [my_app: [key: :value]]
+
+    msg = "expected config for app :sample to return keyword list, got: :oops"
+    assert_raise ArgumentError, msg, fn ->
+      Mix.Config.read fixture_path("configs/bad_app.exs")
+    end
+
+    msg = "expected config to return keyword list, got: :oops"
+    assert_raise ArgumentError, msg, fn ->
+      Mix.Config.read fixture_path("configs/bad_root.exs")
+    end
+  end
+end

lib/mix/test/mix/tasks/loadconfig_test.exs

@@ -0,0 +1,103 @@
+Code.require_file "../../test_helper.exs", __DIR__
+
+defmodule Mix.Tasks.LoadconfigTest do
+  use MixTest.Case
+
+  @apps [:my_app, :other_app]
+
+  teardown do
+    Enum.each @apps, fn app ->
+      Enum.each :application.get_all_env(app), fn {key, _} ->
+        :application.unset_env(app, key, persist: true)
+      end
+    end
+    :ok
+  end
+
+  defmodule Config do
+    def project do
+      [app: :myconfig, version: "0.1.0"]
+    end
+  end
+
+  test "loads and sets application configuration" do
+    Mix.Project.push Config
+
+    in_fixture "no_mixfile", fn ->
+      write_config """
+      [my_app: [key: :value]]
+      """
+
+      assert Application.fetch_env(:my_app, :key) == :error
+      Mix.Tasks.Loadconfig.run []
+      assert Application.fetch_env(:my_app, :key) == {:ok, :value}
+    end
+  end
+
+  test "logs on bad configuration" do
+    Mix.Project.push Config
+
+    in_fixture "no_mixfile", fn ->
+      write_config """
+      :oops
+      """
+
+      assert_raise ArgumentError, "expected config to return keyword list, got: :oops", fn ->
+        Mix.Tasks.Loadconfig.run []
+      end
+
+      msg = "Could not load config config/config.exs from project #{inspect Config}"
+      assert_received {:mix_shell, :error, [^msg]}
+    end
+  end
+
+  test "merge umbrella children configs" do
+    in_fixture "umbrella_dep/deps/umbrella", fn ->
+      Mix.Project.in_project(:umbrella, ".", fn _ ->
+        write_config "apps/foo/config/config.exs", """
+        [my_app: [key: :value]]
+        """
+
+        write_config "apps/bar/config/config.exs", """
+        [other_app: [key: :value]]
+        """
+
+        Mix.Tasks.Loadconfig.run []
+        assert Application.fetch_env(:my_app, :key) == {:ok, :value}
+        assert Application.fetch_env(:other_app, :key) == {:ok, :value}
+      end)
+    end
+  end
+
+  test "raises on umbrella conflicts until resolved" do
+    in_fixture "umbrella_dep/deps/umbrella", fn ->
+      Mix.Project.in_project(:umbrella, ".", fn _ ->
+        write_config "apps/foo/config/config.exs", """
+        [my_app: [key: :value1]]
+        """
+
+        write_config "apps/bar/config/config.exs", """
+        [my_app: [key: :value2]]
+        """
+
+        msg = ~r":foo has set the configuration for key :key in app :my_app to :value1"
+        assert_raise Mix.Error, msg, fn ->
+          Mix.Tasks.Loadconfig.run []
+        end
+
+        write_config """
+        [my_app: [key: :value3], other_app: [key: :value]]
+        """
+
+        Mix.Tasks.Loadconfig.run []
+        assert Application.fetch_env(:other_app, :key) == {:ok, :value}
+        assert Application.fetch_env(:my_app, :key) == {:ok, :value3}
+      end)
+    end
+  end
+
+  defp write_config(path \\ "config/config.exs", contents) do
+    File.mkdir_p! Path.dirname(path)
+    File.write! path, contents
+  end
+end