feat(iOS): Implement and use ContentScrollViewProviding for BottomTabsHostComponentView

ios/RNSScreen.mm

@@ -1242,8 +1242,9 @@ - (void)overrideScrollViewBehaviorInFirstDescendantChainIfNeeded
 
 - (void)updateContentScrollViewEdgeEffectsIfExists
 {
-  [RNSScrollEdgeEffectApplicator applyToScrollView:[RNSScrollViewFinder findScrollViewInFirstDescendantChainFrom:self]
-                                      withProvider:self];
+  [RNSScrollEdgeEffectApplicator
+      applyToScrollView:[RNSScrollViewFinder findContentScrollViewWithDelegatingToProvider:self]
+           withProvider:self];
 }
 
 #pragma mark - RNSSafeAreaProviding

ios/bottom-tabs/RNSBottomTabsHostComponentView.h

@@ -4,6 +4,7 @@
 #import "RNSEnums.h"
 #import "RNSReactBaseView.h"
 #import "RNSScreenContainer.h"
+#import "RNSScrollViewFinder.h"
 
 #ifdef RCT_NEW_ARCH_ENABLED
 #import "RNSViewControllerInvalidating.h"
@@ -27,6 +28,7 @@ NS_ASSUME_NONNULL_BEGIN
  */
 @interface RNSBottomTabsHostComponentView : RNSReactBaseView <
                                                 RNSScreenContainerDelegate,
+                                                RNSContentScrollViewProviding,
 #ifdef RCT_NEW_ARCH_ENABLED
                                                 RNSViewControllerInvalidating
 #else

ios/bottom-tabs/RNSBottomTabsHostComponentView.mm

@@ -194,6 +194,25 @@ - (void)invalidate
 
 #endif
 
+#pragma mark - RNSContentScrollViewProviding
+
+- (UIScrollView *)findContentScrollView
+{
+#if !TARGET_OS_TV && !TARGET_OS_VISION
+  if (_controller.selectedViewController == _controller.moreNavigationController) {
+    // Logic for More Controller; user is shown the native list of tabs.
+    // This we want to keep as-is, we're not styling the ScrollView here,
+    // so let's pretend there isn't one
+    return nil;
+  }
+#endif // check for build target != tvOS, visionOS
+
+  // User selected regular tab with our BottomTabScreenComponentView. We start directly from it.
+  // This has the advantage of being able to continue searching even if the TabScreen
+  // hasn't been mounted yet (see mountChildComponentView(), _reactSubviews).
+  return [RNSScrollViewFinder findContentScrollViewWithDelegatingToProvider:_controller.selectedViewController.view];
+}
+
 #pragma mark - React events
 
 - (nonnull RNSBottomTabsHostEventEmitter *)reactEventEmitter

ios/helpers/scroll-view/RNSContentScrollViewProviding.h

@@ -0,0 +1,9 @@
+@protocol RNSContentScrollViewProviding
+
+/**
+ * Finds content ScrollView within provider's hierarchy. The content ScrollView serves as a main interaction on the
+ * given screen. Implementations may use `RNSScrollViewFinder` to continue the search however they see fit.
+ */
+- (nullable UIScrollView *)findContentScrollView;
+
+@end

ios/helpers/scroll-view/RNSScrollViewFinder.h

@@ -0,0 +1,26 @@
+#import <UIKit/UIKit.h>
+#import "RNSContentScrollViewProviding.h"
+
+@interface RNSScrollViewFinder : NSObject
+
+/**
+ * Searches for content ScrollView by traversing down the hierarchy using first subview, similar to UIKit behavior.
+ * It will fail if:
+ * - UIScrollView is not a first subview of view or one of its descendants in the hierarchy,
+ * - if UIScrollView's parent is not yet attached.
+ *
+ * When `view == nil`, it should also return `nil`.
+ */
++ (nullable UIScrollView *)findScrollViewInFirstDescendantChainFrom:(nullable UIView *)view;
+
+/**
+ * Looks for UIScrollView in a similar way to `findScrollViewInFirstDescendantChainFrom`, until it finds
+ * `RNSContentScrollViewProviding`. Then, it delegates the task to the provider, and returns the results. This can
+ * overcome the problems of subviews' children not being mounted yet, or ScrollView being mounted at index different
+ * than 0.
+ *
+ * When `view == nil`, it should also return `nil`.
+ */
++ (nullable UIScrollView *)findContentScrollViewWithDelegatingToProvider:(nullable UIView *)view;
+
+@end

ios/helpers/scroll-view/RNSScrollViewFinder.mm

@@ -0,0 +1,44 @@
+#import "RNSScrollViewFinder.h"
+
+@implementation RNSScrollViewFinder
+
++ (UIScrollView *)findScrollViewInFirstDescendantChainFrom:(UIView *)view
+{
+  UIView *currentView = view;
+
+  while (currentView != nil) {
+    if ([currentView isKindOfClass:UIScrollView.class]) {
+      return static_cast<UIScrollView *>(currentView);
+    } else if ([currentView.subviews count] > 0) {
+      currentView = currentView.subviews[0];
+    } else {
+      break;
+    }
+  }
+
+  return nil;
+}
+
++ (nullable UIScrollView *)findContentScrollViewWithDelegatingToProvider:(nullable UIView *)view
+{
+  UIView *currentView = view;
+
+  while (currentView != nil) {
+    if ([currentView isKindOfClass:UIScrollView.class]) {
+      return static_cast<UIScrollView *>(currentView);
+    } else if ([currentView respondsToSelector:@selector(findContentScrollView)]) {
+      // When traversing the hierarchy, we don't check for conformance to protocol,
+      // but whether the view responds to `RNSContentScrollViewProviding.findContentScrollView`.
+      // This doesn't place locks and is faster.
+      return [static_cast<id<RNSContentScrollViewProviding>>(currentView) findContentScrollView];
+    } else if ([currentView.subviews count] > 0) {
+      currentView = currentView.subviews[0];
+    } else {
+      break;
+    }
+  }
+
+  return nil;
+}
+
+@end