Add Mix.Tasks.Compile.reenable

lib/mix/lib/mix/task.compiler.ex

@@ -312,4 +312,26 @@ defmodule Mix.Task.Compiler do
 
     Mix.Sync.PubSub.broadcast(build_path, lazy_message)
   end
+
+  @doc """
+  Reenables given compilers so they can be executed again down the stack.
+
+  If an umbrella project reenables compilers, they are re-enabled for all
+  child projects.
+
+  Default is `:all` which effectively means all the compilers returned by
+  `Mix.Task.Compiler.compilers()` are to be reenabled. This task always
+  re-enables `"compile"` and `"compile.all"`.
+  """
+  @spec reenable([{:compilers, compilers}]) :: :ok when compilers: :all | [Mix.Task.task_name()]
+  def reenable(opts \\ []) do
+    compilers =
+      case Keyword.get(opts, :compilers, :all) do
+        :all -> Mix.Task.Compiler.compilers()
+        list when is_list(list) -> list
+      end
+
+    Enum.each(["compile", "compile.all"], &Mix.Task.reenable(&1))
+    Enum.each(compilers, &Mix.Task.reenable("compile.#{&1}"))
+  end
 end

lib/mix/test/mix/tasks/compile_test.exs

@@ -112,6 +112,37 @@ defmodule Mix.Tasks.CompileTest do
     end)
   end
 
+  test "recompiles newly created files" do
+    in_fixture("no_mixfile", fn ->
+      assert Mix.Tasks.Compile.run(["--verbose"]) == {:ok, []}
+      Mix.shell().flush()
+
+      File.mkdir_p!("lib/foo")
+
+      File.write!("lib/foo/z.ex", """
+      defmodule Z do
+        def ok, do: :ok
+      end
+      """)
+
+      assert :ok = Mix.Task.reenable("compile")
+      assert {:noop, []} = Mix.Task.run("compile")
+      refute File.regular?("_build/dev/lib/sample/ebin/Elixir.Z.beam")
+
+      assert :ok = Mix.Task.Compiler.reenable(compilers: [])
+      assert {:noop, []} = Mix.Task.run("compile")
+      refute File.regular?("_build/dev/lib/sample/ebin/Elixir.Z.beam")
+
+      assert :ok = Mix.Task.Compiler.reenable(compilers: ["erlang"])
+      assert {:noop, []} = Mix.Task.run("compile")
+      refute File.regular?("_build/dev/lib/sample/ebin/Elixir.Z.beam")
+
+      assert :ok = Mix.Task.Compiler.reenable()
+      assert {:ok, []} = Mix.Task.run("compile")
+      assert File.regular?("_build/dev/lib/sample/ebin/Elixir.Z.beam")
+    end)
+  end
+
   test "recompiles app cache if manifest changes" do
     in_fixture("no_mixfile", fn ->
       Mix.Tasks.Compile.run(["--force"])