[new-package] klavaro 3.14

mingw-w64-klavaro/001-fix-build-with-clang.patch

@@ -0,0 +1,29 @@
+--- a/src/callbacks.c
++++ b/src/callbacks.c
+@@ -1212,7 +1212,7 @@
+ 	}
+ }
+
+-G_MODULE_EXPORT void
++void
+ on_button_confirm_yes_clicked (GtkButton * button, gpointer user_data)
+ {
+ 	gchar *file;
+@@ -1372,7 +1372,7 @@
+  * 5 - Charts window
+  **********************************************************************/
+
+-G_MODULE_EXPORT void
++void
+ on_combobox_stat_module_changed (GtkComboBox *cmb, gpointer user_data)
+ {
+ 	static gchar *stat_title = NULL;
+@@ -1445,7 +1445,7 @@
+ 	plot_draw_chart (1);
+ }
+
+-G_MODULE_EXPORT void
++void
+ on_combobox_stat_type_changed (GtkComboBox *cmb, gpointer user_data)
+ {
+ 	static gboolean init = TRUE;

mingw-w64-klavaro/PKGBUILD

@@ -0,0 +1,54 @@
+# Contributor: Mehdi Chinoune <[email protected]>
+
+_realname=klavaro
+pkgbase=mingw-w64-${_realname}
+pkgname=("${MINGW_PACKAGE_PREFIX}-${_realname}")
+pkgver=3.14
+pkgrel=1
+pkgdesc="A flexible touch typing tutor. (mingw-w64)"
+arch=('any')
+mingw_arch=('ucrt64' 'clang64' 'clangarm64')
+url='https://klavaro.sourceforge.io'
+msys2_repository_url="https://sourceforge.net/p/klavaro/code/HEAD/tree/trunk/"
+license=('spdx:GPL-3.0-or-later')
+depends=("${MINGW_PACKAGE_PREFIX}-cc-libs"
+         "${MINGW_PACKAGE_PREFIX}-curl"
+         "${MINGW_PACKAGE_PREFIX}-gettext-runtime"
+         "${MINGW_PACKAGE_PREFIX}-glib2"
+         "${MINGW_PACKAGE_PREFIX}-gtk3"
+         "${MINGW_PACKAGE_PREFIX}-gtkdatabox"
+         "${MINGW_PACKAGE_PREFIX}-pango")
+makedepends=("${MINGW_PACKAGE_PREFIX}-cc"
+             "${MINGW_PACKAGE_PREFIX}-autotools"
+             "${MINGW_PACKAGE_PREFIX}-cairo"
+             "intltool")
+source=("https://downloads.sourceforge.net/${_realname}/${_realname}/${_realname}-${pkgver}.tar.bz2"
+        "001-fix-build-with-clang.patch")
+sha256sums=('87187e49d301c510e6964098cdb612126bf030d2a875fd799eadcad3eae56dab'
+            '57709404f7df88d83181c1da7ab435eaf6026d8017f1c3cc7c4019ad42b2121b')
+
+prepare() {
+  cd "${_realname}-${pkgver}"
+
+  patch -p1 -i "${srcdir}/001-fix-build-with-clang.patch"
+}
+
+build() {
+  mkdir -p "build-${MSYSTEM}" && cd "build-${MSYSTEM}"
+
+  CFLAGS+=" -Wno-unused-parameter" \
+  ../"${_realname}-${pkgver}"/configure \
+    --prefix="${MINGW_PREFIX}" \
+    --enable-shared
+
+  make
+}
+
+package() {
+  cd "build-${MSYSTEM}"
+
+  make install DESTDIR="${pkgdir}"
+
+  install -Dm644 "${srcdir}"/${_realname}-${pkgver}/COPYING \
+    "${pkgdir}"${MINGW_PREFIX}/share/licenses/${_realname}/LICENSE
+}