feat: improve fgsea output reporting

workflow/resources/datavzrd/fgsea-template.yaml

@@ -0,0 +1,95 @@
+
+__use_yte__: true
+
+name: fgsea report table
+datasets:
+  gene_set_enrichment:
+    path: ?input.fgsea
+    separator: "\t"
+    headers: 1
+    offer-excel: ?params.offer_excel
+max-in-memory-rows: 20000
+views:
+  gene_set_enrichment:
+    hidden: false
+    dataset: gene_set_enrichment
+    page-size: 25
+    render-table:
+      columns:
+        pathway:
+          label: gene set
+          optional: false
+          display-mode: normal
+          plot-view-legend: false
+        size:
+          label: number of genes
+          optional: false
+          precision: 0
+          display-mode: normal
+          plot:
+            heatmap:
+              scale: linear
+              clamp: false
+              color-scheme: blues
+              aux-domain-columns: ~
+          plot-view-legend: false
+        padj:
+          display-mode: hidden
+        NES:
+          label: enrichment
+          display-mode: normal
+          spell:
+            url: "https://raw.githubusercontent.com/datavzrd/datavzrd-spells/8af3330798a978dc4f336eff4da31f8a43616b10/visualization/effect-size-and-significance-bubble/spell.yaml"
+            with:
+              effect_significance: "padj"
+              effect_size: "NES"
+              effect_size_domain_min: 2
+              effect_size_domain_mid: 0
+              effect_size_domain_max: -2
+              effect_size_color_scheme: "spectral"
+          plot-view-legend: false
+        ES:
+          optional: false
+          precision: 2
+          display-mode: detail
+          plot:
+            heatmap:
+              domain-mid: 0
+              scale: "linear"
+              range:
+                - "#4288b5"
+                - "#fbf8b0"
+                - "#d13c4b"
+          plot-view-legend: false
+        pval:
+          optional: false
+          precision: 2
+          display-mode: detail
+          plot:
+            heatmap:
+              scale: linear
+              clamp: false
+              color-scheme: ""
+              range:
+                - blue
+                - white
+              aux-domain-columns: ~
+          plot-view-legend: false
+        log2err:
+          optional: false
+          precision: 2
+          display-mode: hidden
+          plot-view-legend: false
+        leadingEdge:
+          optional: false
+          display-mode: detail
+          plot-view-legend: false
+        leading_edge_entrez_id:
+          optional: false
+          display-mode: detail
+          plot-view-legend: false
+        leading_edge_ens_gene:
+          optional: false
+          display-mode: detail
+          plot-view-legend: false
+webview-controls: false

workflow/rules/common.smk

@@ -287,6 +287,7 @@ def all_input(wildcards):
                     "results/tables/fgsea/{model}.sig-gene-sets.tsv",
                     "results/plots/fgsea/{model}.table-plot.pdf",
                     "results/plots/fgsea/{model}",
+                    "results/datavzrd-reports/fgsea_{model}/",
                 ],
                 model=config["diffexp"]["models"],
             )

workflow/rules/datavzrd.smk

@@ -110,7 +110,7 @@ rule spia_datavzrd:
     params:
         offer_excel=lookup(within=config, dpath="report/offer_excel", default=False),
     wrapper:
-        "v5.5.0/utils/datavzrd"
+        "v7.9.1/utils/datavzrd"
 
 
 # Generating Differential Expression Datavzrd Report
@@ -144,7 +144,32 @@ rule diffexp_datavzrd:
             wildcards.model
         ]["primary_variable"],
     wrapper:
-        "v5.5.0/utils/datavzrd"
+        "v7.9.1/utils/datavzrd"
+
+
+# Generating fgsea report table
+rule fgsea_datavzrd:
+    input:
+        config=workflow.source_path("../resources/datavzrd/fgsea-template.yaml"),
+        fgsea="results/tables/fgsea/{model}.all-gene-sets.tsv",
+    output:
+        report(
+            directory("results/datavzrd-reports/fgsea_{model}"),
+            htmlindex="index.html",
+            caption="../report/fgsea_table.rst",
+            category="gene set enrichment",
+            subcategory="{model}",
+            patterns=["index.html"],
+            labels={
+                "model": "{model}",
+            },
+        ),
+    log:
+        "logs/datavzrd-report/fgsea_{model}/fgsea_table_{model}.log",
+    params:
+        offer_excel=lookup(within=config, dpath="report/offer_excel", default=False),
+    wrapper:
+        "v7.9.1/utils/datavzrd"
 
 
 # Generating GO Enrichment Datavzrd Report
@@ -181,7 +206,7 @@ rule go_enrichment_datavzrd:
         offer_excel=lookup(within=config, dpath="report/offer_excel", default=False),
         samples=get_model_samples,
     wrapper:
-        "v5.5.0/utils/datavzrd"
+        "v7.9.1/utils/datavzrd"
 
 
 # Generating Meta Comparison Datavzrd Reports
@@ -207,7 +232,7 @@ rule meta_compare_datavzrd:
     log:
         "logs/datavzrd-report/meta_comp_{method}.{meta_comp}.log",
     wrapper:
-        "v5.5.0/utils/datavzrd"
+        "v7.9.1/utils/datavzrd"
 
 
 # Generating Input Datavzrd Reports
@@ -232,4 +257,4 @@ rule inputs_datavzrd:
     log:
         "logs/datavzrd-report/{input}_datavzrd.log",
     wrapper:
-        "v5.5.0/utils/datavzrd"
+        "v7.9.1/utils/datavzrd"

workflow/rules/enrichment.smk

@@ -38,36 +38,11 @@ rule fgsea:
         gene_sets=config["enrichment"]["fgsea"]["gene_sets_file"],
         common_src=workflow.source_path("../scripts/common.R"),
     output:
-        enrichment=report(
-            "results/tables/fgsea/{model}.all-gene-sets.tsv",
-            caption="../report/fgsea-table-all.rst",
-            category="Gene set enrichment analysis",
-            labels={"model": "{model}"},
-        ),
-        rank_ties=report(
-            "results/tables/fgsea/{model}.rank-ties.tsv",
-            caption="../report/fgsea-rank-ties.rst",
-            category="Gene set enrichment analysis",
-            labels={"model": "{model}"},
-        ),
-        significant=report(
-            "results/tables/fgsea/{model}.sig-gene-sets.tsv",
-            caption="../report/fgsea-table-significant.rst",
-            category="Gene set enrichment analysis",
-            labels={"model": "{model}"},
-        ),
-        plot=report(
-            "results/plots/fgsea/{model}.table-plot.pdf",
-            caption="../report/fgsea-table-plot.rst",
-            category="Gene set enrichment analysis",
-            labels={"model": "{model}"},
-        ),
-        plot_collapsed=report(
-            "results/plots/fgsea/{model}.collapsed_pathways.table-plot.pdf",
-            caption="../report/fgsea-collapsed-table-plot.rst",
-            category="Gene set enrichment analysis",
-            labels={"model": "{model}"},
-        ),
+        enrichment="results/tables/fgsea/{model}.all-gene-sets.tsv",
+        rank_ties="results/tables/fgsea/{model}.rank-ties.tsv",
+        significant="results/tables/fgsea/{model}.sig-gene-sets.tsv",
+        plot="results/plots/fgsea/{model}.table-plot.pdf",
+        plot_collapsed="results/plots/fgsea/{model}.collapsed_pathways.table-plot.pdf",
     params:
         bioc_species_pkg=bioc_species_pkg,
         model=get_model,