Add debug macro D and T

.lispwords

@@ -13,3 +13,4 @@
 (define-json-union 1)
 (call-with-read-lock 1)
 (call-with-write-lock 1)
+(define-syntax-parse-rule 1)

common/debug.rkt

@@ -0,0 +1,52 @@
+#lang racket/base
+(require racket/file
+         racket/runtime-path
+         racket/match
+         racket/string
+         racket/format)
+
+(provide
+  maybe-debug-log
+  maybe-debug-file
+  D
+  T)
+
+(define debug? #f)
+
+(define-runtime-path df "debug.out.rkt")
+(define (maybe-debug-file t)
+  (when debug?
+    (display-to-file t df #:exists 'replace)))
+
+(define-runtime-path dp "debug.log")
+(define (maybe-debug-log m)
+  (when debug?
+    (with-output-to-file dp
+      #:exists 'append
+      (lambda ()
+        (writeln m)))))
+
+(define (err-log tag name msg)
+  (eprintf "[~a] ~a:\n~a\n" tag name msg))
+
+;; DEBUG macro: evaluates the expression, logs the result, and returns the result.
+(define-syntax-rule (D expr)
+  (call-with-values
+    (lambda () expr)
+    (lambda results
+      (err-log 'DEBUG (quote expr)
+               (match results
+                 [(list) (format "void")]
+                 [(list x) (~v x)]
+                 [_ (string-join (map ~v results) "\n")]))
+      (apply values results))))
+
+;; TIME macro: evaluates the expression, logs the time taken, and returns the result.
+(define-syntax-rule (T expr)
+  (let-values ([(results cpu-time real-time gc-time)
+                (time-apply (lambda () expr) '())])
+    (err-log 'TIME (quote expr)
+             (format "cpu time: ~a real time: ~a gc time: ~a"
+                     cpu-time real-time gc-time))
+    (apply values results)))
+

main.rkt

@@ -8,7 +8,7 @@
          racket/class
          racket/async-channel
          "common/interfaces.rkt"
-         "lsp/debug.rkt"
+         "common/debug.rkt"
          "lsp/methods.rkt"
          "lsp/msg-io.rkt"
          "lsp/responses.rkt")