FEAT added DRV8302 example code

Author: askuric

README.md

@@ -10,8 +10,8 @@ Therefore this is an attempt to:
 - Demystify FOC algorithm and make a robust but simple Arduino library: [Arduino *SimpleFOClibrary*](https://docs.simplefoc.com/arduino_simplefoc_library_showcase)
 - Develop a modular BLDC driver board: [Arduino *SimpleFOCShield*](https://docs.simplefoc.com/arduino_simplefoc_shield_showcase).
 
-
-> ***UPDATE:*** Arduino *SimpleFOClibrary* now supports STM32 boards [Nucleo](https://www.st.com/en/evaluation-tools/stm32-nucleo-boards.html) and [Bluepill](https://stm32-base.org/boards/STM32F103C8T6-Blue-Pill.html).
+> ***UPDATE:*** Arduino *SimpleFOClibrary* now supports high performance DRV8302 driver boards (60V, 15A, 30$). [YouTube link](https://www.youtube.com/watch?v=RI4nNMF608I).
+> You can find the board by clicking on [Aliexpress link](https://bit.ly/2BZZ5fG) and the  Arduino code example in the examples folder!
 
 ## Arduino *SimpleFOCShield*
 

examples/hardware_specific_examples/DRV8305_driver/motor_full_control_serial_examples/encoder/full_control_serial/full_control_serial.ino

@@ -0,0 +1,143 @@
+/**
+ * Comprehensive BLDC motor control example using encoder and the DRV8302 board
+ * 
+ * Using serial terminal user can send motor commands and configure the motor and FOC in real-time:
+ * - configure PID controller constants
+ * - change motion control loops
+ * - monitor motor variabels
+ * - set target values
+ * - check all the configuration values 
+ * 
+ * check the https://docs.simplefoc.com for full list of motor commands
+ * 
+ */
+#include <SimpleFOC.h>
+
+// DRV8302 pins connections
+// don't forget to connect the common ground pin
+#define INH_A 9
+#define INH_B 10
+#define INH_C 11
+#define EN_GATE 7
+#define M_PWM A1 
+#define M_OC A2
+#define OC_ADJ A3
+
+// motor instance
+BLDCMotor motor = BLDCMotor(INH_A, INH_B, INH_C, 11, EN_GATE);
+
+// encoder instance
+Encoder encoder = Encoder(2, 3, 8192);
+
+// Interrupt routine intialisation
+// channel A and B callbacks
+void doA(){encoder.handleA();}
+void doB(){encoder.handleB();}
+
+void setup() {
+
+  // initialize encoder sensor hardware
+  encoder.init();
+  encoder.enableInterrupts(doA, doB); 
+  // link the motor to the sensor
+  motor.linkSensor(&encoder);
+
+  // DRV8302 specific code
+  // M_OC  - enable overcurrent protection
+  pinMode(M_OC,OUTPUT);
+  digitalWrite(M_OC,LOW);
+  // M_PWM  - enable 3pwm mode
+  pinMode(M_PWM,OUTPUT);
+  digitalWrite(M_PWM,HIGH);
+  // OD_ADJ - set the maximum overcurrent limit possible
+  // Better option would be to use voltage divisor to set exact value
+  pinMode(OC_ADJ,OUTPUT);
+  digitalWrite(OC_ADJ,HIGH);
+
+  // choose FOC modulation
+  motor.foc_modulation = FOCModulationType::SpaceVectorPWM;
+
+  // power supply voltage [V]
+  motor.voltage_power_supply = 12;
+
+  // set control loop type to be used
+  motor.controller = ControlType::voltage;
+
+  // contoller configuration based on the controll type 
+  motor.PI_velocity.P = 0.2;
+  motor.PI_velocity.I = 20;
+  // default voltage_power_supply
+  motor.PI_velocity.voltage_limit = 12;
+
+  // velocity low pass filtering time constant
+  motor.LPF_velocity.Tf = 0.01;
+
+  // angle loop controller
+  motor.P_angle.P = 20;
+  // angle loop velocity limit
+  motor.P_angle.velocity_limit = 50;
+
+  // use monitoring with serial for motor init
+  // monitoring port
+  Serial.begin(115200);
+  // comment out if not needed
+  motor.useMonitoring(Serial);
+
+  // initialise motor
+  motor.init();
+  // align encoder and start FOC
+  motor.initFOC();
+
+  // set the inital target value
+  motor.target = 2;
+
+
+  Serial.println("Full control example: ");
+  Serial.println("Run user commands to configure and the motor (find the full command list in docs.simplefoc.com) \n ");
+  Serial.println("Initial motion control loop is voltage loop.");
+  Serial.println("Initial target voltage 2V.");
+  
+  _delay(1000);
+}
+
+
+void loop() {
+  // iterative setting FOC phase voltage
+  motor.loopFOC();
+
+  // iterative function setting the outter loop target
+  // velocity, position or voltage
+  // if tatget not set in parameter uses motor.target variable
+  motor.move();
+
+  // user communication
+  motor.command(serialReceiveUserCommand());
+}
+
+// utility function enabling serial communication the user
+String serialReceiveUserCommand() {
+  
+  // a string to hold incoming data
+  static String received_chars;
+  
+  String command = "";
+
+  while (Serial.available()) {
+    // get the new byte:
+    char inChar = (char)Serial.read();
+    // add it to the string buffer:
+    received_chars += inChar;
+
+    // end of user input
+    if (inChar == '\n') {
+      
+      // execute the user command
+      command = received_chars;
+
+      // reset the command buffer 
+      received_chars = "";
+    }
+  }
+  return command;
+}
+