Add tests for :twilio/handle-event for twilio-transport-in

Author: ovistoica

core/src/voice_fn/transport.clj

@@ -111,6 +111,24 @@
 
                     :else [state]))}))
 
+(defn twilio-transport-in-transform
+  [{:twilio/keys [handle-event] :as state} _ input]
+  (let [data (u/parse-if-json input)
+        output (if (fn? handle-event) (handle-event data) nil)
+        out-frames (partial merge-with into output)]
+    (case (:event data)
+      "start" [state (if-let [stream-sid (:streamSid data)]
+                       (out-frames {:sys-out [(frame/system-config-change {:twilio/stream-sid stream-sid
+                                                                           :transport/serializer (make-twilio-serializer stream-sid)})]})
+                       (out-frames {}))]
+      "media"
+      [state (out-frames {:out [(frame/audio-input-raw
+                                  (u/decode-base64 (get-in data [:media :payload])))]})]
+
+      "close"
+      [state (out-frames {:sys-out [(frame/system-stop true)]})]
+      nil)))
+
 (def twilio-transport-in
   (flow/process
     {:describe (fn [] {:outs {:sys-out "Channel for system messages that have priority"
@@ -123,18 +141,4 @@
              {::flow/in-ports {:twilio-in in-ch}
               :twilio/handle-event handle-event})
 
-     :transform (fn [{:twilio/keys [handle-event] :as state} _ input]
-                  (let [data (u/parse-if-json input)
-                        output (if (fn? handle-event) (handle-event data) nil)
-                        out-frames (partial merge-with into output)]
-                    (case (:event data)
-                      "start" (when-let [stream-sid (:streamSid data)]
-                                [state (out-frames {:sys-out [(frame/system-config-change {:twilio/stream-sid stream-sid
-                                                                                           :transport/serializer (make-twilio-serializer stream-sid)})]})])
-                      "media"
-                      [state (out-frames {:out [(frame/audio-input-raw
-                                                  (u/decode-base64 (get-in data [:media :payload])))]})]
-
-                      "close"
-                      [state (out-frames {:sys-out [(frame/system-stop true)]})]
-                      nil)))}))
+     :transform twilio-transport-in-transform}))

core/test/voice_fn/transport_test.clj

@@ -0,0 +1,34 @@
+(ns voice-fn.transport-test
+  (:require
+   [midje.sweet :as midje :refer [fact facts]]
+   [voice-fn.frame :as frame]
+   [voice-fn.transport :as sut]
+   [voice-fn.utils.core :as u]))
+
+(def test-config-change-frame (frame/system-config-change {:llm/context {:messages [{:role :system :content "You are a cool llm"}]}}))
+(defn twilio-start-handle-event [event]
+  (cond
+    (= (:event event) "start")
+    {:sys-out [test-config-change-frame]}
+    :else {}))
+
+(facts
+  "about twilio transport in"
+  (fact
+    "Transport in calls twilio/handle-event if it is provided"
+    (let [state {:twilio/handle-event twilio-start-handle-event}]
+      (sut/twilio-transport-in-transform
+        state
+        :twilio-in
+        (u/json-str {:event "start"})) => [state {:sys-out [test-config-change-frame]}]
+      (fact
+        "Merges frames in the same array if more are generated"
+        (let [[new-state {:keys [sys-out]}] (sut/twilio-transport-in-transform
+                                              state
+                                              :twilio-in
+                                              (u/json-str {:event "start"
+                                                           :streamSid "hello"}))]
+          new-state => state
+          (first sys-out) => test-config-change-frame
+          (frame/system-config-change? (last sys-out)) => true
+          (:twilio/stream-sid (:frame/data (last sys-out))) => "hello")))))